showfriends.as

1.配置java环境

/**
 * @(#)ShowFriends.as
 * 
 * @author soda E-mail:[e-mail]
 * @version 1.0
 * <br>Program Name: NetGame for Blue
 * <br>Date: 2007-4-22
 */
import org.blue.net.ConnectJavaServer;
import org.game.context.Session;
import mx.soda.util.Map;
/**
 * 查看好友列表
 */
class org.game.handel.ShowFriends extends MovieClip 
{
	private var friendListDepth:Number = 100;
	private var closeBtn:Button;
	private var upPageBtn:Button;
	private var nextPageBtn:Button;
	//好友条
	private var frientListsMC:MovieClip;
	private var session:Session;
	//对话框
	private var friendChatMC:MovieClip;
	
	public function ShowFriends()
	{
		session = Session.getSession();
		//关闭物品栏
		closeBtn.onRelease = function()
		{
			debug("closeBtn");
			this._parent.unloadMovie();
		};
		this.onLoad = function()
		{
			debug("加载完成");
			//默认是加载第一页
			readShowFriends(1);
		};
	}
	
	/**
	 * 读去当前页的好友信息
	 * @param page:页数
	 */
	private function readShowFriends(page:Number):Void
	{
		
		var connect:ConnectJavaServer = ConnectJavaServer.getConnectJavaServer();
		var session:Session = Session.getSession();
		var obj:Object = new Object();
		debug("session.getId():" + session.getId());
		connect.call("PersonRequest","firends",obj,session.getName(),page);
		var par:ShowFriends = this;
		obj.onResult = function(map:Map)
		{
			par.debug("map:" + map);
			var ary:Array = map.values();
			par.debug("ary:" + ary);
			var talkContent:Map = session.getTalkContent();
			var len:Number = ary.length;
			for(var i:Number = 0; i < len; i++)
			{
				var num:Number = i + 1;
				par.debug("ary[i].get(\"friendName\"):" + ary[i].get("friendName"));
				var mc:MovieClip = par.attachMovie("frientListsMC",
										"frientListsMC" + num,par.friendListDepth++);
				mc.setFriendInfo(ary[i].get("friendName"),ary[i].get("friendEsate"));
				mc.headMC.gotoAndStop(ary[i].get("friendSculpt"));
				mc._width = 260.0;
				mc._height = 48;
				mc._x = 16;
				mc._y = i * 48 + 25;
				//检查是有存有信息
				var talks = talkContent.get(ary[i].get("friendName"));
				trace("=========talks=====" + talks);
				if(talks != undefined)
				{
					trace("mc.emailMC:" + mc.emailMC);
					//提示有信息
					mc.emailMC.gotoAndPlay("start");
					mc.setHavaInfo(true);
				}
			}
		};
	}
	/**
	 * 输出调试信息
	 */
	private function debug(msg:String):Void
	{
		trace("ShowFriends debug ->" + msg);
	}
}