configure.in

ortp协议栈（实时传输协议）

dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/rtpmod.c)

VERSION=0.4.2
PACKAGE=ortp

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE($PACKAGE,$VERSION)

AC_CANONICAL_HOST
AC_CANONICAL_BUILD

hpux_host=no
posixtimer_interval=10000

if test "$host_os" = "hpux11.00" -o "$host_os" = "hpux11.11" ;then
	AC_DEFINE(HOST_IS_HPUX)
	hpux_host=yes
fi

dnl Checks for programs.
AC_PROG_CC

if test "$GCC" != "yes" ; then
	if test "$hpux_host" = "yes" ; then
		dnl we are probably using HPUX cc compiler, so add a +O2 to CFLAGS
		CFLAGS="$CFLAGS +O2"
	fi
fi

AC_PROG_RANLIB
AM_PROG_LIBTOOL

dnl Checks for libraries.
AM_PATH_GLIB(1.2.0, [AC_DEFINE(HAVE_GLIB)], ,[gthread])

build_scheduler=yes

dnl Check if we have seteuid system call
AC_CHECK_LIB(c, seteuid, AC_DEFINE(HAVE_SETEUID))

dnl check if we can use the pthread_library
AC_CHECK_LIB(pthread, pthread_mutex_init, [pthread_enabled=yes], [pthread_enabled=no])

if test $pthread_enabled = "no" ; then
	build_scheduler=no
fi

AC_ARG_ENABLE(debug,
			[  --enable-debug=[yes/no]   enables the display of traces showing the execution of the library. [default=yes]],
			[case "${enableval}" in
				yes) debug_enabled=yes;;
				no) debug_enabled=no;;
				*) AC_MSG_ERROR("Bad value for --enable-debug");;
			esac],
			[debug_enabled=yes])

if test $debug_enabled = "yes"; then
	AC_DEFINE(RTP_DEBUG)
fi

AC_ARG_ENABLE(memcheck,
				[  --enable-memcheck=[yes/no]   enables memory leak detection (HPUX only).],
				[case "${enableval}" in
				yes) memcheck_enabled=yes;;
				no) memcheck_enabled=no;;
				*) AC_MSG_ERROR("Bad value for --enable-memcheck");;
			esac],
				[memcheck_enabled=no])
				
if test "$memcheck_enabled" = "yes" ; then
	if test "$hpux_host" = "yes" ; then
		AC_DEFINE(ENABLE_MEMCHECK)
	else
		echo "WARNING ************ : the memory check option is only availlable for HPUX."
	fi
fi

AC_ARG_ENABLE(hpuxkernel,
			[  --enable-hpuxkernel   compile the library as kernel module for HP-UX],
			[case "${enableval}" in
				yes) target_is_hpux=yes;;
				no) target_is_hpux=no;;
				*) AC_MSG_ERROR("Bad value for --enable-hpuxkernel");;
			esac],
			[target_is_hpux=no])

if test $target_is_hpux = "yes" ; then
	AC_DEFINE(TARGET_IS_HPUXKERNEL)
	build_scheduler="no"
else
	ORTPLOG="-DG_LOG_DOMAIN=\"oRTP\""
fi

AM_CONDITIONAL(HPUXKERNEL,test "x$target_is_hpux" = "xyes") 

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h sys/time.h unistd.h sys/audio.h linux/soundcard.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_HEADER_TIME
AC_WORDS_BIGENDIAN

dnl Checks for library functions.
AC_CHECK_FUNCS(select socket strerror)

if test $build_scheduler = "yes"; then
	AC_DEFINE(BUILD_SCHEDULER)
	PTHREAD_LIBS="-lpthread"
	if test $hpux_host = "yes" ; then
		PTHREAD_CFLAGS="-D_REENTRANT"
		AC_DEFINE(NOCONNECT)
dnl it seems 10 ms is too fast on hpux and it causes trouble 
		posixtimer_interval=20000
	fi
	AC_SUBST(PTHREAD_CFLAGS)
	AC_SUBST(PTHREAD_LIBS)
fi

AC_DEFINE_UNQUOTED(POSIXTIMER_INTERVAL,$posixtimer_interval)

dnl ##################################################
dnl # Check for gtk-doc.
dnl ##################################################

AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])

if test "x$with_html_dir" = "x" ; then
  HTML_DIR='${datadir}/gtk-doc/html'
else
  HTML_DIR=$with_html_dir
fi

AC_SUBST(HTML_DIR)

AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)

gtk_doc_min_version=0.6
if $GTKDOC ; then
    gtk_doc_version=`gtkdoc-mkdb --version`
    AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
    if perl <<EOF ; then
      exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
            ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
EOF
      AC_MSG_RESULT(yes)
   else
      AC_MSG_RESULT(no)
      GTKDOC=false
   fi
fi

dnl Let people disable the gtk-doc stuff.
AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)

if test x$enable_gtk_doc = xauto ; then
  if test x$GTKDOC = xtrue ; then
    enable_gtk_doc=yes
  else
    enable_gtk_doc=no
  fi
fi

AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)



AC_OUTPUT(
Makefile
src/Makefile
docs/Makefile
)