eventcychandle.s43

MSP430FE42X防窍电电表DEMO（编译器IAR3.42)

#include	"msp430xe42x.h"
#include  "EveFlagDef.h"

                EXTERN  MeterRunState
                EXTERN  SystemEventFlag
                EXTERN  SystemCycle
                EXTERN  SystemIV
                
                EXTERN  WatchdogReset
                EXTERN  ESP_ENRDYFG_Process                                
                EXTERN  BT_Process
                EXTERN  DataSave_Process
                EXTERN  LCD_Process
                EXTERN  KEY_Process                
                EXTERN  ProcCom
                EXTERN  Time_Compensate
                EXTERN  MinuteProcess
                EXTERN  EspParaSave_Process
                EXTERN  Calibration_Process                               
                EXTERN  HourProcess
                EXTERN  DayProcess
                EXTERN  MonthProcess
                EXTERN  YearProcess
                EXTERN  Task_No
                
                
                
                PUBLIC  EventCycHandle
                
                RSEG    CODE
EventCycHandle: BIT     #MAIN_VOLTAGE_ON, &MeterRunState   ;6cycles
                JZ      VolOFF                             ;2cycles
VolON           BIS     #LPM0 + GIE,SR
                JMP     L1
VolOFF          BIS     #LPM3 + GIE,SR                     ;2cycles

L1              MOV     #1,&SystemCycle                    ;4cycles
                MOV     #1,&SystemIV                       ;4cycles
                DINT                                       ;1cycle
                TST     &SystemEventFlag                   ;4cycles
                JZ      EventCycHandle                     ;2cycles
                EINT                                       ;1cycle
L2              BIT     &SystemCycle,&SystemEventFlag      ;6cycles
                JZ      L4                                 ;2cycles
                RLA     &SystemIV                          ;6cycles
                
                ADD     &SystemIV,PC                       ;4cycles
                JMP     L3
                
                JMP     TASK01                             ;2cycles
                JMP     TASK02
                JMP     TASK03
                JMP     TASK04
                JMP     TASK05
                JMP     TASK06
                JMP     TASK07
                JMP     TASK08
                JMP     TASK09
                JMP     TASK10
                JMP     TASK11
                JMP     TASK12
                JMP     TASK13
                JMP     TASK14
                JMP     TASK15
                JMP     TASK16
                JMP     L1
                
L3              RRA     &SystemIV                          ;4cycles
L4              RLA     &SystemCycle                       ;6cycles
                
                INC     &SystemIV                          ;4cycles
                CMP     &SystemCycle,&SystemEventFlag      ;6cycles
                JN      L1                                 ;2cycles
                JMP     L2                                 ;2cycles
                





TASK01          CALL    #WatchdogReset                    ;17cycles
                JMP     L3                                ;3cycles
                
TASK02          CALL    #ESP_ENRDYFG_Process 
                JMP     L3
                
TASK03          CALL    #BT_Process
                JMP     L3
                
TASK04          CALL    #DataSave_Process 
                JMP     L3
                
TASK05          CALL    #LCD_Process 
                JMP     L3
                
TASK06          CALL    #KEY_Process 
                JMP     L3
                
TASK07          CALL    #ProcCom 
                JMP     L3
                
TASK08          CALL    #Time_Compensate 
                JMP     L3
                
TASK09          CALL    #MinuteProcess 
                JMP     L3
                
TASK10          CALL    #EspParaSave_Process
                JMP     L3
                
TASK11          CALL    #Calibration_Process 
                JMP     L3
                
TASK12          CALL    #HourProcess 
                JMP     L3
                
TASK13          CALL    #DayProcess 
                JMP     L3
                
TASK14          CALL    #MonthProcess 
                JMP     L3
                
TASK15          CALL    #YearProcess 
                JMP     L3
                
TASK16          CALL    #Task_No
                JMP     L3  
   
   
                END