sampletraversinglist.as

《Flash AS3殿堂之路》光盘源码 学习ActionScript 3.0

package org.kingda.book.display
{
	import flash.display.Sprite;
	import flash.display.DisplayObjectContainer;
	import flash.display.DisplayObject;

	public class SampleTraversingList extends Sprite
	{
		public function SampleTraversingList() {
			var container:Sprite = new Sprite();
			var rect:RectSprite = new RectSprite ("A", 0xB9121B);
			container.addChild(rect);
			container.addChild(new StarShape());
			addChild(container);
			rect.name = "KingdaRect";
			traverseDisplayContainer(container);
			/*输出：
			 depth:0 [object RectSprite] KingdaRect
			     depth:0 [object TextField] instance3
			 depth:1 [object StarShape] instance4
			*/
		
			trace ("-----------------");
			traverseDisplayContainer(this);
			/*输出：
			 depth:0 [object Sprite] instance1
		     depth:0 [object RectSprite] KingdaRect
		         depth:0 [object TextField] instance3
		     depth:1 [object StarShape] instance4
			*/
		}
		
		public static function traverseDisplayContainer(
									container:DisplayObjectContainer, 
									indentString:String = ""):void 
		{								
			    var child:DisplayObject;
			    for (var i:uint=0; i < container.numChildren; i++) {
			        child = container.getChildAt(i);
			        trace (indentString,"depth:"+i, child, child.name); 
			        //如果发现是容器，则递归
			        if (container.getChildAt(i) is DisplayObjectContainer) {
			            traverseDisplayContainer(DisplayObjectContainer(child), 
			            							indentString + "    ");
			        }
			    }
		}
	}
}