sampletextlink.as

《Flash AS3殿堂之路》光盘源码 学习ActionScript 3.0

package org.kingda.book.display
{
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.events.TextEvent;
	import flash.net.URLRequest;
	import flash.net.navigateToURL;

	public class SampleTextLink extends Sprite
	{		
		private var txt:TextField;
		public function SampleTextLink()
		{
			txt = new TextField();
			txt.width = 300;
			txt.wordWrap = true;
			addChild(txt);			
			txt.htmlText = 
				"点击<u><a href='event:geturl|http://www.kingda.org/|_blank'>这儿</a></u>在" + 
				"新窗口打开一个到www.kingda.org链接。<br/>" + 
				"点击<u><a href='event:load|someswf.swf'>这儿</a></u>则是在Flash中加载一个动画。<br/>" + 
				"点击<u><a href='event:move|10'>这儿</a></u>则是将文本框移动10个像素。"
			txt.addEventListener(TextEvent.LINK, clickLink);							
		}
		
		private function clickLink(evt:TextEvent):void {
			trace (evt.text);
			var cmdArray:Array = evt.text.split("|");
			switch (cmdArray[0]) {
				case "geturl":
					geturl(cmdArray[1],cmdArray[2]);
					break;
				case "load":
					loadswf(cmdArray[1]);
					break;
				case "move":
					movetxt(cmdArray[1]);
					break;
				default:
					trace (cmdArray);
			}
		}
		
		private function geturl(url:String, target:String):void {
			var tmpRequest:URLRequest = new URLRequest(url);
			navigateToURL(tmpRequest, target);
		}
		private function loadswf(url:String):void {
			trace ("load a swf from :" + url);//用trace模拟一下.
		}
		private function movetxt(distance:Number):void {
			txt.x += distance;
		}
		
	}
}