sampleloadbinary.as

《Flash AS3殿堂之路》光盘源码 学习ActionScript 3.0

package org.kingda.book.net
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import flash.display.Loader;
    import flash.utils.ByteArray;
    import flash.system.Security;
    import flash.events.ProgressEvent;

	public class SampleLoadBinary extends Sprite
	{
		private var loader:Loader;
		private var loader2:Loader //请读者自行添加
		public function SampleLoadBinary() {
			//var targetURL:String = "fla/LinkedClass.swf";
			Security.allowDomain("www.actionscript3.cn");
			var targetURL:String = "http://www.actionscript3.cn/tmp/LinkedClass.swf";
			var request:URLRequest = new URLRequest(targetURL);
            var variables:URLLoader = new URLLoader();
            variables.dataFormat = URLLoaderDataFormat.BINARY;
            
            variables.addEventListener(Event.COMPLETE, completeHandler);
            variables.addEventListener(ProgressEvent.PROGRESS, listening);
            try
            {
            	 trace ("loading...");
                variables.load(request);
            } 
            catch (error:Error)
            {
                trace("Unable to load URL: " + error);
            }         
            
		}
		private function listening(event:ProgressEvent):void {
			trace ("now:" + event.bytesLoaded + ": " +event.bytesTotal);
		}
		
		private function completeHandler(event:Event):void {
            trace ("loaded");
            loader = new Loader();
            var content:ByteArray = event.target.data as ByteArray;
            loader.contentLoaderInfo.addEventListener (Event.COMPLETE, convertHandler);
            loader.loadBytes(content); 
            
            //提示，loader2在此加入:loader2 = new Loader() ...    
            loader2 = new Loader();   
            loader2.contentLoaderInfo.addEventListener (Event.COMPLETE, convertHandler);
            loader2.loadBytes(content);   
        }
        private function convertHandler(event:Event):void {
        	//addChild(loader);
        	addChild(event.target.loader as Loader);
        	event.target.loader.y = 100*Math.random();
        }
	}
}