samplesendandload.as

《Flash AS3殿堂之路》光盘源码 学习ActionScript 3.0

package org.kingda.book.net
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.events.ProgressEvent;
    import flash.text.TextField;

	public class SampleSendAndLoad extends Sprite
	{
		private var _result:TextField;
		public function SampleSendAndLoad() {
			//建立一个文本框对象，登录成功后，在其中显示返回的Session ID。
			_result = new TextField();
			_result.autoSize = "left";
			_result.wordWrap = true;
			_result.width = 300;
			addChild(_result);
			
			var loginXML:XML = 
			    <login>
			        <username>Kingda.org</username>
			        <password>ActionScript 3</password>
			    </login>;
			var request:URLRequest = new URLRequest("http://www.flash-mx.com/mm/login_xml.cfm");
			request.contentType = "text/xml";
			request.data = loginXML.toXMLString();
			request.method = URLRequestMethod.POST;
			var loader:URLLoader = new URLLoader();
			loader.addEventListener(Event.COMPLETE, completeHandler);
			try
			{
			    trace ("loading...");
			    loader.load(request);
			}
			catch (error:ArgumentError)
			{
			    trace("参数错误");
			}
			catch (error:SecurityError)
			{
			    trace("发生安全错误");
			    _result.text = "发生安全错误。\n" + error;
			}
		}
				
		private function completeHandler(event:Event):void
        {
            trace(event.target.data); //服务器端返回的信息
            var resultXML:XML = new XML(event.target.data);
            _result.text = resultXML.@sessionid;
        }
	}
}