importantsample.as

《Flash AS3殿堂之路》光盘源码 学习ActionScript 3.0

package org.kingda.book.namespaces
{
	import flash.display.Sprite;
	import org.kingda.book.namespaces.*;
	use namespace night;
	use namespace noon;
	use namespace morning;
	//本节例子可以看出，如果是在类外定义的命名空间，必须要在使用类前打开。但是类里面的命名空间不需要这样。
	public class ImportantSample extends Sprite
	{
		public function ImportantSample() {
			 var vocab:MultilingualVocabulary = new MultilingualVocabulary();

            trace(vocab.hello());    // hello
            
            var languages:Array = vocab.getLanguages();
            
            for (var i:uint; i < languages.length; i++) {
                var ns:Namespace = languages[i];
                if (ns != null) {
                    trace(ns.toString() + ": " + vocab.ns::hello());
                    // hello
                    // MultilingualVocabulary:Hawaiian: aloha
                    // MultilingualVocabulary:French: bon jour
             		}
            }
		}
	}
}

import org.kingda.book.namespaces.*;
class MultilingualVocabulary {
    //即使私有也没有关系，只要引用传出去即可。
    private namespace French;
    private namespace Hawaiian;
    private var languages:Array;

    public function MultilingualVocabulary() {
        languages = new Array(morning, noon, Hawaiian, French);
    }
        
    public function hello():String { 
        return "hello";
    }

    Hawaiian function hello():String {
        return "aloha";
    }

    French function hello():String { 
        return "bon jour";
    }
    
    morning function hello():String {
	 	return "morning";
	 	trace ("good morning!");
	}
	noon function hello():String {
		return "noon";
	 	trace ("good noon!");
	}
	night function hello():String {
		return "night";
		trace ("night hello()");
	}
        
    public function getLanguages():Array {
        return languages;
    }
}