sampleinheriteventdispatcher.as

《Flash AS3殿堂之路》光盘源码 学习ActionScript 3.0

package org.kingda.book.event
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.EventDispatcher;

	public class SampleInheritEventDispatcher extends Sprite
	{
		public function SampleInheritEventDispatcher() {
		 //生成一个KingdaSampleDispatcher的实例
			var dispatcher:KingdaSampleDispatcher = new KingdaSampleDispatcher();
            
			//标准的实现
			dispatcher.addEventListener(KingdaSampleDispatcher.ACTION, actionHandler);
            dispatcher.doSomething();
			
			//可以用直接字符串标识事件类型，但推荐使用静态加const的字符串
			dispatcher.addEventListener("KingdaPlaySC", anotherHandler);  
            
			//直接用new Event生成一个新的事件对象，该对象的事件类型为"KingdaPlaySC"
			dispatcher.dispatchEvent(new Event("KingdaPlaySC"));
			//输出：
			//action的侦听器: [Event type="action" bubbles=false cancelable=false eventPhase=2]
			//KingdaPlaySC的侦听器: [Event type="KingdaPlaySC" bubbles=false cancelable=false eventPhase=2]
        }

        private function actionHandler(event:Event):void {
            trace("action的侦听器: " + event);
        }
		
		private function anotherHandler(event:Event):void {
            trace("KingdaPlaySC的侦听器: " + event);
        }
    }
}

import flash.events.EventDispatcher;
import flash.events.Event;

class KingdaSampleDispatcher extends EventDispatcher {
    public static var ACTION:String = "action";

    //如果你需要在自己类中某个方法中发送事件，那么示例如下
	public function doSomething():void {
		//你的代码.....
		
		//发送事件
       dispatchEvent(new Event(KingdaSampleDispatcher.ACTION));
    }
}