update.f90

Sfdtd Simple finite-difference time-domain

! update.f90
! 
! Update Regeln fuer das FDTD Gitter
!
!    Copyright (C) 2007  Paul Panserrieu, < [e-mail] >
!
!    This program is free software: you can redistribute it and/or modify
!    it under the terms of the GNU General Public License as published by
!    the Free Software Foundation, either version 3 of the License.
! 
! last modified: 18-07-2007 01:25:26 PM CEST

MODULE update

USE fdtd_gitter 


IMPLICIT NONE

CONTAINS

SUBROUTINE h_update(g)

  TYPE(gitter), INTENT(INOUT)      :: g
  INTEGER                          :: ix, iy, iz

  DO iz=g%nzl, g%nzyh, 1
    DO iy=g%nyl, g%nyyh, 1
      DO ix=g%nxl+1, g%nxyh, 1
        g%H(ix, iy, iz, 1) = g%H(ix, iy, iz, 1)                           &
                            - g%MAT_MUE                                   &
                              * ( g%E(ix  , iy  , iz  , 2)                &
                                + g%E(ix  , iy+1, iz  , 3)                &
                                - g%E(ix  , iy  , iz+1, 2)                &
                                - g%E(ix  , iy  , iz  , 3)                &
                                )
      ENDDO
    ENDDO
  ENDDO

  DO iz=g%nzl, g%nzyh, 1
    DO iy=g%nyl+1, g%nyyh, 1
      DO ix=g%nxl, g%nxyh, 1
        g%H(ix, iy, iz, 2) = g%H(ix, iy, iz, 2)                             &
                              - g%MAT_MUE                                   &
                                * ( g%E(ix  , iy  , iz  , 3)                &
                                  + g%E(ix  , iy  , iz+1, 1)                &
                                  - g%E(ix+1, iy  , iz  , 3)                &
                                  - g%E(ix  , iy  , iz  , 1)                &
                                  )
      ENDDO
    ENDDO
  ENDDO

  DO iz=g%nzl+1, g%nzyh, 1
    DO iy=g%nyl, g%nyyh, 1
      DO ix=g%nxl, g%nxyh, 1
        g%H(ix, iy, iz, 3) = g%H(ix, iy, iz, 3)                             &
                              - g%MAT_MUE                                   &
                                * ( g%E(ix  , iy  , iz  , 1)                &
                                  + g%E(ix+1, iy  , iz  , 2)                &
                                  - g%E(ix  , iy+1, iz  , 1)                &
                                  - g%E(ix  , iy  , iz  , 2)                &
                                  )
      ENDDO
    ENDDO
  ENDDO

END SUBROUTINE h_update

SUBROUTINE e_update(g)

  TYPE(gitter), INTENT(INOUT)      :: g
  INTEGER                          :: ix, iy, iz

  DO iz=g%nzl+1, g%nzyh, 1
    DO iy=g%nyl+1, g%nyyh, 1
      DO ix=g%nxl, g%nxyh, 1
        g%E(ix, iy, iz, 1) = g%E(ix, iy, iz, 1)                             &
                             + g%MAT_EPS                                    &
                               * ( g%H(ix  , iy  , iz  , 3)                 &
                                 - g%H(ix  , iy  , iz  , 2)                 &
                                 - g%H(ix  , iy-1, iz  , 3)                 &
                                 + g%H(ix  , iy  , iz-1, 2)                 &
                                 )
      ENDDO
    ENDDO
  ENDDO

  DO iz=g%nzl+1, g%nzyh, 1
    DO iy=g%nyl, g%nyyh, 1
      DO ix=g%nxl+1, g%nxyh, 1
        g%E(ix, iy, iz, 2)= g%E(ix, iy, iz, 2)                              &
                             + g%MAT_EPS                                    &
                               * ( g%H(ix  , iy  , iz  , 1)                 &
                                 - g%H(ix  , iy  , iz  , 3)                 &
                                 - g%H(ix  , iy  , iz-1, 1)                 &
                                 + g%H(ix-1, iy  , iz  , 3)                 &
                                 )
      ENDDO
    ENDDO
  ENDDO

  DO iz=g%nzl, g%nzyh, 1
    DO iy=g%nyl+1, g%nyyh, 1
      DO ix=g%nxl+1, g%nxyh, 1
        g%E(ix, iy, iz, 3)= g%E(ix, iy, iz, 3)                              &
                             + g%MAT_EPS                                    &
                               * ( g%H(ix  , iy  , iz  , 2)                 &
                                 - g%H(ix  , iy  , iz  , 1)                 &
                                 - g%H(ix-1, iy  , iz  , 2)                 &
                                 + g%H(ix  , iy-1, iz  , 1)                 &
                                 )
        
      ENDDO
    ENDDO
  ENDDO

END SUBROUTINE e_update

END MODULE update