cbpnfile.bas

VISUAL BASIC与MATLAB实现混合编程源代码

Attribute VB_Name = "CBpnFile"
Private Declare Function GetPrivateProfileInt Lib "kernel32" Alias "GetPrivateProfileIntA" (ByVal lpApplicationName As String, ByVal lpKeyName As String, ByVal nDefault As Long, ByVal lpFileName As String) As Long
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long

Public ErrorMsg As String
'网络模型文件名(包括文件路径)
Public BpnFileName As String
'网络模型文件名
Public FileName As String
'网络模型文件名（不含扩展名）
Public FilePre As String
'网络训练输入文件
Public InTrainFile As String
'网络训练输出文件
Public OutTrainFile As String
'网络仿真输入文件
Public InSimuFile As String
'网络仿真输出文件
Public OutSimuFile As String
'当前文件
Public CurFileName As String

'对属性进行初始化
Public Function Class_Initialize()
  BpnFileName = vbNullString
  FileName = vbNullString
  FilePre = vbNullString
  InTrainFile = vbNullString
  OutTrainFile = vbNullString
  InSimuFile = vbNullString
  OutSimuFile = vbNullString
  CurFileName = vbNullString
  ErrorMsg = vbNullString
End Function

'指定 BPN 文件名给 CIniFile
Public Sub SpecifyBpn(FilePathName)
  BpnFileName = Trim(FilePathName)
End Sub

'判断是否已经指定了 BPN 文件名
Private Function NoBpnFile() As Boolean
  NoBpnFile = True
  If BpnFileName = vbNullString Then
     ErrorMsg = "没有指定 BPN 文件"
     Exit Function
  End If
  ErrorMsg = vbNullString
  NoBpnFile = False
End Function

Public Function WriteString(Section As String, key As String, Value As String) As Boolean
  WriteString = False
  If NoBpnFile() Then
     Exit Function
  End If
  If WritePrivateProfileString(Section, key, Value, BpnFileName) = 0 Then
     ErrorMsg = "写入失败"
     Exit Function
  End If
  WriteString = True
End Function

Public Function ReadString(Section As String, key As String, Size As Long) As String
  Dim ReturnStr As String
  Dim ReturnLng As Long
  ReadString = vbNullString
  If NoBpnFile() Then
     Exit Function
  End If
  ReturnStr = Space(Size)
  ReturnLng = GetPrivateProfileString(Section, key, vbNullString, ReturnStr, Size, BpnFileName)
  ReadString = Left(ReturnStr, ReturnLng)
End Function

Public Function ReadInt(Section As String, key As String) As Long
  Dim ReturnLng As Long
  ReadInt = 0
  ReturnLng = GetPrivateProfileInt(Section, key, 0, BpnFileName)
  If ReturnLng = 0 Then
     ReturnLng = GetPrivateProfileInt(Section, key, 1, BpnFileName)
     If ReturnLng = 1 Then
        ErrorMsg = "不能读取"
        Exit Function
     End If
  End If
  ReadInt = ReturnLng
End Function