lbdbgrid.pas

天涯進銷存系統

end;

procedure TLBGridDataLink.Reset;
begin
  if FModified then RecordChanged(nil) else Dataset.Cancel;
end;

function TLBGridDataLink.IsAggRow(Value: Integer): Boolean;
begin
  Result := False;
end;

procedure TLBGridDataLink.BuildAggMap;
begin
end;

{ TLBColumnTitle }
constructor TLBColumnTitle.Create(Column: TLBColumn);
begin
  inherited Create;
  FColumn := Column;
  FFont := TFont.Create;
  FFont.Assign(DefaultFont);
  FFont.OnChange := FontChanged;
end;

destructor TLBColumnTitle.Destroy;
begin
  FFont.Free;
  inherited Destroy;
end;

procedure TLBColumnTitle.Assign(Source: TPersistent);
begin
  if Source is TLBColumnTitle then
  begin
    if cvTitleAlignment in TLBColumnTitle(Source).FColumn.FAssignedValues then
      Alignment := TLBColumnTitle(Source).Alignment;
    if cvTitleColor in TLBColumnTitle(Source).FColumn.FAssignedValues then
      Color := TLBColumnTitle(Source).Color;
    if cvTitleCaption in TLBColumnTitle(Source).FColumn.FAssignedValues then
      Caption := TLBColumnTitle(Source).Caption;
    if cvTitleFont in TLBColumnTitle(Source).FColumn.FAssignedValues then
      Font := TLBColumnTitle(Source).Font;
  end
  else
    inherited Assign(Source);
end;

function TLBColumnTitle.DefaultAlignment: TAlignment;
begin
  Result := taLeftJustify;
end;

function TLBColumnTitle.DefaultColor: TColor;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := FColumn.GetGrid;
  if Assigned(Grid) then
    Result := Grid.FixedColor
  else
    Result := clBtnFace;
end;

function TLBColumnTitle.DefaultFont: TFont;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := FColumn.GetGrid;
  if Assigned(Grid) then
    Result := Grid.TitleFont
  else
    Result := FColumn.Font;
end;

function TLBColumnTitle.DefaultCaption: string;
var
  Field: TField;
begin
  Field := FColumn.Field;
  if Assigned(Field) then
    Result := Field.DisplayName
  else
    Result := FColumn.FieldName;
end;

procedure TLBColumnTitle.FontChanged(Sender: TObject);
begin
  Include(FColumn.FAssignedValues, cvTitleFont);
  FColumn.Changed(True);
end;

function TLBColumnTitle.GetAlignment: TAlignment;
begin
  if cvTitleAlignment in FColumn.FAssignedValues then
    Result := FAlignment
  else
    Result := DefaultAlignment;
end;

function TLBColumnTitle.GetColor: TColor;
begin
  if cvTitleColor in FColumn.FAssignedValues then
    Result := FColor
  else
    Result := DefaultColor;
end;

function TLBColumnTitle.GetCaption: string;
begin
  if cvTitleCaption in FColumn.FAssignedValues then
    Result := FCaption
  else
    Result := DefaultCaption;
end;

function TLBColumnTitle.GetFont: TFont;
var
  Save: TNotifyEvent;
  Def: TFont;
begin
  if not (cvTitleFont in FColumn.FAssignedValues) then
  begin
    Def := DefaultFont;
    if (FFont.Handle <> Def.Handle) or (FFont.Color <> Def.Color) then
    begin
      Save := FFont.OnChange;
      FFont.OnChange := nil;
      FFont.Assign(DefaultFont);
      FFont.OnChange := Save;
    end;
  end;
  Result := FFont;
end;

function TLBColumnTitle.IsAlignmentStored: Boolean;
begin
  Result := (cvTitleAlignment in FColumn.FAssignedValues) and
    (FAlignment <> DefaultAlignment);
end;

function TLBColumnTitle.IsColorStored: Boolean;
begin
  Result := (cvTitleColor in FColumn.FAssignedValues) and
    (FColor <> DefaultColor);
end;

function TLBColumnTitle.IsFontStored: Boolean;
begin
  Result := (cvTitleFont in FColumn.FAssignedValues);
end;

function TLBColumnTitle.IsCaptionStored: Boolean;
begin
  Result := (cvTitleCaption in FColumn.FAssignedValues) and
    (FCaption <> DefaultCaption);
end;

procedure TLBColumnTitle.RefreshDefaultFont;
var
  Save: TNotifyEvent;
begin
  if (cvTitleFont in FColumn.FAssignedValues) then Exit;
  Save := FFont.OnChange;
  FFont.OnChange := nil;
  try
    FFont.Assign(DefaultFont);
  finally
    FFont.OnChange := Save;
  end;
end;

procedure TLBColumnTitle.RestoreDefaults;
var
  FontAssigned: Boolean;
begin
  FontAssigned := cvTitleFont in FColumn.FAssignedValues;
  FColumn.FAssignedValues := FColumn.FAssignedValues - ColumnTitleValues;
  FCaption := '';
  RefreshDefaultFont;
  { If font was assigned, changing it back to default may affect grid title
    height, and title height changes require layout and redraw of the grid. }
  FColumn.Changed(FontAssigned);
end;

procedure TLBColumnTitle.SetAlignment(Value: TAlignment);
begin
  if (cvTitleAlignment in FColumn.FAssignedValues) and (Value = FAlignment) then Exit;
  FAlignment := Value;
  Include(FColumn.FAssignedValues, cvTitleAlignment);
  FColumn.Changed(False);
end;

procedure TLBColumnTitle.SetColor(Value: TColor);
begin
  if (cvTitleColor in FColumn.FAssignedValues) and (Value = FColor) then Exit;
  FColor := Value;
  Include(FColumn.FAssignedValues, cvTitleColor);
  FColumn.Changed(False);
end;

procedure TLBColumnTitle.SetFont(Value: TFont);
begin
  FFont.Assign(Value);
end;

procedure TLBColumnTitle.SetCaption(const Value: string);
var
  Grid: TLBCustomDBGrid;
begin
  if Column.IsStored then
  begin
    if (cvTitleCaption in FColumn.FAssignedValues) and (Value = FCaption) then Exit;
    FCaption := Value;
    Include(Column.FAssignedValues, cvTitleCaption);
    Column.Changed(False);
  end
  else
  begin
    Grid := Column.GetGrid;
    if Assigned(Grid) and (Grid.Datalink.Active) and Assigned(Column.Field) then
      Column.Field.DisplayLabel := Value;
  end;
end;


{ TLBColumn }

constructor TLBColumn.Create(Collection: TCollection);
var
  Grid: TLBCustomDBGrid;
begin
  Grid := nil;
  if Assigned(Collection) and (Collection is TLBDBGridColumns) then
    Grid := TLBDBGridColumns(Collection).Grid;
  if Assigned(Grid) then Grid.BeginLayout;
  try
    inherited Create(Collection);
    FDropDownRows := 7;
    FButtonStyle := cbsAuto;
    FFont := TFont.Create;
    FFont.Assign(DefaultFont);
    FFont.OnChange := FontChanged;
    FImeMode := imDontCare;
    FImeName := Screen.DefaultIme;
    FTitle := CreateTitle;
    FVisible := True;
    FExpanded := True;
    FStored := True;
  finally
    if Assigned(Grid) then Grid.EndLayout;
  end;
end;

destructor TLBColumn.Destroy;
begin
  FTitle.Free;
  FFont.Free;
  FPickList.Free;
  inherited Destroy;
end;

procedure TLBColumn.Assign(Source: TPersistent);
begin
  if Source is TLBColumn then
  begin
    if Assigned(Collection) then Collection.BeginUpdate;
    try
      RestoreDefaults;
      FieldName := TLBColumn(Source).FieldName;
      if cvColor in TLBColumn(Source).AssignedValues then
        Color := TLBColumn(Source).Color;
      if cvWidth in TLBColumn(Source).AssignedValues then
        Width := TLBColumn(Source).Width;
      if cvFont in TLBColumn(Source).AssignedValues then
        Font := TLBColumn(Source).Font;
      if cvImeMode in TLBColumn(Source).AssignedValues then
        ImeMode := TLBColumn(Source).ImeMode;
      if cvImeName in TLBColumn(Source).AssignedValues then
        ImeName := TLBColumn(Source).ImeName;
      if cvAlignment in TLBColumn(Source).AssignedValues then
        Alignment := TLBColumn(Source).Alignment;
      if cvReadOnly in TLBColumn(Source).AssignedValues then
        ReadOnly := TLBColumn(Source).ReadOnly;
      Title := TLBColumn(Source).Title;
      DropDownRows := TLBColumn(Source).DropDownRows;
      ButtonStyle := TLBColumn(Source).ButtonStyle;
      PickList := TLBColumn(Source).PickList;
      PopupMenu := TLBColumn(Source).PopupMenu;
      FVisible := TLBColumn(Source).FVisible;
      FExpanded := TLBColumn(Source).FExpanded;
    finally
      if Assigned(Collection) then Collection.EndUpdate;
    end;
  end
  else
    inherited Assign(Source);
end;

function TLBColumn.CreateTitle: TLBColumnTitle;
begin
  Result := TLBColumnTitle.Create(Self);
end;

function TLBColumn.DefaultAlignment: TAlignment;
begin
  if Assigned(Field) then
    Result := FField.Alignment
  else
    Result := taLeftJustify;
end;

function TLBColumn.DefaultColor: TColor;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := GetGrid;
  if Assigned(Grid) then
    Result := Grid.Color
  else
    Result := clWindow;
end;

function TLBColumn.DefaultFont: TFont;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := GetGrid;
  if Assigned(Grid) then
    Result := Grid.Font
  else
    Result := FFont;
end;

function TLBColumn.DefaultImeMode: TImeMode;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := GetGrid;
  if Assigned(Grid) then
    Result := Grid.ImeMode
  else
    Result := FImeMode;
end;

function TLBColumn.DefaultImeName: TImeName;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := GetGrid;
  if Assigned(Grid) then
    Result := Grid.ImeName
  else
    Result := FImeName;
end;

function TLBColumn.DefaultReadOnly: Boolean;
var
  Grid: TLBCustomDBGrid;
begin
  Grid := GetGrid;
  Result := (Assigned(Grid) and Grid.ReadOnly) or
    (Assigned(Field) and FField.ReadOnly);
end;

function TLBColumn.DefaultWidth: Integer;
var
  W: Integer;
  RestoreCanvas: Boolean;
  TM: TTextMetric;
begin
  if GetGrid = nil then
  begin
    Result := 64;
    Exit;
  end;
  with GetGrid do
  begin
    if Assigned(Field) then
    begin
      RestoreCanvas := not HandleAllocated;
      if RestoreCanvas then
        Canvas.Handle := GetDC(0);
      try
        Canvas.Font := Self.Font;
        GetTextMetrics(Canvas.Handle, TM);
        Result := Field.DisplayWidth * (Canvas.TextWidth('0') - TM.tmOverhang)
          + TM.tmOverhang + 4;
        if dgTitles in Options then
        begin
          Canvas.Font := Title.Font;
          W := Canvas.TextWidth(Title.Caption) + 4;
          if Result < W then
            Result := W;
        end;
      finally
        if RestoreCanvas then
        begin
          ReleaseDC(0,Canvas.Handle);
          Canvas.Handle := 0;
        end;
      end;
    end
    else
      Result := DefaultColWidth;
  end;
end;

procedure TLBColumn.FontChanged;
begin
  Include(FAssignedValues, cvFont);
  Title.RefreshDefaultFont;
  Changed(False);
end;

function TLBColumn.GetAlignment: TAlignment;
begin
  if cvAlignment in FAssignedValues then
    Result := FAlignment
  else
    Result := DefaultAlignment;
end;

function TLBColumn.GetColor: TColor;
begin
  if cvColor in FAssignedValues then
    Result := FColor
  else
    Result := DefaultColor;
end;

function TLBColumn.GetExpanded: Boolean;
begin
  Result := FExpanded and Expandable;
end;

function TLBColumn.GetField: TField;
var
  Grid: TLBCustomDBGrid;
begin    { Returns Nil if FieldName can't be found in dataset }
  Grid := GetGrid;
  if (FField = nil) and (Length(FFieldName) > 0) and Assigned(Grid) and
    Assigned(Grid.DataLink.DataSet) then
  with Grid.Datalink.Dataset do
    if Active or (not DefaultFields) then
      SetField(FindField(FieldName));
  Result := FField;
end;

function TLBColumn.GetFont: TFont;