frmbasicweave.frm

企业ERP系统 采用VB+SQL2000实现。 有客户合约

VERSION 5.00
Object = "{4932CEF1-2CAA-11D2-A165-0060081C43D9}#2.0#0"; "Actbar2.OCX"
Object = "{0ECD9B60-23AA-11D0-B351-00A0C9055D8E}#6.0#0"; "MSHFLXGD.OCX"
Begin VB.Form frmBasicWeave 
   Caption         =   "組織信息"
   ClientHeight    =   3195
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   4680
   LinkTopic       =   "Form1"
   MDIChild        =   -1  'True
   ScaleHeight     =   3195
   ScaleWidth      =   4680
   Begin ActiveBar2LibraryCtl.ActiveBar2 ActiveBar21 
      Height          =   11115
      Left            =   0
      TabIndex        =   0
      Top             =   0
      Width           =   15240
      _LayoutVersion  =   1
      _ExtentX        =   26882
      _ExtentY        =   19606
      _DataPath       =   ""
      Bands           =   "frmBasicWeave.frx":0000
      Begin VB.Frame Frame1 
         Height          =   8475
         Left            =   60
         TabIndex        =   1
         Top             =   540
         Width           =   15015
         Begin MSHierarchicalFlexGridLib.MSHFlexGrid MSHF1 
            Height          =   8115
            Left            =   120
            TabIndex        =   2
            Top             =   240
            Width           =   14775
            _ExtentX        =   26061
            _ExtentY        =   14314
            _Version        =   393216
            AllowUserResizing=   1
            BeginProperty Font {0BE35203-8F91-11CE-9DE3-00AA004BB851} 
               Name            =   "MS Sans Serif"
               Size            =   8.25
               Charset         =   0
               Weight          =   400
               Underline       =   0   'False
               Italic          =   0   'False
               Strikethrough   =   0   'False
            EndProperty
            _NumberOfBands  =   1
            _Band(0).Cols   =   2
         End
      End
   End
End
Attribute VB_Name = "frmBasicWeave"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Dim lngrow As Integer
Dim newItem As Boolean
Dim stateId As String
Private Sub ActiveBar21_ToolClick(ByVal Tool As ActiveBar2LibraryCtl.Tool)
    Select Case Tool.Name
    Case "cmdAdd":
        NewOperatorInf
    Case "cmdEdit":
        EditOperatorInf
    Case "cmdDel":
        DelOperatorInf
    Case "cmdCancel":
        Unload Me
    Case "cmdExport":
        Dim strFile As String
        frmMain.CDFile.ShowOpen
        strFile = frmMain.CDFile.FileName
        If strFile = "" Then Exit Sub
        ExportExcel MSHF1, strFile
    End Select
End Sub
Public Sub FillMshf1(ByVal strSql As String)
   Dim rs As ADODB.Recordset
   Dim lngrow As Long
      Screen.MousePointer = vbHourglass
      On Error GoTo errLabel
      Set rs = New ADODB.Recordset
      With rs
        .CursorLocation = adUseClient
        .CursorType = adOpenDynamic
        .LockType = adLockOptimistic
        Set .ActiveConnection = Cn
      End With
      rs.Open strSql
      With MSHF1
          .Redraw = False
          .Rows = 2
          '.FixedRows = 2
          .Cols = 5
          '.FixedCols = 3
          .Clear
          '初始化
         .WordWrap = False
         .TextMatrix(0, 0) = "序号"
         .TextMatrix(0, 1) = "英文名稱"
         .TextMatrix(0, 2) = "組織名稱"
         .TextMatrix(0, 3) = "填寫日期"
         .TextMatrix(0, 4) = "填寫人"
         .ColWidth(0) = 600
         .ColWidth(1) = 2000
         .ColWidth(2) = 4000
         .ColWidth(3) = 4000
         .ColWidth(4) = 4000
    '.....................................................
         .Rows = rs.RecordCount + 2
         On Error Resume Next
         For lngrow = 2 To rs.RecordCount + 1
                .TextMatrix(lngrow, 0) = lngrow - 1
                .TextMatrix(lngrow, 1) = Trim$(NullValue(rs.Fields!eWeave))
                .TextMatrix(lngrow, 2) = Trim$(NullValue(rs.Fields!Weave))
                .TextMatrix(lngrow, 3) = NullValue(rs.Fields!UpdateDate)
                .TextMatrix(lngrow, 4) = NullValue(rs.Fields!UpdateOperator)
                rs.MoveNext
          Next
          lngrow = 0
          .TextMatrix(1, 0) = "总计"
          .TextMatrix(1, 2) = .Rows - 2
           SetItemBackColor MSHF1
          .Redraw = True
      End With
      rs.Close
remClear:
    Set rs = Nothing
    Screen.MousePointer = vbDefault
    Exit Sub
errLabel:
    On Error Resume Next
    MSHF1.Redraw = True
    GoTo remClear
End Sub
Private Sub Form_Load()
    '设置窗口大小
    FormInit Me, True
    SetObjectWH Frame1
    SetObjectWH MSHF1
    FillMshf1 ("select * from tBasicWeave")
    ActiveBar21.Bands("toolbar").Tools.item("cmdDel").Enabled = False
    ActiveBar21.Bands("toolbar").Tools.item("cmdEdit").Enabled = False
    Me.Caption = "組織信息"
    HookWheel Me.hwnd
End Sub
'增加信息
Private Sub NewOperatorInf()
    frmBasicWeaveInfo.newItem = True
    frmBasicWeaveInfo.InitInfo ""
    frmBasicWeaveInfo.Show vbModal
    ActiveBar21.Bands("toolbar").Tools.item("cmdDel").Enabled = False
    ActiveBar21.Bands("toolbar").Tools.item("cmdEdit").Enabled = False
End Sub

'编辑信息
Private Sub EditOperatorInf()
    frmBasicWeaveInfo.newItem = False
    If lngrow = 1 Then Exit Sub
    frmBasicWeaveInfo.InitInfo MSHF1.TextMatrix(lngrow, 1)
    frmBasicWeaveInfo.Show vbModal
    ActiveBar21.Bands("toolbar").Tools.item("cmdDel").Enabled = False
    ActiveBar21.Bands("toolbar").Tools.item("cmdEdit").Enabled = False
End Sub

'删除信息
Private Sub DelOperatorInf()
    Dim strSql As String
    If lngrow > MSHF1.Rows - 1 Then Exit Sub
    If lngrow <= 1 Then
        MsgBox "请选中一条要删除的记录！", vbExclamation, "提示"
        Exit Sub
    End If
    On Error GoTo errHandle
    If MsgBox("确定要刪除？", vbQuestion + vbYesNo, "询问") = vbNo Then
        Exit Sub
    Else
        strSql = "delete from  tBasicWeave  where eWeave='" & MSHF1.TextMatrix(lngrow, 1) & "'"
        objDatabase.ExecCmd strSql
        MsgBox "刪除成功!", vbInformation, "提示"
    End If
    FillMshf1 ("select * from tBasicWeave")
    ActiveBar21.Bands("toolbar").Tools.item("cmdDel").Enabled = False
    ActiveBar21.Bands("toolbar").Tools.item("cmdEdit").Enabled = False
    Exit Sub
errHandle:

   objDatabase.DatabaseError
    
End Sub



Private Sub MSHF1_Click()
    lngrow = Val(MSHF1.row)
    If lngrow = 1 Then
       MSHF1.Sort = 1
    Else
       MSHF1.row = lngrow
        MSHF1.col = 0
        MSHF1.ColSel = MSHF1.Cols - 1
        ActiveBar21.Bands("toolbar").Tools.item("cmdDel").Enabled = True
        ActiveBar21.Bands("toolbar").Tools.item("cmdEdit").Enabled = True
    End If
End Sub

Private Sub MSHF1_DblClick()
   EditOperatorInf
End Sub