loader.lds.kernel

Hermit-at-1.1.3,一款bootloader

ENTRY(_start_ram)

MEMORY
{
	SRAM	: ORIGIN = 0x60000000, LENGTH = 0xc000
	DRAM1	: ORIGIN = 0xc0000000, LENGTH = 0x02000000
}

SECTIONS
{
	. = 0xC0028000;
	.text BLOCK(32):
	{
		__text_start = ABSOLUTE(.);

		*(.ram.boot)		/* must come first */
		*(.hermit.version)

		*(.text)		/* program text (code) */
		*(.text.*)		/* annotated text sections */
		*(.stub)
		*(.gnu.warning)
		*(.gnu.linkonce.t*)
		*(.glue_7t)
		*(.glue_7)
		*(.rodata)		/* read-only data */
		*(.rodata.*)		/* read-only data */
		*(.gnu.linkonce.r*)
		*(.rodata1)		/* read-only data */
		*(.sdata2)

		*(.eh_frame)
		*(.gcc_except_table)
		*(.got)			/* global offset table */
		*(.dynamic)

		*(.sdata)
		*(.sdata.*)
		*(.gnu.linkonce.s.*)

		*(.got.plt)

		__text_end = ABSOLUTE(.);
	} >DRAM1

	/* .data: initialized data (must be relocated to RAM) */
	.data BLOCK(32):
	{
		__data_start = ABSOLUTE(.);
		*(.data)		/* initialized writeable data */
		*(.data.*)		/* initialized writeable data */
		*(.gnu.linkonce.d*)
		*(.data1)
		__data_end = ABSOLUTE(.);
	} >DRAM1

	/* .bss: uninitialized data (must be zeroed) */
	.bss BLOCK(32):
	{
		__bss_start = ABSOLUTE(.);
		*(.sbss)
		*(.dynsbss)
		*(.sbss.*)
		*(.sbss2)
		*(.scommon)
		*(.bss)			/* uninitialized data (zeroed) */
		*(.dynbss)
		*(.bss.*)		/* uninitialized data (zeroed) */
		*(COMMON)
		__bss_end = ABSOLUTE(.);
	} >DRAM1

	/* .unused: stuff we don't want in the loader */
	.unused 0:
	{
		*(.ctors)		/* constructors */
		*(.dtors)		/* destructors */
		*(.init)		/* initialization code */
		*(.fini)		/* termination code */
		*(.note.ABI-tag)

		*(.interp)		/* path name of program interpreter */
		*(.hash)		/* symbol hash table */
		*(.dynsym)		/* dynamic linking symbol table */
		*(.dynstr)
		*(.gnu.version)
		*(.gnu.version_d)
		*(.gnu.version_r)
		*(.plt)			/* procedure linkage table */

		*(.rel.init)		/* relocation information... */
		*(.rela.init)
		*(.rel.text)
		*(.rela.text)
		*(.rel.fini)
		*(.rela.fini)
		*(.rel.rodata)
		*(.rela.rodata)
		*(.rel.data)
		*(.rela.data)
		*(.rel.ctors)
		*(.rela.ctors)
		*(.rel.dtors)
		*(.rela.dtors)
		*(.rel.got)
		*(.rela.got)
		*(.rel.sdata)
		*(.rela.sdata)
		*(.rel.sbss)
		*(.rela.sbss)
		*(.rel.sdata2)
		*(.rela.sdata2)
		*(.rel.sbss2)
		*(.rela.sbss2)
		*(.rel.bss)
		*(.rela.bss)
		*(.rel.plt)
		*(.rela.plt)

		*(.stab)		/* symbol table (debugging)... */
		*(.stabstr)
		*(.stab.excl)
		*(.stab.exclstr)
		*(.stab.index)
		*(.stab.indexstr)
	}
}