building.as

AS3代码 用于判断假3D图形的遮挡关系 请使用FLASH CS3或其他支持AS3语言的软件打开

package 
{
	import flash.display.Sprite;
	import flash.events.*;
	import flash.geom.Point;
	import flash.net.URLRequest;
	import flash.display.Loader;
	public class Building extends Sprite
	{
		private var firstpoint:Point=new Point();//左参考点位置
		private var secondpoint:Point=new Point();//右参考点位置
		public var leftpoint:Point=new Point();
		public var rightpoint:Point=new Point();
		private var picLoad:Loader;
		private var picReq:URLRequest;

		//初始化函数:获取图片的url和左右顶点的参考坐标
		public function Building (_picURL:String,_firstX:Number,_firstY:Number,_secondX:Number,_secondY:Number)
		{
			firstpoint.x=_firstX;
			firstpoint.y=_firstY;
			secondpoint.x=_secondX;
			secondpoint.y=_secondY;
			picLoad=new Loader();
			picReq=new URLRequest(_picURL);
			picLoad.load (picReq);
			picLoad.contentLoaderInfo.addEventListener (Event.COMPLETE,LoadCompletFun);
			addChild (picLoad);

		}
		//坐标系转换函数：将平面坐标转化为游戏坐标并返回
		private function TransformPointFun (_xpoint:Number,_ypoint:Number):Point
		{
			var point:Point=new Point();
			point.x=Math.round(_xpoint/0.89442718/2-_ypoint/0.44721359/2);
			point.y=Math.round(_xpoint/0.89442718/2+_ypoint/0.44721359/2);
			return point;
		}
		//初始化四个顶点的坐标，坐标系为游戏坐标
		private function InitPointFun ()
		{
			leftpoint=TransformPointFun(x + firstpoint.x,y + firstpoint.y);
			rightpoint=TransformPointFun(x + secondpoint.x,y + secondpoint.y);
		}
		//图片加载成功后执行的程序
		private function LoadCompletFun (evt:Event)
		{
			InitPointFun();
			addEventListener(MouseEvent.MOUSE_DOWN,MouseDownFun);
			addEventListener(MouseEvent.MOUSE_UP,MouseUpFun);
		}
		private function MouseDownFun(evt:MouseEvent)
		{
//			this.parent.setChildIndex(this,this.parent.numChildren-1);
			this.startDrag();
			//trace("您的点击:"+this.name);
		}
		private function MouseUpFun(evt:MouseEvent)
		{
			this.stopDrag();
		    InitPointFun();
		}
	}
}