const.asp

xml缓存类试用版用于ASP

<!--#include file="conn.asp"-->
<!--#include file="XmlCacheCls.asp"-->
<!--#include file="business.asp"-->
<%

'定义全局变量
Dim Rs,SQL
Dim FoundErr,ErrMsg,SucMsg
FoundErr = False

'=============================================================
'函数名称： PageListpage()
'参数说明： TotalPage 总页数 CurPage 当前页 filestr 文件路径
'			sPagesize 记录数 str 连接字符串			
'函数作用： 分页列表
'=============================================================
Private Function PageListpage(TotalPage,CurPage,sPagesize,filestr,str)
	IF CurPage>TotalPage Then CurPage=TotalPage
	
	IF CurPage<=1 Then
		Response.Write "<font face=webdings>9</font> "  & vbCrLf
		Response.Write "<font face=webdings>7</font> "  & vbCrLf
	Else
		Response.Write "<a href="""&filestr&str&"page=1""><font face=webdings>9</font></a> "  & vbCrLf
		Response.Write "<a href="""&filestr&str&"page="&CurPage-1&"""><font face=webdings>7</font></a> "  & vbCrLf
	End IF
	
	Dim PLine,StarPLine,EndPLine

	'计算起点和结束点
	IF TotalPage<=10 Then
		StarPLine=1
		EndPLine=TotalPage
	Else
		IF (TotalPage-CurPage)>3 Then
			IF CurPage>6 Then
				StarPLine=CurPage-5
				EndPLine=CurPage+4
			Else
				StarPLine=1
				EndPLine=10			
			End IF
		Else
			StarPLine=TotalPage-9
			EndPLine=TotalPage
		End IF
	End IF
	'写出分页
	For PLine=StarPLine To EndPLine
		IF PLine>TotalPage Then Exit Function
		IF PLine=CurPage Then
			Response.Write " <font color=""#FF0000"">"&PLine&"</font> "
		Else
			Response.Write " <a href="""&filestr&str&"page="&PLine&""">"&PLine&"</a> "
		End IF
		IF PLine<EndPLine And PLine<TotalPage Then
			Response.Write " "
		End IF
	Next
	
	IF CurPage>=TotalPage Then
		Response.Write " <font face=webdings>8</font>"  & vbCrLf
		Response.Write " <font face=webdings>:</font>"  & vbCrLf
	Else
		Response.Write " <a href="""&filestr&str&"page="&CurPage+1&"""><font face=webdings>8</font></a>"  & vbCrLf
		Response.Write " <a href="""&filestr&str&"page="&TotalPage&"""><font face=webdings>:</font></a>"  & vbCrLf
	End IF
	
	Response.Write " 跳到第"  & vbCrLf
	Response.Write "<input name=""page"" type=""text"" id=""page"" size=""1"" value="""&CurPage&""" style=""height:12px;width:24px"">"  & vbCrLf
	Response.Write "页 "  & vbCrLf
	Response.Write "<a href=""javascript:location.href='"&filestr&str&"page='+document.getElementById('page').value+''"">Go</a>"  & vbCrLf
	Response.Write ""  & vbCrLf
End Function
%>