transform.pas

Magio牛的usaco源代码

{
ID:maigoak1
PROG:transform
}

program transform;
const
  maxn=10;
var
  fin,fout:text;
  origin,tmp,target:array[1..maxn,1..maxn]of boolean;
  n,i,j:byte;
  c:char;
procedure change(mode:byte);
  var
    i,j:byte;
  begin
    for i:=1 to n do
      for j:=1 to n do
        case mode of
          1:tmp[j,n+1-i]:=origin[i,j];
          2:tmp[n+1-i,n+1-j]:=origin[i,j];
          3:tmp[n+1-j,i]:=origin[i,j];
          4:tmp[i,n+1-j]:=origin[i,j];
          5:tmp[n+1-j,n+1-i]:=origin[i,j];
          6:tmp[n+1-i,j]:=origin[i,j];
          7:tmp[j,i]:=origin[i,j];
          8:tmp[i,j]:=origin[i,j];
        end;
  end;
procedure check(code:byte);
  var
    i,j:byte;
  begin
    for i:=1 to n do
      for j:=1 to n do
        if tmp[i,j]<>target[i,j] then exit;
    writeln(fout,code);
    close(fout);
    halt;
  end;
begin
  assign(fin,'transform.in');
  reset(fin);
  readln(fin,n);
  for i:=1 to n do begin
    for j:=1 to n do begin
      read(fin,c);
      if c='@' then origin[i,j]:=true else origin[i,j]:=false;
    end;
    readln(fin);
  end;
  for i:=1 to n do begin
    for j:=1 to n do begin
      read(fin,c);
      if c='@' then target[i,j]:=true else target[i,j]:=false;
    end;
    readln(fin);
  end;
  close(fin);

  assign(fout,'transform.out');
  rewrite(fout);
  change(1);check(1);
  change(2);check(2);
  change(3);check(3);
  change(4);check(4);
  change(5);check(5);
  change(6);check(5);
  change(7);check(5);
  change(8);check(6);
  writeln(fout,7);
  close(fout);
end.