msvc50compp.stp

此程序是本人编写的在MFC环境下调用Matlab函数进行编程的实例

# $Revision: 1.6 $

use msvc_modules_installer;

sub msvc50compp 
{
    my $input = shift;
    my $default_location = "C:\\Program Files\\DevStudio";

    my $specified_compiler_location = "";

    my $language_handled_fcn = sub {
        my $lang = shift;
        
        return $lang eq "C" || $lang eq "CPP";
    };

    my $locate_fcn = sub {
        my @msvc5_roots = ();
        my $msvc5_root;
        my $registry_lookup_fcn = $input->{"registry_lookup"};

        if ($ENV{'MSVCDir'} ne "" && $ENV{'MSVCDir'} =~ /\\VC$/i &&
            -e "$ENV{'MSVCDir'}\\bin\\cl.exe")
        {
            $msvc5_root = $ENV{'MSVCDir'};
            $msvc5_root = substr($msvc5_root, 0, length($msvc5_root) - 3);
            push(@msvc5_roots, $msvc5_root);
        }

        if ($ENV{'MSDEVDIR'} ne "" && $ENV{'MSDEVDIR'} =~ /\\SharedIDE$/i
               && -e "$ENV{'MSDEVDIR'}\\..\\VC\\bin\\cl.exe")
        {
            $msvc5_root = $ENV{'MSDEVDIR'};
            $msvc5_root =~ s|\\SharedIDE$||i;
            push(@msvc5_roots, $msvc5_root);
        }

        $msvc5_root = &$registry_lookup_fcn("SOFTWARE\\Microsoft\\DevStudio\\5.0\\Directories",
                                            "ProductDir");
        if (-e "$msvc5_root\\VC\\bin\\cl.exe")
        {
            push(@msvc5_roots, $msvc5_root);
        }

        if (-e "$default_location")
        {
            push(@msvc5_roots, $default_location);
        }

        return @msvc5_roots;
    };

    my $root_val = sub {
        my $base_directory = shift;

        $specified_compiler_location = $base_directory; # Remember this for post_setup_hook

        # Since the Microsoft Visual C environment variable MSVCDir actually points to the
        # VC subdirectory of MSVC 5.0, we need to tack on the \VC to the base compiler
        # location.
        return $base_directory . "\\VC";
    };

    my $post_setup_hook = sub {
        my @filetable = (["MATLABWizard.awx",      "\\sharedide\\template"],
                         ["MATLABWizard.hlp",      "\\sharedide\\template"],
                         ["MATLABAddin.dll",       "\\sharedide\\addins"],
                         ["usertype.dat",          "\\sharedide\\bin"]);

        &install_msvc_modules($specified_compiler_location, \@filetable, $input->{'matlab_bin'});
    };

    return {
        "vendor_name"  => "Microsoft Visual C/C++",
        "version"      => "5.0",
        "group_id"     => "MSVC",
        "serial"       => 2.0,
        "root_var"     => "MSVCDir",
        "optfile_name" => "msvc50compp.bat",
        "default_location" => $default_location,
        "language_handled" => $language_handled_fcn,
        "root_val"     => $root_val,
        "locate"       => $locate_fcn,
        "post_setup_hook"  => $post_setup_hook
        };
}
1;