tkagent_tool

mobile ip 在linux下的一种实现

#!/usr/bin/wish
# $Id: tkagent_tool,v 1.4 2000/04/06 07:26:53 jm Exp $
# Agent Configuration Tool 

# Dynamic hierarchial IP tunnel
# Copyright (C) 1998-2000, Dynamics group

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License version 2 as
# published by the Free Software Foundation. See README and COPYING for
# more details.


if { $argc != 1 } {
    puts "Usage: $argv0 <tool_name>"
    exit
}

set tool [lindex $argv 0]

wm title . "Dynamics Configuration Tool ($tool)"

frame .top -border 5
pack .top -side top -fill x

# buttons
frame .left -border 10
pack .left -side left -fill y

button .left.statusbutton -text Status -command Status
button .left.listbutton -text List -command List
button .left.showbutton -text Show -command Show
button .left.destroybutton -text Destroy -command Destroy
button .left.quitbutton -text Quit -command exit
pack .left.listbutton -side top -fill x
pack .left.statusbutton -side top -fill x
pack .left.showbutton -side top -fill x
pack .left.destroybutton -side top -fill x
pack .left.quitbutton -side bottom -fill x


# results
frame .resframe
pack .resframe -side left -fill both -expand y

set idlist [listbox .resframe.idlist -width 15]
pack $idlist -side left -fill y 

set restext [text .resframe.restext -width 40 -height 10]
pack .resframe.restext -side left -fill both -expand y


proc List {} {
    global idlist tool
    $idlist delete 0 end
    set l [split [exec $tool list] \n]
    foreach id $l {
	if { $id != {} } {
	    $idlist insert end $id
	}
    }
}

proc ShowText { text } {
    global restext
    $restext config -state normal
    $restext delete 1.0 end
    $restext insert end $text
    $restext config -state disabled 
}

proc Status {} {
    global tool
    ShowText [exec $tool status]
}

proc Show {} {
    global idlist restext tool
    set id [$idlist get active]
    if { $id != {} } {
	ShowText [exec $tool show $id]
    }
}

proc Destroy {} {
    global idlist tool
    set id [$idlist get active]
    if { $id != {} } {
	ShowText [exec $tool destroy $id]
    }
    List
}