decript.inc

汽车遥控制的源代码.用的单片机是PIC16F72. 大批量生产.

DECRYPT
	MOVLW   11+1            
        MOVWF   CNT1          

DECRYPT_OUTER
        MOVLW   48              
        MOVWF   CNT0          

DECRYPT_INNER
	CLRWDT			
        MOVFW   CNT1	
        XORLW   1            
        SKPNZ                   
        GOTO    ROTATE_KEY      

      
							
        CLRC                   
       
        MOVLW   1               
        BTFSC   HOP3,3       
        MOVLW   10000B          
        MOVWF   MASK            

        BTFSS   HOP2,0       
        GOTO    $+3
        RLF     MASK,F
        RLF     MASK,F            

        BTFSC   HOP1,0       	
        RLF     MASK,F

        ; MASK HAS NOW BEEN SHIFTED 0-7 TIMES ACCORDING TO BITS 2:1:0

        MOVLW   0             
        BTFSC   HOP4,1
        IORLW   2               
        BTFSC   HOP4,6
        IORLW   4               

        ADDWF   PCL,F           
				
                               
TABLE
        MOVLW   02EH            
        GOTO    TABLE_END       

        MOVLW   074H            
        GOTO    TABLE_END      

        MOVLW   05CH            
        GOTO    TABLE_END       

        MOVLW   03AH            
                                 
TABLE_END
        ANDWF   MASK,F          
        MOVLW   0               
        SKPZ                    
        MOVLW   10000000B       

        XORWF   HOP2,W    
        XORWF   HOP4,W    	
        XORWF   KEY1,W		

        MOVWF   MASK           
        RLF     MASK,F          

        RLF     HOP1,F         
        RLF     HOP2,F
        RLF     HOP3,F
        RLF     HOP4,F

ROTATE_KEY
        CLRC		
        BTFSC   KEY7,7       	
        SETC                    

        RLF     KEY0,F         	
        RLF     KEY1,F
        RLF     KEY2,F
        RLF     KEY3,F
        RLF     KEY4,F
        RLF     KEY5,F
        RLF     KEY6,F
        RLF     KEY7,F       
	

        DECFSZ  CNT0,F         
        GOTO    DECRYPT_INNER   

        DECFSZ  CNT1,F         	
        GOTO    DECRYPT_OUTER   
        
        RETLW   0