stripeshape.as

使用as3.0重新写了播放器 播放器大小缩小,在21k左右 新参数和vcastr2.x不同 可以通过xml对播放器设置 界面更新 增加音量控制 留出了插件的接口

package com.ruochi.shape{
	import flash.display.Sprite;
	import flash.geom.Rectangle;
	public class StripeShape extends Sprite {
		private var _w:Number;
		private var _h:Number;
		private var _color1:uint;
		private var _color2:uint;
		public function StripeShape(w:Number = 80, h:Number = 10, c1:uint = 0xffffff, c2:uint = 0 ) {
			super()
			_w = w;
			_h = h;
			_color1 = c1;
			_color2 = c2;
			buildUI();
		}
		private function buildUI():void {
			graphics.clear();
			graphics.beginFill(_color1);
			graphics.drawRect(0, 0, _w, _h);
			graphics.endFill();
			var num:int = _w/_h/2;
			graphics.beginFill(_color2);			
			for (var i:int = 0; i < num; i++) {
				graphics.moveTo(i*2 * _h, _h);
				graphics.lineTo((i*2 + 1) * _h, 0);
				graphics.lineTo((i*2 + 2) * _h, 0);
				graphics.lineTo((i*2 + 1) * _h, _h);
				graphics.lineTo(i*2 * _h, _h);
			}
			graphics.endFill();
		}
		public function set color1(c:uint):void {
			_color1 = c;
			buildUI();
		}
		public function get color1():uint {
			return _color1;
		}
		public function set color2(c:uint):void {
			_color2 = c;
			buildUI();
		}
		public function get color2():uint {
			return _color2;
		}
	}
}