advancesearch.asp

客户资源管理系统 1.显示所有客户资料 2.添加/修改客户资料； 3.添加客户拜访记录； 4.模糊搜索； 5.数据导出导入excal-access； 6.信息录入人员管理； 7.数据转移

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%
Option Explicit
Response.Buffer = True
Response.Expires = 0
Response.Expiresabsolute = Now() - 1 
Response.AddHeader "pragma","no-cache" 
Response.AddHeader "cache-control","private" 
Response.CacheControl = "no-cache"
%>
<!--#include file="Connections/conn.asp" -->

<!--登录权限判断，Session和MD5加密判断-->
<%
Rem Session("CRM_account") 用户帐号
Rem Session("CRM_name") 用户名
Rem Session("CRM_level") 用户等级

If Session("CRM_account") = "" Or Session("CRM_name") = "" Or Session("CRM_level") <= 0 Then Response.Redirect("login.asp")

Dim action
action = Trim(Request("action"))
If action = "killSession" Then Session("CRM_sql") = ""

Dim strCounter,strToPrint

Function getGroupName(gId)
    If gId = "" Then
	    getGroupName = ""
	Else
	    Dim rs
		Set rs = Server.CreateObject("ADODB.Recordset")
		rs.Open "Select * From baidu_group Where gId = " & gId,conn,3,1
		If rs.RecordCount <> 1 Then
		    getGroupName = ""
		Else
		    getGroupName = rs("gName")
		End If
		rs.Close
		Set rs = Nothing
	End If
End Function

Function getGroup(gName)
    If gName = "" Then
	    getGroup = 0
	Else
	    Dim rs
		Set rs = Server.CreateObject("ADODB.Recordset")
		rs.Open "Select * From baidu_group Where gName = '" & gName & "'",conn,3,1
		If rs.RecordCount <> 1 Then
		    getGroup = 0
		Else
		    getGroup = rs("gId")
		End If
		rs.Close
		Set rs = Nothing
	End If
End Function

Function getUserList(intLevel,intGroup)
    Dim rs,strUserList
	strUserList = "'" & Session("CRM_name") & "'"
	Set rs = Server.CreateObject("ADODB.Recordset")
	rs.Open "Select * From baidu_user Where uLevel < " & intLevel & " And uGroup = " & intGroup,conn,3,1
	Do While Not rs.BOF And Not rs.EOF
	    If strUserList = "" Then
		    strUserList = "'" & rs("uName") & "'"
		Else
		    strUserList = strUserList & ",'" & rs("uName") & "'"
		End If
		rs.MoveNext
	Loop
	rs.Close
	Set rs = Nothing
	getUserList = strUserList
End Function

''生成下拉列表
Function getList(i,sTable,iId,sValue,sName,selfValue)
    If i < 1 Or i > 2 Then
	    getList = ""
		Exit Function
	End If
	Dim strList
	Dim rs
	If i = 1 Then
	    strList = "<select name=""" & sName & """ selfValue=""" & selfValue & """>"
		strList = strList & "<option value="""">请选择</option>"
		Set rs = Server.CreateObject("ADODB.Recordset")
		rs.Open "Select * From " & sTable & "",conn,3,1
		Do While Not rs.BOF And Not rs.EOF
		    strList = strList & "<option value=""" & rs(sValue) & """>" & rs(sValue) & "</option>"
			rs.MoveNext
		Loop
		rs.Close
		Set rs = Nothing
		strList = strList & "</select>"
		getList = strList
	Else
	    strList = "<select name=""" & sName & """ selfValue=""" & selfValue & """>"
		strList = strList & "<option value="""">请选择</option>"
		Set rs = Server.CreateObject("ADODB.Recordset")
		rs.Open "Select * From " & sTable & "",conn,3,1
		Do While Not rs.BOF And Not rs.EOF
		    strList = strList & "<option value=""" & rs(iId) & """>" & rs(sValue) & "</option>"
			rs.MoveNext
		Loop
		rs.Close
		Set rs = Nothing
		strList = strList & "</select>"
		getList = strList
	End If
End Function

Dim subAction
subAction = Trim(Request("subAction"))

If subAction = "searchItem" Then
    Dim cCompany,cLinkman,cTel,cZip,cfax,cUser,cType,cAddress,cGroup
	Dim arrUser
	cCompany = Trim(Request("company"))
	cLinkman = Trim(Request("linkman"))
	cTel = Trim(Request("tel"))
	cZip = Trim(Request("Zip"))
	cfax = Trim(Request("fax"))
	cAddress = Trim(Request("address"))
	cType = Trim(Request("type"))
	cUser = Trim(Request("user"))
	cGroup = Request("group")
	If cGroup <> "" Then
	    cGroup = CInt(Abs(cGroup))
	End If
	
	Dim sql
    sql = ""
    If cCompany <> "" Then
        If sql = "" Then
            sql = sql & " Where cCompany Like '%" & cCompany & "%'"
	    Else
	        sql = sql & " And cCompany Like '%" & cCompany & "%'"
        End If
	End If
	
	
    If cLinkman <> "" Then
        If sql = "" Then
            sql = sql & " Where cLinkman Like '%" & cLinkman & "%'"
	    Else
	        sql = sql & " And cLinkman Like '%" & cLinkman & "%'"
        End If
	End If
	
	If cTel <> "" Then
        If sql = "" Then
            sql = sql & " Where cTel Like '%" & cTel & "%'"
	    Else
	        sql = sql & " And cTel Like '%" & cTel & "%'"
        End If
	End If
	
	If czip <> "" Then
        If sql = "" Then
            sql = sql & " Where czip Like '%" & czip & "%'"
	    Else
	        sql = sql & " And czip Like '%" & czip & "%'"
        End If
	End If
	
	If cfax <> "" Then
        If sql = "" Then
            sql = sql & " Where cfax Like '%" & cfax & "%'"
	    Else
	        sql = sql & " And cfax Like '%" & cfax & "%'"
        End If
	End If
	
    If cAddress <> "" Then
        If sql = "" Then
            sql = sql & " Where cAddress Like '%" & cAddress & "%'"
	    Else
	        sql = sql & " And cAddress Like '%" & cAddress & "%'"
        End If
	End If
	
    If cType <> "" Then
        If sql = "" Then
            sql = sql & " Where cType = '" & cType & "'"
	    Else
	        sql = sql & " And cType = '" & cType & "'"
        End If
	End If
		
	If cGroup <> "" And IsNumeric(cGroup) Then
        If sql = "" Then
            sql = sql & " Where cGroup = " & cGroup
	    Else
	        sql = sql & " And cGroup = " & cGroup
        End If
	End If
	
	If Session("CRM_level") < 9 Then
        If cUser <> "" Then
    	    arrUser = Split(getUserList(Session("CRM_level"),Session("CRM_group")),",")
	        Dim k,flag
	        flag = 0
    	    For k = 0 To UBound(arrUser) - 1
    	        If Replace(arrUser(k),"'","") = cUser Then
    		        flag = 1
    		    	Exit For
    		    End If
    	    Next
            If flag = 1 Then
                If sql = "" Then
                    sql = sql & " Where cUser = '" & cUser & "'"
    	        Else
    	            sql = sql & " And cUser = '" & cUser & "'"
                End If
    		Else
    		    If sql = "" Then
                    sql = sql & " Where cUser = '权限不允许的用户'"
    	        Else
    	            sql = sql & " And cUser = '权限不允许的用户'"
                End If
    	    End If
    	Else
    	    If sql = "" Then
                sql = sql & " Where cUser In (" & getUserList(Session("CRM_level"),Session("CRM_group")) & ")"
    	    Else
    	        sql = sql & " And cUser In (" & getUserList(Session("CRM_level"),Session("CRM_group")) & ")"
            End If
    	End If
	Else
	    If cUser <> "" Then
	        If sql = "" Then
                sql = sql & " Where cUser = '" & cUser & "'"
        	Else
    	        sql = sql & " And cUser = '" & cUser & "'"
            End If
		End If
	End If
End If

If cCompany = "" And cLinkman = "" And cTel = "" And cAddress = "" And cType = "" And cUser = "" And cGroup = "" And czip = "" And cfax = "" Then
    If Session("CRM_sql") <> "" Then
        sql = Session("CRM_sql")
	Else
	    If Session("CRM_level") < 9 Then
		    sql = " Where cUser In (" & getUserList(Session("CRM_level"),Session("CRM_group")) & ")"
		End If
	End If
Else
    Session("CRM_sql") = sql
End If

'If Session("CRM_level") < 9 Then
'    If sql = "" Then
'	    sql = sql & " Where cUser In (" & getUserList(Session("CRM_level"),Session("CRM_group")) & ")"
'	Else
'	    sql = sql & " And cUser In (" & getUserList(Session("CRM_level"),Session("CRM_group")) & ")"
'	End If
'End If

strToPrint = strToPrint & "        <tr>" & VBCrlf
strToPrint = strToPrint & "          <td width=""7%""  align=""center"" bgcolor=""menu"">编　号</td>" & VBCrlf
strToPrint = strToPrint & "          <td width=""10%"" align=""center"" bgcolor=""menu"">录入时间</td>" & VBCrlf
strToPrint = strToPrint & "          <td width=""30%"" align=""center"" bgcolor=""menu"">公司名称</td>" & VBCrlf
strToPrint = strToPrint & "          <td width=""30%"" align=""center"" bgcolor=""menu"">公司地址</td>" & VBCrlf
strToPrint = strToPrint & "          <td width=""7%""  align=""center"" bgcolor=""menu"">联 系 人</td>" & VBCrlf
strToPrint = strToPrint & "          <td width=""9%""  align=""center"" bgcolor=""menu"">客户类型</td>" & VBCrlf
strToPrint = strToPrint & "          <td width=""7%""  align=""center"" bgcolor=""menu"">业 务 员</td>" & VBCrlf
strToPrint = strToPrint & "        </tr>" & VBCrlf

Dim rs,intTotalRecords,intTotalPages,intCurrentPage,intPageSize
intCurrentPage = CInt(ABS(Request("pageNum")))
If Not IsNumeric(intCurrentPage) Or intCurrentPage <= 0 Then intCurrentPage = 1
intPageSize = 40

Set rs = Server.CreateObject("ADODB.Recordset")
'Response.Write(sql)
'Response.End()
rs.Open "Select * From baidu_client" & sql & " Order By cId",conn,3,1
intTotalRecords = rs.RecordCount
rs.PageSize = intPageSize
intTotalPages = rs.PageCount
If intCurrentPage > intTotalPages Then intCurrentPage = intTotalPages
If intTotalRecords > 0 Then rs.AbsolutePage = intCurrentPage
strCounter = strCounter & "共 " & intTotalRecords & " 条记录 "
strCounter = strCounter & "共 " & intTotalPages & " 页 "
strCounter = strCounter & "当前第 " & intCurrentPage & " 页 "
If intCurrentPage <> 1 And intTotalRecords <> 0 Then
    strCounter = strCounter & "<a href=""?pageNum=1""><<首页</a> "
Else
    strCounter = strCounter & "<<首页 "
End If
If intCurrentPage > 1 Then
    strCounter = strCounter & "<a href=""?pageNum=" & intCurrentPage - 1 & """><上一页</a> "
Else
    strCounter = strCounter & "<上一页 "
End If
If intCurrentPage < intTotalPages Then
    strCounter = strCounter & "<a href=""?pageNum=" & intCurrentPage + 1 & """>下一页></a> "
Else
    strCounter = strCounter & "下一页> "
End If
If intCurrentPage <> intTotalPages Then
    strCounter = strCounter & "<a href=""?pageNum=" & intTotalPages & """>尾页>></a>"
Else
    strCounter = strCounter & "尾页>>"
End If

Dim i
i = 0
Do While Not rs.BOF And Not rs.EOF
    i = i + 1
    strToPrint = strToPrint & "        <tr>" & VBCrlf
    strToPrint = strToPrint & "          <td align=""center"">" & rs("cId") & "</td>" & VBCrlf
    strToPrint = strToPrint & "          <td align=""center"">" & rs("cdate") & "</td>" & VBCrlf
    strToPrint = strToPrint & "          <td><a href=""view.asp?cId=" & rs("cId") & """>" & rs("cCompany") & "</a></td>" & VBCrlf
	strToPrint = strToPrint & "        <td>" & rs("caddress") & "</td>" &  VBCrlf
	strToPrint = strToPrint & "        <td align=""center"">" & rs("clinkman") & "</td>" &  VBCrlf
	strToPrint = strToPrint & "        <td align=""center"">" & rs("cType") & "</td>" & VBCrlf
        strToPrint = strToPrint & "        <td align=""center"">" & rs("cUser") & "</td>" & VBCrlf
    If i >= intPageSize Then Exit Do
	rs.MoveNext
Loop
rs.Close