ramp.asm

包含几个高效的矢量运算的数学函数

	.include "ccall.asm"
	
	.def _ti_ramp
_ti_ramp:
	pre_ccall 5,AR_Y,AR_A,AR_INC,AR_INCEXP,AR_N
	
	sar AR_INCEXP,*
	lt *
	
	; Modify any registers needed
	setc SXM
	; Note: Overflow mode is off in C.

;STACK
; stack[0]=INC

	sar AR_INC,*
	lacc *
	sar AR_A,*

	bcnd POSITIVE,GT 
; If INC is negative, add .999 to A for good quantization	
	lacc *,16 
	add #07fffh,1
	b SKIP
POSITIVE:	
	lacc *,16

SKIP:	
; Compute N%7 to make N divisible by 8 in the unrolled loop	
	; Save ACC
	sacl *+				; stack[0]=ACC_L
	sach *+				; stack[1]=ACC_H
	
	sar AR_N,*			; stack[2]=N
	lacl *+				; acc=N
	and #07h			; acc&=0111b - Unroll 8 iterations
	sacl *-				; stack[3] = N % 0111b
	lacc *,13			; acch=stack[2]>>3=N>>3
	sach *+				; stack[2]=N>>3
	lar AR_N,*-			; AR_N = stack[3] = N%7
	mar *-

	; Restore ACC
	lacc *-,16			; acch=stack[1]
	add *,AR_STACK		; acc+=stack[0]
	sar AR_INC,*,AR_N	; stack[0]=AR_INC

	banz NEXT0,AR_Y	; Skip loop if AR_X = 0
	b NEXT1

NEXT0:
	sach *+,AR_STACK ; Y[i]=ACC
	addt *,AR_N
	banz NEXT0,AR_Y

NEXT1:
	mar *,AR_STACK
	adrk #2
	lar AR_N,*- ; AR_N = stack[2]=N>>3
	mar *-,AR_N
	banz NEXT2,AR_Y		; Go to 8x loop if AR_X > 0
	b DONE

NEXT2:
 .loop 7                     
	sach *+,AR_STACK ; Y[i]=ACC
	addt *,AR_Y
 .endloop
	sach *+,AR_STACK ; Y[i]=ACC
	addt *,AR_N
	; while(N--)
	banz NEXT2,AR_Y

	
; Begin C Post Processing
DONE:
   post_ccall 5