mult16.asm

包含几个高效的矢量运算的数学函数

	.include "ccall.asm"

	.def _ti_mult16
_ti_mult16:

******************
* INITIALIZATION *
******************
	pre_ccall 7,AR_X,AR_XEXP,AR_Y,AR_YEXP,AR_Z,AR_ZEXP,AR_N
	spm	#1 ; Shift product left one to delete redundant sign bit.
	setc SXM

	sar AR_XEXP,*
	lacc *
	sar AR_YEXP,*
	add *,AR_ZEXP
	sacl *,AR_STACK
	
	; Local variables (and parameters) will be set up as follows:
	;
	; get arguments and place them properly - take the from the
	; software stack and place them into their correct positions

	; Local variables
	; N%8 - stack[0]
	; N/8 - stack[1]
	

; Compute N%7 to make N divisible by 8 in the unrolled loop	
	sar AR_N,*			; stack[0]=N         
	lacl *+				; acc=N
	and #07h			; acc&=0111b - Unroll 8 iterations
	sacl *-				; stack[1] = N % 0111b
	lacc *,13			; acch=N>>3
	sach *+				; stack[0]=N>>3
	lar AR_N,*-,AR_N		; AR_Y = stack[1] = N%7
	banz NEXT0,AR_X		; Skip loop if AR_X = 0
	b NEXT1

NEXT0:
	; z[AR_Z++]=x[AR_X++]*y[AR_Y++]
	lt *+,AR_Y 			; TREG = x[AR_X++];
	mpy *+,AR_Z 			; PREG = TREG * y[AR_Y++];
	sph *+,AR_N 			; z[AR_Z++] = PREG >> 16;
		
	; while(AR_N--)
	banz NEXT0,AR_X

NEXT1:
	mar *,AR_STACK
	lar AR_N,*,AR_N ; AR_Y = stack[0]=N>>3 
	banz NEXT2,AR_X		; Go to 8x loop if AR_X > 0
	b DONE

NEXT2:
	; z[AR_Z++]=x[AR_X++]*y[AR_Y++]
	.loop 7
	lt *+,AR_Y 			; TREG = x[AR_X++];
	mpy *+,AR_Z 			; PREG = TREG * y[AR_Y++];
	sph *+,AR_X 			; z[AR_Z++] = PREG >> 16;
	.endloop
	lt *+,AR_Y 			; TREG = x[AR_X++];
	mpy *+,AR_Z 			; PREG = TREG * y[AR_Y++];
	sph *+,AR_N 			; z[AR_Z++] = PREG >> 16;
	; while(AR_N--)
	banz NEXT2,AR_X

DONE:
   spm #0    			; Restore product shift mode to 0
	post_ccall 7