add.asm

包含几个高效的矢量运算的数学函数

	.include "ccall.asm"
	
	.def _ti_add
_ti_add:
	pre_ccall 7,AR_X,AR_XEXP,AR_Y,AR_YEXP,AR_Z,AR_ZEXP,AR_N
   
	; Modify any registers needed
	; Note: Overflow mode is off in C.

	setc sxm
	
;;; We need to ensure YEXP>XEXP.  If not, swap X and Y.
	sar AR_YEXP,*
	lacc *
	sar AR_XEXP,*      
	sub *
	bcnd SKIP1,geq
;; XEXP>YEXP.. so swap.
; Swap X and Y
	sar AR_X,*+
	sar AR_Y,*-
	lar AR_Y,*+
	lar AR_X,*-
; Swap XEXP and YEXP
	sar AR_XEXP,*+
	sar AR_YEXP,*-
	lar AR_YEXP,*+
	lar AR_XEXP,*-

SKIP1:	
;;; YEXP>XEXP now.
;; If YEXP-XEXP>15 just return Y.
	sar AR_YEXP,*
	lacc *,AR_ZEXP
	sub #1
	sacl *,AR_STACK
	sar AR_XEXP,*
	sub *
	sacl * ; stack[0]=YEXP-XEXP
	sub #14
	bcnd SKIP2,leq
;;; YEXP-1-XEXP>15-1 in this case.
;; Copy Y to Z
	mar *,AR_ZEXP
	lacc *
	add #1
	sacl *,AR_N
	banz LOOP1,AR_Y
	b DONE
LOOP1:
	lacc *+,AR_Z
	sacl *+,AR_N
	banz LOOP1,AR_Y
	b DONE

SKIP2:	
;;; YEXP-XEXP<=15 in this case:

;; TREG = 15-(YEXP-XEXP)
	lacl #15
	sub *
	sacl *
	lt *
	
; Compute N%7 to make N divisible by 8 in the unrolled loop	
	sar AR_N,*			; stack[0]=N         
	lacl *+				; acc=N
	and #07h			; acc&=0111b - Unroll 8 iterations
	sacl *-				; stack[1] = N % 0111b
	lacc *,13			; acch=N>>3
	sach *+				; stack[0]=N>>3
	lar AR_N,*-,AR_N	; AR_N = stack[1] = N%7
	banz NEXT0,AR_Y	; Skip loop if AR_X = 0
	b NEXT1

;; Add (Y<<15)+(X<<(YEXP-XEXP)) and store in Z
NEXT0:
	lacc *+,15,AR_X
	addt *+,AR_Z
	sach *+,AR_N
	banz NEXT0,AR_Y

NEXT1:
	mar *,AR_STACK
	lar AR_N,*,AR_N ; AR_N = stack[0]=N>>3
	banz NEXT2,AR_Y		; Go to 8x loop if AR_X > 0
	b DONE

NEXT2:
 .loop 7                     
	lacc *+,15,AR_X
	addt *+,AR_Z
	sach *+,AR_Y
 .endloop
	lacc *+,15,AR_X
	addt *+,AR_Z
	sach *+,AR_N
	; while(N--)
	banz NEXT2,AR_X
	
DONE:
	post_ccall 7

	ret