17_0809.asm

可作为接口实验的参考教材

;//****************************************************************
;文件名:并行A/D转换器ADC0809转换程序  FOR 8088 

;功能: 把模拟信号转换成数字量，并通过数码显示被转换的数字量。

;接线: 连接并行模数转换模块的CS_0809到CPU模块的200H,+Vref到+5V电源;
;      IN-0接到电位器模块的0～5V输出。
;//****************************************************************

Z8279    EQU       239H
D8279    EQU       238H

D0809    EQU       200H
LEDMOD   EQU       00    ; 左边输入,八位显示外部译码八位显示
LEDFEQ   EQU       38H   ; 扫描频率
CODE     SEGMENT
ASSUME    CS:CODE,DS:code

START:   push      cs
         pop       ds
         call      delay
         MOV       DX,Z8279
         MOV       AL,LEDMOD
         OUT       DX,AL

         MOV       AL,LEDFEQ
         OUT       DX,AL

         MOV       CX,06H
XZ:      MOV       DX,D8279
         MOV       AL,00H
         OUT       DX,AL
         LOOP      XZ

         MOV       DX,D8279
         MOV       AL,5eH
         OUT       DX,AL
         MOV       DX,D8279
         MOV       AL,77H
         OUT       DX,AL           ;以上为写(AD)
         NOP
bg:
         mov       dx,D0809
         mov       al,0
         out       dx,al
         call      delay
         in        al,dx           ;  读入结果
         MOV       AH,AL
         and       al,0fh
         push      ax
         mov       dx,z8279
         mov       al,80h
         out       dx,al
         pop       ax
         LEA       BX,LED
         XLAT
         MOV       DX,D8279          ;将AL中内容写到数码管上
         OUT       DX,AL
         MOV       AL,AH
         mov       cl,4
         ror       al,cl
         and       al,0fh  
         push      ax
         mov       dx,z8279
         mov       al,81h
         out       dx,al
         pop       ax
         LEA       BX,LED
         XLAT
         MOV       DX,D8279          ;将AL中内容写到数码管上
         OUT       DX,AL                
         call      delay
         JMP       BG
         
delay    proc      near
         push      cx
         mov       cx,01f00h
         loop      $
         pop       cx
         ret
         delay     endp
         
LED      DB  3FH,06H,5BH,4FH,66H,6DH,7DH,07H
         DB  7FH,6FH,77H,7CH,39H,5EH,79H,71H
         
         CODE  ENDS
END      START