editor_chkpurview.asp

依蓝旅游网站管理系统Elan2008.SP2

<%
Option Explicit
Response.Buffer = True 
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1 
Response.CacheControl = "no-cache" 
%>
<!--#include file="../Conn.asp"-->
<%

Dim ChannelID, ShowType, FilesPath, IsUpload, CheckType
Dim UserID, UserName, UserPassword, UserRndPassword

ChannelID = Trim(ReplaceBadChar(request("ChannelID")))
ShowType = EL_CLng(Trim(request("ShowType")))

If ChannelID = "" Then
    Call CloseConn()
    response.write "频道参数丢失！"
    response.End
Else
    ChannelID = EL_CLng(ChannelID)
End If

If ShowType = 5 And ChannelID = 9 Then
   UserID = ReplaceBadChar(Trim(Request.Cookies("User_"& EL_Sn)("UserID")))
   UserName = ReplaceBadChar(Trim(Request.Cookies("User_"& EL_Sn)("UserName")))
   UserPassword = ReplaceBadChar(Trim(Request.Cookies("User_"& EL_Sn)("UserPassword")))
   UserRndPassword = ReplaceBadChar(Trim(Request.Cookies("User_"& EL_Sn)("UserRndPassword")))   
   CheckType = 2
Else
   UserID = ReplaceBadChar(Trim(request.Cookies("Admin_"& EL_Sn)("AdminID"))) 
   UserName = ReplaceBadChar(Trim(request.Cookies("Admin_"& EL_Sn)("AdminName")))
   UserPassword = ReplaceBadChar(Trim(Request.Cookies("Admin_"& EL_Sn)("AdminPassword")))
   UserRndPassword = ReplaceBadChar(Trim(Request.Cookies("Admin_"& EL_Sn)("AdminRndPassword")))
   CheckType = 1
End If

If UserID = "" Or UserName = "" Or UserPassword="" Or UserRndPassword="" Then
   Call CloseConn()
   Response.Write "请先登录后再使用此功能！"
   Response.End
End If

If ChannelID > 0 Then
   Dim CheckCmd
   Set CheckCmd = Server.CreateObject("ADODB.COMMAND")
   With CheckCmd
	  .ActiveConnection = Conn
	  .CommandText = "EL_SP_EditorPurview"
	  .CommandType = 4
	  .Prepared = True
	  .Parameters.Append .CreateParameter("RETURN", 2, 4)
	  .Parameters.Append .CreateParameter("@CheckType", 3, 1, 4, CheckType)
	  .Parameters.Append .CreateParameter("@AdminID", 3, 1, 4, UserID)
	  .Parameters.Append .CreateParameter("@AdminName", 200, 1, 50, UserName)
	  .Parameters.Append .CreateParameter("@Password", 200, 1, 32, UserPassword)
	  .Parameters.Append .CreateParameter("@RndPassword", 200, 1, 32, UserRndPassword)
	  .Parameters.Append .CreateParameter("@ChannelID", 3, 1, 4, ChannelID)
	  .Parameters.Append .CreateParameter("@Disabled", 11, 2, 1)
	  .Parameters.Append .CreateParameter("@EnableUpload", 11, 2, 1)
	  .Parameters.Append .CreateParameter("@ChannelDir", 200, 2, 20)
	  .Parameters.Append .CreateParameter("@UploadDir", 200, 2, 20)
	  .Execute()
   End With

   Select Case CheckCmd(0)
   Case 40:
        Set CheckCmd = Nothing 
		Call CloseConn()
		Response.Write "请先登录后再使用此功能！"
		Response.End()
   Case 41:
        Set CheckCmd = Nothing 
		Call CloseConn()
		Response.Write "<font color=red>系统禁止了两个人使用同一帐号同时登陆系统，此帐号已经在别的地方登陆</font>"
		Response.End()
   Case 42:
        Set CheckCmd = Nothing 
		Call CloseConn()
		Response.Write "频道参数错误！"
		Response.End()
   End Select

   If CheckCmd(7) = True Then
      Set CheckCmd = Nothing
      Call CloseConn()
      Response.Write "此频道已被禁用"
      Response.End()
   End If
   IsUpload = CheckCmd(8)
   FilesPath = InstallDir & CheckCmd(9) &"/"& CheckCmd(10) &"/"
   Set CheckCmd = Nothing
Else
  IsUpload = False
End If

CloseConn()

If ShowType>1 And ShowType<>5 Then IsUpload = False

Function ReplaceBadChar(strChar)
    If strChar = "" Or IsNull(strChar) Then
        ReplaceBadChar = ""
        Exit Function
    End If
    Dim strBadChar, arrBadChar, tempChar, i
    arrBadChar = Split(EL_BadChar, ",")
    tempChar = strChar
    For i = 0 To UBound(arrBadChar)
        tempChar = Replace(tempChar, arrBadChar(i), "")
    Next
    ReplaceBadChar = tempChar
End Function

Function EL_CLng(ByVal str1)
    If IsNumeric(str1) Then
        EL_CLng = CLng(str1)
    Else
        EL_CLng = 0
    End If
End Function

%>