📄 admin_skin.asp

📁 依蓝旅游网站管理系统Elan2008.SP2
💻 ASP
📖 第 1 页 / 共 2 页
字号:
12 下一页
<%
Option Explicit
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
%>
<!--#Include File="../Conn.asp"-->
<!--#Include File="Admin_CheckPurview.asp"-->
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<link href='Admin_Style.css' type='text/css' rel='stylesheet'>
<title>网站风格管理</title>
<script language="javascript" src="../js/Common.js"></script>
<script language="javascript" src="../js/InstallDir.js"></script>
</head>
<body>
<table width="100%" border="0" cellpadding="0" cellspacing="1" class="Border">
  <tr>
    <td align="center" class="top_25"><strong>网站风格管理</strong></td>
  </tr>
  <tr>
    <td class="td_50">管理导航：<a href="Admin_Skin.asp">风格管理首页</a> | <a href="Admin_Skin.asp?Action=Add">添加风格</a> | <a href="Admin_Skin.asp?Action=Import">风格导入</a> | <a href="Admin_Skin.asp?Action=Export">风格导出</a></td>
  </tr>
</table>
<br>
<%
If EL_Admin.Purview <> 1 Then
   If EL_Admin.CheckAdminPurview(6, 3) = False Then
      EL_Admin.ShowPurviewError("对不起！您没有足够的管理权限")
   End If
End If

Select Case Action
  Case "": Call ManageSkin()
  Case "Add": Call AddSkin()
  Case "SaveNewSkin": Call SaveSkin(0)
  Case "Modify": Call ModifySkin()
  Case "SaveModify": Call SaveSkin(1)
  Case "SetDefaulted": Call SaveSkin(2)
  Case "Delete": Call SaveSkin(3)
  Case "Import": Call ImportSkin()
  Case "Export": Call ExportSkin()
  Case "Refresh": Call RefreshSkin()
End Select
Call EL_Common.Bottom()
Call ApplicationTerminate()

Sub RefreshSkin()
   On Error Resume Next
   Dim SkinCmd, rsSkin
   Dim SkinID, Content
   
   SkinID = EL_Common.ELRequest("SkinID", 2)
   
   Call EL_Common.InitCommonCmd(SkinCmd, rsSkin, "EL_Skin", "Content", "SkinID="& SkinID)
   rsSkin.Close()
   If SkinCmd(0) <> 1 Then
      Set rsSkin = Nothing
	  Set SkinCmd = Nothing
	  EL_Common.ShowErrorMsg("指定风格不存在")
	  Exit Sub
   End If
   rsSkin.Open()
   Content = rsSkin("Content")
   rsSkin.Close()
   Set rsSkin = Nothing
   Set SkinCmd = Nothing
   Call EL_Common.CreateFile(Content, InstallDir &"Skin/DefaultStyle"& SkinID &".css", True)
   EL_Common.ShowSuccessMsg("刷新风格成功")
   EL_Common.ShowScriptError()
End Sub

Sub SaveSkin(UpdateType)
   On Error Resume Next
   Dim SkinCmd
   Dim SkinID, SkinName, Content, Defaulted
   
   SkinID = EL_Common.ELRequest("SkinID", 2)
   SkinName = EL_Common.ELRequest("SkinName", 1)
   Content = EL_Common.ELRequest("Content", 1)
   Defaulted = EL_Common.ELRequest("Defaulted", 2)
   
   Call EL_Common.InitCommand(SkinCmd, "EL_SP_Skin")
   With SkinCmd
     .Parameters.Append .CreateParameter("RETURN", 2, 4)
	 .Parameters.Append .CreateParameter("@UpdateType", 3, 1, 4, UpdateType)
	 If UpdateType = 0 Then
	    .Parameters.Append .CreateParameter("@SkinID", 3, 2, 4)
	 Else
	    .Parameters.Append .CreateParameter("@SkinID", 3, 1, 4, SkinID)
	 End If
	 .Parameters.Append .CreateParameter("@SkinName", 200, 1, 50, SkinName)
	 .Parameters.Append .CreateParameter("@Content", 203, 1, EL_Common.LenParameter(Content), Content)
	 .Parameters.Append .CreateParameter("@Defaulted", 11, 1, 1, Defaulted)
	 .Execute()
   End With
   If SkinCmd(0) = 40 Then
      EL_Common.ShowErrorMsg("指定风格不存在")
	  Set SkinCmd = Nothing
	  Exit Sub
   End If
   If UpdateType = 0 Then
      SkinID = SkinCmd(2)
      Call EL_Common.CreateFile(Content, InstallDir &"Skin/DefaultStyle"& SkinID &".css", True)
      EL_Common.ShowSuccessMsg("添加风格成功："& SkinName)
   ElseIf UpdateType = 1 Then
      Call EL_Common.CreateFile(Content, InstallDir &"Skin/DefaultStyle"& SkinID &".css", True)
	  EL_Common.ShowSuccessMsg("修改风格成功："& SkinName)
   ElseIf UpdateType = 2 OR UpdateType = 3 Then
      Set SkinCmd = Nothing
      Response.Redirect ComeURL
   Else
      EL_Common.ShowErrorMsg("页面参数错误")
   End If   
   Set SkinCmd = Nothing
   EL_Common.ShowScriptError()
End Sub


Sub ExportSkin()
On Error Resume Next
Dim ExportStep, SkinID, Disabled, SkinData, IsClear
Dim SkinCmd, rsSkin, RowCount, i
Dim SkinConn, SkinName, Content

ExportStep = EL_Common.ELRequest("ExportStep", 2)

If ExportStep = 0 Then
Call EL_Common.InitCommonCmd(SkinCmd, rsSkin, "EL_Skin", "SkinID, SkinName", "1=1")
rsSkin.Close()
RowCount = SkinCmd(0)
%>
<script language="javascript">
function Check(frm){
  if(frm.SkinID.value.trim()=="" || frm.SkinID.options.selectedIndex == -1){
     alert("请选择要导入的风格");
	 frm.SkinID.focus();
	 return false;
  }
  SubmitOnce(frm);
  return;
}
</script>
<form name="myform" action="Admin_Skin.asp" method="post" onSubmit="return Check(this)">
<table width="100%" border="0" cellpadding="0" cellspacing="1" class="Border">
  <tr>
    <td colspan="2" class="top_25"><strong>风格导出</strong></td>
  </tr>
  <tr>
    <td width="19%" class="td_ItemName"><strong>选择要导出的风格</strong></td>
    <td width="81%" class="td_25">
	<select name="SkinID" size="10" multiple id="SkinID" style="height:250px; width:250px;">
      <%
	  If RowCount=0 Then
	     Response.Write "<option value=''>系统中没有可以导出的风格</option>"
		 Disabled = "disabled"
	  Else
	     Disabled = ""
		 rsSkin.Open()
	     For i = 1 To RowCount
		    Response.Write "<option value='"& rsSkin(0) &"'>"& rsSkin(1) &"</option>"
			If i<RowCount Then rsSkin.MoveNext
		 Next		 
		 rsSkin.Close()
	  End If
	%>
    </select></td>
  </tr>
  <tr>
    <td class="td_ItemName"><strong>目标数据表</strong></td>
    <td class="td_25"><input name="SkinData" type="text" id="SkinData" value="<%=InstallDir%>EL_Skin.mdb" size="30">
      <input name="IsClear" type="checkbox" class="nomargin" id="IsClear" value="1" checked> 
      先清空目标数据表</td>
  </tr>
  <tr>
    <td class="td_ItemName">&nbsp;</td>
    <td class="td_50"><input type="submit" name="Submit33" value=" 导 出 " <%=Disabled%>>
      <input name="Action" type="hidden" id="Action" value="Export">
      <input name="ExportStep" type="hidden" id="ExportStep" value="1"></td>
  </tr>
</table>
</form>
<%
Set rsSkin = Nothing
Set SkinCmd = Nothing

ElseIf ExportStep = 1 Then

SkinID = EL_Common.ELRequest("SkinID", 1)
IsClear = EL_Common.ELRequest("IsClear", 2)
SkinData = EL_Common.ELRequest("SkinData", 1)

Set SkinConn = Server.CreateObject("ADODB.Connection")
SkinConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(SkinData)
If Err Then
   Err.Clear
   EL_Common.ShowErrorMsg("打开风格数据表错误，无法完成风格导出操作，请返回上一步检查数据表路径是否正确")
   SkinConn.Close()
   Set SkinConn = Nothing
   Exit Sub
End If

Set rsSkin = SkinConn.Execute("Select SkinID,SkinName,Content From EL_Skin")
If Err Then
   Err.Clear()
   EL_Common.ShowErrorMsg("数据表中的数据结构错误，无法导出风格")
   rsSkin.Close()
   Set rsSkin = Nothing
   SkinConn.Close()
   Set SkinConn = Nothing
   Exit Sub
End If
rsSkin.Close()
Set rsSkin = Nothing

If IsClear = 1 Then '清空
   SkinConn.Execute("DELETE FROM EL_Skin")
End If

Call EL_Common.InitCommonCmd(SkinCmd, rsSkin, "EL_Skin", "SkinName,Content", "SkinID IN("& SkinID &")")
rsSkin.Close()
RowCount = SkinCmd(0)
If RowCount > 0 Then
   rsSkin.Open()
   For i = 1 To RowCount
      SkinConn.Execute("INSERT INTO EL_Skin(SkinName,Content) VALUES('"& Replace(rsSkin("SkinName"), "'", "''") &"', '"& Replace(rsSkin("Content"), "'", "''") &"')")
	  If i<RowCount Then rsSkin.MoveNext
   Next
   rsSkin.Close()
End If
Set rsSkin = Nothing
Set SkinCmd = Nothing
SkinConn.Close()
Set SkinConn = Nothing

EL_Common.ShowScriptError()
Response.Redirect "Admin_Skin.asp?Action=Export&ExportStep=2"

ElseIf ExportStep = 2 Then
  EL_Common.ShowSuccessMsg("成功导出风格")
End If

EL_Common.ShowScriptError()
End Sub


Sub ImportSkin()
On Error Resume Next
Dim ImportStep
Dim SkinData, SkinID
Dim rsSkin, SkinConn, Disabled
ImportStep = EL_Common.ELRequest("ImportStep", 2)

'第一步：数据表路径
If ImportStep = 0 Then
%>
<form name="myform" action="Admin_Skin.asp" method="post">
<table width="100%" border="0" cellpadding="0" cellspacing="1" class="Border">
  <tr>
    <td colspan="2" class="top_25"><strong>风格导入：第一步</strong></td>
  </tr>
  <tr>
    <td width="19%" class="td_ItemName"><strong>风格数据表路径</strong></td>
    <td width="81%" class="td_25"><input name="SkinData" type="text" id="SkinData" value="<%=InstallDir%>EL_Skin.mdb" size="30"></td>
  </tr>
  <tr>
    <td class="td_ItemName">&nbsp;</td>
    <td class="td_50"><input type="submit" name="Submit3" value="下一步">
    <input name="ImportStep" type="hidden" id="ImportStep" value="1">
    <input name="Action" type="hidden" id="Action" value="Import"></td>
  </tr>
</table>
</form>
<%
'第二步：选择风格
ElseIf ImportStep = 1 Then

Disabled = "Disabled"
SkinData = EL_Common.ELRequest("SkinData", 1)

Set SkinConn = Server.CreateObject("ADODB.Connection")
SkinConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(SkinData)
If Err Then
   Err.Clear
12 下一页
💿 文件大小 4678 K
👤 上传用户 libin2722
📂 所属分类企业管理
🏷️ 相关标签

#Elan #2008 #SP #旅游
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -