admin_control.asp

依蓝旅游网站管理系统Elan2008.SP2

<!--#include File="Class/Admin_ClassAdmin.asp"-->
<!--#include File="Class/Admin_ClassCommon.asp"-->
<!--#include File="Class/Admin_ClassChannel.asp"-->
<!--#Include File="Class/Admin_SaveRemoteImages.asp"-->
<!--#Include File="../Inc/ClassJpeg.asp"-->
<%
Dim EL_Admin, EL_PurviewPassed, EL_Common, EL_Channel
Dim EL_ChannelModuleName(10)
Dim CurrentPage, PageSizes, URLParameters

Set EL_Common = New Class_Common

If ComeURL = "" Then
   Response.Clear()
   Response.Write "<font color=red>禁止直接输入地址访问后台页面</font>"
   Call EL_Common.InsertLog(1, ComeURL, "直接输入地址访问后台页面", "")
   Set EL_Common = Nothing
   Call CloseConn()
   Response.End()
Else
   Dim Current_URL
   Current_URL = "http://" & Trim(Request.ServerVariables("HTTP_HOST"))
   Current_URL = Current_URL & Trim(Request.ServerVariables("SCRIPT_NAME"))
   If CheckComefrom(ComeURL, Current_URL) = False Then
      Response.Clear()
      Response.Write "<font color=red>禁止从外部链接地址访问后台页面</font>"
	  Call EL_Common.InsertLog(1, ComeURL, "试图从系统外部地址提交的数据", "")
	  Set EL_Common = Nothing
	  Call CloseConn()
      Response.End()
   End If
End If

EL_ChannelModuleName(1) = "Article"
EL_ChannelModuleName(2) = "Hotel"
EL_ChannelModuleName(3) = "Product"
EL_ChannelModuleName(4) = "Flight"
EL_ChannelModuleName(5) = "Sight"
EL_ChannelModuleName(6) = "Photo"
EL_ChannelModuleName(7) = "Shop"
EL_ChannelModuleName(8) = "Car"
EL_ChannelModuleName(9) = "Forum"

Set EL_Admin = New Class_Admin
Set EL_Channel = New Class_Channel
CurrentPage = EL_Common.ELRequest("page", 2)
PageSizes = EL_Common.ELRequest("pagesizes", 2)
If PageSizes = 0 Then PageSizes = 20
URLParameters = Request.ServerVariables("QUERY_STRING")
URLParameters = EL_Common.ReplaceText(URLParameters, "\&{0,}pagesizes=[0-9]*", "")
If CurrentPage<1 Then 
   CurrentPage = 1
Else
   URLParameters = EL_Common.ReplaceText(URLParameters, "\&{0,}page=[0-9]*", "")
End If

Function CheckComefrom(StrComeURL, StrCurrentURL)
   If Trim(StrComeURL) = "" Then
      CheckComefrom = False
   Else
      If LCase(Left(StrComeURL, InStrRev(StrComeURL, "/"))) <> LCase(Left(StrCurrentURL, InStrRev(StrCurrentURL, "/"))) Then
	     CheckComefrom = False
	  Else
	     CheckComefrom = True
	  End If
   End If
End Function

Sub ApplicationTerminate()
   On Error Resume Next
   Set EL_Admin = Nothing
   Set EL_Cache = Nothing
   Set EL_Common = Nothing
   Set EL_Channel = Nothing
   Call CloseConn()
   If Err Then Err.Clear
   Response.End()
End Sub
%>