📄 admin_selectfile.asp
字号:
<%
Option Explicit
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
Response.CacheControl = "no-cache"
%>
<!--#Include File="../Conn.asp"-->
<!--#include File="Admin_CheckCode.asp"-->
<!--#include File="Class/Admin_ClassAdmin.asp"-->
<!--#include File="Class/Admin_ClassCommon.asp"-->
<!--#include File="Class/Admin_ClassChannel.asp"-->
<html>
<head>
<title>选择文件</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<link href='Admin_Style.css' type='text/css' rel='stylesheet'>
<base target="_self">
</head>
<body>
<%
Sub ApplicationTerminate()
On Error Resume Next
Set EL_Admin = Nothing
Set EL_Common = Nothing
Set EL_Channel = Nothing
Call CloseConn()
If Err Then Err.Clear
Response.End()
End Sub
Dim EL_Admin, EL_Common, EL_Channel, CurrentPage, URLParameters
Dim FSO, ObjectCurrentFolder, ObjectSubFolders, ObjectSubFolder, ObjectFiles
Dim DialogType, Folder, TrueFolder, FolderCounter, AllFolders
Set EL_Admin = New Class_Admin
Set EL_Common = New Class_Common
Set EL_Channel = New Class_Channel
CurrentPage = EL_Common.ELRequest("page", 2)
URLParameters = request.ServerVariables("QUERY_STRING")
If CurrentPage<1 Then
CurrentPage = 1
Else
URLParameters = EL_Common.ReplaceText(URLParameters, "\&page=[0-9]*", "")
End If
If EL_Admin.ErrorCode = 1 Then
Response.Write "请登陆后在使用此功能"
Call ApplicationTerminate()
ElseIf EL_Admin.ErrorCode = 2 Then
Response.Write "<font color=red>系统禁止了两个人使用同一帐号同时登陆系统，此帐号已经在别的地方登陆。</font>"
Call ApplicationTerminate()
End If
If EL_Channel.ChannelID <= 0 Then
Response.Write "频道参数错误"
Call ApplicationTerminate()
Else
EL_Channel.GetChannelConfig()
If EL_Channel.ErrorCode = 1 Then
Response.Write("频道参数错误")
Call ApplicationTerminate()
End If
If EL_Channel.Disabled Then
Response.Write("该频道已被禁用")
Call ApplicationTerminate()
End If
End If
DialogType = EL_Common.ELRequest("DialogType", 1)
Folder = EL_Common.ELRequest("Folder", 1)
TrueFolder = InstallDir & EL_Channel.ChannelDir &"/"& EL_Channel.UploadDir &"/"& Folder
Call Main()
Call ApplicationTerminate()
Sub Main()
Dim ParentFolder, URLFolder
Set FSO = Server.CreateObject(Object_FSO)
Set ObjectCurrentFolder = FSO.GetFolder(Server.MapPath(TrueFolder))
Set ObjectSubFolders = ObjectCurrentFolder.SubFolders
Set ObjectFiles = ObjectCurrentFolder.Files
URLFolder = Folder
If URLFolder <> "" Then URLFolder = Folder &"/"
ParentFolder = FSO.GetParentFolderName(Folder)
AllFolders = ""
For Each ObjectSubFolder in ObjectSubFolders
AllFolders = AllFolders &"<div class=leftdiv style='padding-right:10px;'>"
AllFolders = AllFolders &"<a href=""Admin_SelectFile.asp?DialogType="& DialogType &"&ChannelID="& EL_Channel.ChannelID &"&Folder="& URLFolder & ObjectSubFolder.Name &""" >"
AllFolders = AllFolders &"<img src='images/folder.gif' border=0 style='float:left'> "
AllFolders = AllFolders &"<m style='float:left'>"& ObjectSubFolder.Name &"</m>"
AllFolders = AllFolders &"</a></div>"
Next
%>
<script language="javascript">
function OK(s){
window.returnValue = s;
window.close();
}
</script>
<table width="100%" border="0" cellspacing="1" cellpadding="0" class="Border">
<tr>
<td height="30" style="background:#D4D0C8;">
<div class="leftdiv"><strong>目录导航：</strong> <%=TrueFolder%></div>
<div class="rightdiv">
<% If Folder<>"" Then %>
<a href="Admin_SelectFile.asp?TempMode=1&DialogType=<%=DialogType%>&ChannelID=<%=EL_Channel.ChannelID%>&Folder=<%=ParentFolder%>"><img src="Images/upfolder.gif" border="0" style="float:left"> <m style="float:left">返回上一级目录</m></a>
<% Else %>
<img src="Images/upfolder.gif" border="0" style="float:left; filter:gray"> <span style="float:left" disabled>返回上一级目录</span>
<% End If %>
</div>
</td>
</tr>
</table>
<% If AllFolders<>"" Then %>
<table width="100%" border="0" cellspacing="1" cellpadding="0">
<tr>
<td class="td_50"><%=AllFolders%></td>
</tr>
</table>
<% End If%>
<br>
<table width="100%" border="0" cellspacing="2" cellpadding="0" class="Border">
<tr>
<%
Dim tFile, i, File_Ext, arrUploadExt, tFileExt, ViewImage
Dim PageCounts, PageSizes, FileNum
PageSizes = 20
PageCounts = 0
i = 1
FileNum = 0
arrUploadExt = Split("jpg|bmp|gif|png$swf$mid|mp3|wmv|asf|avi|mpg$ram|rm|ra$rar|exe|doc|zip","$")
For Each tFile In ObjectFiles
tFileExt = Right(tFile.Name, Len(tFile.Name) - InstrRev(tFile.Name, "."))
Select Case lCase(DialogType)
Case "pic":
File_Ext = Split(arrUploadExt(0), "|")
ViewImage = TrueFolder &"/"& tFile.Name
Case "flash":
File_Ext = Split(arrUploadExt(1), "|")
ViewImage = InstallDir & AdminDir &"/Images/filetype_flash.gif"
Case "media":
File_Ext = Split(arrUploadExt(2), "|")
ViewImage = InstallDir & AdminDir &"/Images/filetype_media.gif"
Case "real":
File_Ext = Split(arrUploadExt(3), "|")
ViewImage = InstallDir & AdminDir &"/Images/filetype_rm.gif"
Case "fujian":
File_Ext = Split(arrUploadExt(4), "|")
Select Case lcase(tFileExt)
Case "exe": ViewImage = InstallDir & AdminDir &"/Images/filetype_exe.gif"
Case "rar": ViewImage = InstallDir & AdminDir &"/Images/filetype_rar.gif"
Case Else: ViewImage = InstallDir & AdminDir &"/Images/filetype_other.gif"
End Select
End Select
If EL_Common.FoundInArray(File_Ext, tFileExt) = True Then
FileNum = FileNum + 1
If FileNum>(CurrentPage-1) * pageSizes And FileNum <= CurrentPage*PageSizes Then
Response.Write "<td class=""td_25"" align=""center"" width=""25%"" onmouseover=""this.className='MouseOver_25'"" onmouseout=""this.className='td_25'"">"
Response.Write "<div style='padding:5px'>"
Response.Write "<a href=""javascript:OK('"& TrueFolder &"/"& tFile.Name &"')""><img src='"& ViewImage &"' width=140 height=100 border=0></a>"
Response.Write "<div><a href='"& ViewImage &"' target=_blank>"& tFile.Name &"</a>"
Response.Write "<br>文件大小："& Round(tFile.Size / 1024, 1) &" K <br>修改日期：" & tFile.DateLastModified
Response.Write "</div>"
Response.Write "</div></td>"
If (i Mod 4) = 0 Then Response.Write "</tr><tr>"
i = i + 1
End If
End If
Next
If FileNum = 0 Then
Response.Write "<td class=""td_50"">该目录下没有文件</td>"
Else
If FileNum>PageSizes Then
If (FileNum Mod PageSizes)=0 Then
PageCounts = Int(FileNum / PageSizes)
Else
PageCounts = Int(FileNum / PageSizes) + 1
End If
Else
PageCounts = 1
End If
End If
%>
</tr>
</table>
<table width="100%" border="0" cellspacing="1" cellpadding="0">
<tr>
<td align="center"><%Call ShowPage(URLParameters, CurrentPage, PageSizes, PageCounts, FileNum, "文件", "个")%></td>
</tr>
</table>
<%
Set ObjectSubFolders = Nothing
Set ObjectCurrentFolder = Nothing
Set FSO = Nothing
End Sub
Sub ShowPage(ByVal URL, ByVal CurrentPage, ByVal PageSizes, ByVal PageCounts, ByVal TotalRowCount, ByVal ItemName, ByVal ItemUnit)
Dim StrHtml, i, ScriptName
ScriptName = Request.ServerVariables("SCRIPT_NAME") &"?"
If URL = "" Then
ScriptName = ScriptName & URL
Else
ScriptName = ScriptName & URL &"&"
End If
Response.Write "<table border=""0"" cellspacing=""1"" cellpadding=""0"">"
Response.Write "<form name='pageform' action='Admin_SelectFile.asp?"& URL &"' method='Post'><tr><td>"
Response.Write "一共<strong style='color:red'>"& TotalRowCount &"</strong>"& ItemUnit & ItemName &" "
Response.Write "<a href='"& ScriptName &"page=1'>首页</a> "
If CurrentPage = 1 Then
Response.Write "<a disabled>上一页</a> "
Else
Response.Write "<a href='"& ScriptName &"page="& (CurrentPage-1) &"'>上一页</a> "
End If
If CurrentPage >= PageCounts Then
Response.Write "<a disabled>下一页</a> "
Else
Response.Write "<a href='"& ScriptName &"page="& (CurrentPage+1) &"'>下一页</a> "
End If
Response.Write "<a href='"& ScriptName &"page="& PageCounts &"'>尾页</a> "
Response.Write "<strong style='color:red'>"& CurrentPage &"</strong>/<strong>"& PageCounts &"</strong>页 "
Response.Write "<strong>"& PageSizes &"</strong>"& ItemUnit & ItemName &"/页 "
Response.Write "跳转</td><td>"
If PageCounts>3000 Then Response.Flush()
Response.Write "<select onChange=""javascript:submit()"" name='page'>"
For i = 1 To PageCounts
Response.Write "<option value='"& i &"' "& EL_Common.SetObjectSelected(CurrentPage, i) &">第"& i &"页</option>"
Next
Response.Write"</select>"
Response.Write"</td></tr></form></table>"
End Sub
%>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -