classsendmail.asp

依蓝旅游网站管理系统Elan2008.SP2

<%
Class ClassSendMail
  
   Private Object_Email, SMTP_Server, SMTP_UserName, SMTP_Password, SMTP_Domain
   Public SubjectName, FromUserName, FromEmail, ToEmail, EmailBody, EnableSendEmail
   
   Private Sub Class_Initialize()   
      Dim MailConfigCmd, rsMailConfig
	  Call EL_Common.InitCommonCmd(MailConfigCmd, rsMailConfig, "EL_Config", "Top 1 Object_Email,SMTP_Server,SMTP_UserName,SMTP_Password,SMTP_Domain", "1=1")
      Object_Email = rsMailConfig(0)
      SMTP_Server = rsMailConfig(1)
      SMTP_UserName = rsMailConfig(2)
      SMTP_Password = rsMailConfig(3)
      SMTP_Domain = rsMailConfig(4)
      rsMailConfig.Close()
      Set rsMailConfig = Nothing
      Set MailConfigCmd = Nothing
	  
	  If Object_Email = "" OR ObjTest(Object_Email) = False Then
	     EnableSendEmail = False
	  Else
	     EnableSendEmail = True
	  End If	  
	  SubjectName = SiteName
   End Sub
   
   Private Sub Class_Terminate()
   End Sub   
   
   Public Sub SendMail()
      If EnableSendEmail = False Then
	     EL_Common.ShowErrorMsg("邮件发送组件错误")
		 Call ApplicationTerminate()
		 Exit Sub
	  End If
      Select Case UCase(Object_Email)
	     Case "JMAIL.MESSAGE": Call Jmail()
		 Case "CDONTS.NEWMAIL": Call Cdonts()
		 Case "PERSITS.MAILSENDER": Call AspEmail()
		 Case "EASYMAIL.MAILSEND": Call EasyMail()
		 Case Else:
		    EL_Common.ShowErrorMsg("邮件发送组件错误")
			Call ApplicationTerminate()
			Exit Sub
	  End Select
   End Sub
   
   Private Sub Jmail()
      Dim Jmessage
	  Set Jmessage = Server.CreateObject(Object_Email)
	  Jmessage.Silent = True
	  Jmessage.Logging = True
	  Jmessage.Charset = "gb2312"
	  Jmessage.ContentType = "text/html"
	  Jmessage.MailServerUserName = SMTP_UserName
	  Jmessage.MailServerPassword = SMTP_Password
	  Jmessage.Priority = 1
	  Jmessage.From = SMTP_UserName
	  Jmessage.FromName = FromUserName
	  Jmessage.AddRecipient ToEmail
	  Jmessage.Subject = SubjectName
	  Jmessage.Body = EmailBody
	  Jmessage.Send(SMTP_Server)
	  Jmessage.Close()
	  Set Jmessage = Nothing
   End Sub
   
   Private Sub Cdonts()
      Dim Cmail
      Set Cmail = Server.CreateObject(Object_Email)
	  Cmail.From = SMTP_UserName
	  Cmail.To =ToEmail
	  Cmail.Subject = SubjectName
	  Cmail.BodyFormat = 0
	  Cmail.MailFormat = 0
	  Cmail.Importance = 1
	  Cmail.Body = EmailBody
	  Cmail.Send
	  Set Cmail = Nothing
   End Sub
   
   Private Sub AspEmail()
      Dim ObjMail
	  Set ObjMail = Server.CreateObject(Object_Email)
	  ObjMail.Charset = "gb2312"
	  ObjMail.From = SMTP_UserName
	  ObjMail.FromName = FromUserName
	  ObjMail.AddAddress ToEmail
	  ObjMail.Subject = SubjectName
	  ObjMail.IsHTML = True
	  ObjMail.Body = EmailBody
	  ObjMail.UserName = SMTP_UserName
	  ObjMail.Password = SMTP_Password
	  ObjMail.Host = SMTP_Server
	  ObjMail.Priority = 1
	  ObjMail.Send	  
	  Set ObjMail = Nothing
   End Sub
   
   Private Sub EasyMail()
	  Dim MailSend
	  Set MailSend = Server.CreateObject(Object_Email) 
	  MailSend.CreateNew SMTP_UserName, SMTP_Password
	  MailSend.MailName = FromUserName
	  MailSend.EM_To = ToEmail
	  MailSend.EM_Subject = SubjectName 
      MailSend.EM_HTML_Text = Emailbody
      MailSend.useRichEditer = true 
      MailSend.send 
      Set MailSend=nothing 
   End Sub 
   
   Private Function ObjTest(strObj)
	On Error Resume Next
	ObjTest = False
	Dim TestObj
	Set TestObj = server.CreateObject (strObj)
	If -2147221005 <> Err then
		ObjTest = True
	Else
	   Err.Clear
	End If	
   End Function

   
End Class
%>