classuser.asp

依蓝旅游网站管理系统Elan2008.SP2

<%

Class ClassUser
   
   Public UserID, UserName, UserPassword, UserRndPassword
   Public UserIsLogin, ErrorCode, FaceSizeX, FaceSizeY
   Public GroupID, TrueName, FaceType, Userface, FaceSize, Sex, Birthday, IDCard, Mobile, Phone, Fax, QQ, ICQ, MSN, Email, Address, ZipCode
   Public Marriage, Job, JobTitle, Income, CompanyName, Sign, RegDateTime, LoginTimes, LastLoginTime, LastLoginIp, Online
   Public ArrDiscountOfBook, Points, Exps, PostCount, EliteCount
   Public BookCount_Hotel, BookCount_Flight, BookCount_Product, BookCount_Sight, BookCount_Shop
   Public IsBoardManager, ArrManageBoardID, EnablePost, DisablePostDays, BoardSuperManager, LastAwardDateOfLogin
   Public UserType, UserTypeName
   Public GroupName, GroupType, Group_ArrDiscountOfBook
   Public MessageNum, BookNum   
   Public DiscountOfHotel, DiscountOfFlight, DiscountOfProduct, DiscountOfSight, DiscountOfCar
   Public ForumLevel, LevelPictrue, DeleteCount
   
   Private Sub Class_Initialize
      ErrorCode = 0
	  MessageNum = 0
	  BookNum = 0	 
	  UserType = 1 '默认为游客 
	  UserIsLogin = True
	  UserTypeName = EL_Common.Lang("BaseConfig.UserType"& UserType, "游客")	  
	  UserID = EL_Common.ELClng(Trim(Request.Cookies("User_"& EL_Sn)("UserID")))
	  UserName = Trim(Request.Cookies("User_"& EL_Sn)("UserName"))
	  UserPassword = Trim(Request.Cookies("User_"& EL_Sn)("UserPassword"))
	  UserRndPassword = Trim(Request.Cookies("User_"& EL_Sn)("UserRndPassword"))
	  If UserID = "" Or UserName = "" Or UserPassword = "" Or UserRndPassword = "" Or UserID = 0 Then
	     UserIsLogin = False
		 UserID = 0
		 UserName = UserTypeName
		 Response.Cookies("EL_User_Counter")("UserID") = ""
	  Else
	     Response.Cookies("EL_User_Counter")("UserID") = UserID
	  End If	
   End Sub
   
   Private Sub Class_Terminate
   End Sub
   
   Public Sub UserLogout()
      If UserID > 0 Then 
	     If ErrorCode = 3 Or ErrorCode = 9999 Then Conn.Execute("Update EL_User SET Online=0 WHERE UserID="& UserID)
		 Conn.Execute("Delete From EL_CounterOnline WHERE [ClientIp]='"& RemoteIp &"' And UserID="& UserID)
	  End If
	  Response.Cookies("User_"& EL_Sn)("UserID") = ""
	  Response.Cookies("User_"& EL_Sn)("UserName") = ""
	  Response.Cookies("User_"& EL_Sn)("UserPassword") = ""
	  Response.Cookies("User_"& EL_Sn)("UserRndPassword") = ""
	  Response.Cookies("EL_User_Counter")("UserID") = ""	  
   End Sub
   
   Public Sub GetUserInfo() 
	  Dim UserCmd, rsUser 
	  
	  Set UserCmd = Server.CreateObject("ADODB.COMMAND")
	  With UserCmd
	     .ActiveConnection = Conn
		 .CommandText = "EL_SP_UserInfo"
		 .CommandType = 4
		 .Prepared = True
		 .Parameters.Append .CreateParameter("RETURN", 2, 4)
		 .Parameters.Append .CreateParameter("@ShowType", 3, 1, 4, 0)
		 .Parameters.Append .CreateParameter("@UserID", 3, 1, 4, UserID)
		 .Parameters.Append .CreateParameter("@MessageNum", 3, 2, 4)
		 Set rsUser = .Execute()
	  End With
	  
	  rsUser.Close()
	  If UserCmd(0) <> 1 Then
	     UserIsLogin = False
		 UserID = 0
		 UserName = UserTypeName
		 Response.Cookies("EL_User_Counter")("UserID") = ""
		 ErrorCode = 1
		 Set rsUser = Nothing
		 Set UserCmd = Nothing
		 Call UserLogout()
		 Exit Sub
	  End If	
	  MessageNum = UserCmd(3)  
	  rsUser.Open()
	  If Int(rsUser("UserID")) <> Int(UserID) Or LCase(rsUser("UserName")) <> LCase(UserName) Or rsUser("Password") <> UserPassword Then
	     UserIsLogin = False
		 UserID = 0
		 UserName = UserTypeName
		 ErrorCode = 1
		 Response.Cookies("EL_User_Counter")("UserID") = ""
		 rsUser.Close()
		 Set rsUser = Nothing
		 Set UserCmd = Nothing
		 Call UserLogout()
		 Exit Sub
	  End If
	  
	  If rsUser("RndPassword") <> UserRndPassword Then
	     UserIsLogin = False
		 UserID = 0
		 UserName = UserTypeName
		 Response.Cookies("EL_User_Counter")("UserID") = ""
		 ErrorCode = 2
		 rsUser.Close()
		 Set rsUser = Nothing
		 Set UserCmd = Nothing
		 Call UserLogout()
		 Exit Sub
	  End If
	  	  
	  UserID               = rsUser("UserID")
	  UserName             = rsUser("UserName")
	  UserPassword         = rsUser("Password")
	  UserRndPassword      = rsUser("RndPassword")
	  GroupID              = rsUser("GroupID")
	  TrueName             = rsUser("TrueName")
	  FaceType             = rsUser("FaceType")
	  Userface             = rsUser("Userface")
	  FaceSize             = rsUser("FaceSize")
	  Sex                  = rsUser("Sex")
	  Birthday             = rsUser("Birthday")
	  IDCard               = rsUser("IDCard")
	  Mobile               = rsUser("Mobile")
	  Phone                = rsUser("Phone")
	  Fax                  = rsUser("Fax")
	  QQ                   = rsUser("QQ")
	  ICQ                  = rsUser("ICQ")
	  MSN                  = rsUser("MSN")
	  Email                = rsUser("Email")
	  Address              = rsUser("Address")
	  ZipCode              = rsUser("ZipCode")
	  Marriage             = rsUser("Marriage")
	  Job                  = rsUser("Job")
	  JobTitle             = rsUser("JobTitle")
	  Income               = rsUser("Income")
	  CompanyName          = rsUser("CompanyName")
	  Sign                 = rsUser("Sign")
	  RegDateTime          = rsUser("RegDateTime")
	  LoginTimes           = rsUser("LoginTimes")
	  LastLoginTime        = rsUser("LastLoginTime")
	  LastLoginIp          = rsUser("LastLoginIp")
	  ArrDiscountOfBook    = rsUser("ArrDiscountOfBook")
	  Points               = rsUser("Points")
	  Exps                 = rsUser("Exps")
	  BookCount_Hotel      = rsUser("BookCount_Hotel")
	  BookCount_Flight     = rsUser("BookCount_Flight")
	  BookCount_Product    = rsUser("BookCount_Product")
	  BookCount_Sight      = rsUser("BookCount_Sight")
	  BookCount_Shop       = rsUser("BookCount_Shop")
	  PostCount            = rsUser("PostCount")
	  EliteCount           = rsUser("EliteCount")
	  IsBoardManager       = rsUser("IsBoardManager")
	  ArrManageBoardID     = rsUser("ArrManageBoardID")
	  EnablePost           = rsUser("EnablePost")
	  BoardSuperManager     = rsUser("BoardSuperManager")
	  LastAwardDateOfLogin = rsUser("LastAwardDateOfLogin")
	  GroupName            = rsUser("Group_GroupName")
	  GroupType            = rsUser("Group_GroupType")
	  Group_ArrDiscountOfBook = rsUser("Group_ArrDiscountOfBook")
	  Online               = rsUser("Online")
	  ForumLevel           = rsUser("ForumLevel")
	  LevelPictrue         = rsUser("LevelPictrue")
	  DeleteCount          = rsUser("DeleteCount")
	  rsUser.Close()
	  Set rsUser = Nothing
	  Set UserCmd = Nothing	  	  

	  If Err Then
	     UserIsLogin = False
		 UserID = 0
		 UserName = UserTypeName
		 Response.Cookies("EL_User_Counter")("UserID") = ""		 
		 Err.Clear
		 ErrorCode = 1
		 Call UserLogout()
		 Exit Sub
	  End If	
	  If Online = False Then
	     UserIsLogin = False
		 UserID = 0
		 UserName = UserTypeName
		 Response.Cookies("EL_User_Counter")("UserID") = ""
		 ErrorCode = 3
		 Call UserLogout()
		 Exit Sub
	  Else
		 UserIsLogin = True
	  End If 
	  UserType = 0 
	  UserTypeName = EL_Common.Lang("BaseConfig.UserType"& UserType, "会员")
	  If FaceSize <> "" Then
	     Dim ArrSize
		 ArrSize = Split(FaceSize, "*")
		 If UBound(ArrSize) < 1 Then 
		    FaceSizeX = DefaultFaceSize
			FaceSizeY = DefaultFaceSize
		 Else
		    FaceSizeX = EL_Common.ELClng(ArrSize(0))
		    FaceSizeY = EL_Common.ELClng(ArrSize(1))
		    If FaceSizeX<=0 Then FaceSizeX = DefaultFaceSize
		    If FaceSizeY<=0 Then FaceSizeY = DefaultFaceSize
		 End If
	  Else
	     FaceSizeX = DefaultFaceSize
		 FaceSizeY = DefaultFaceSize
	  End If	
	  If FaceSizeX>FaceMaxSize Then FaceSizeX = FaceMaxSize
	  If FaceSizeY>FaceMaxSize Then FaceSizeY = FaceMaxSize
	  If Not IsNULL(ArrManageBoardID) Then
	     ArrManageBoardID = Replace(ArrManageBoardID, " ", "")
	  Else
	     ArrManageBoardID = ""
	  End If
	  Call PushDiscount(Group_ArrDiscountOfBook, ArrDiscountOfBook, DiscountOfHotel, DiscountOfFlight, DiscountOfProduct, DiscountOfSight, DiscountOfCar)
   End Sub
   
   Private Sub PushDiscount(ByVal strGroup, ByVal strUser, r1, r2, r3, r4, r5)
      Dim ArrPushGroup, ArrPushUser, i, ArrReturn(4)
	  
	  ArrPushGroup = Split(strGroup, ",")
	  ArrPushUser = Split(strUser, ",")
	  
	  For i = 0 To 4
	     ArrPushGroup(i) = ArrPushGroup(i)
		 ArrPushUser(i) = ArrPushUser(i)
	     If ArrPushUser(i) <> 0 Then
		    ArrReturn(i) = ArrPushUser(i)
		 ElseIf ArrPushGroup(i) <> 0 Then
		    ArrReturn(i) = ArrPushGroup(i)
		 Else
		    ArrReturn(i) = 0
		 End If
	  Next
	  r1 = ArrReturn(0)
	  r2 = ArrReturn(1)
	  r3 = ArrReturn(2)
	  r4 = ArrReturn(3)
	  r5 = ArrReturn(4)
   End Sub  
   
   Public Function Label_UserInfo(ByVal HTML)
      Dim TempHTML
	  TempHTML = HTML
	  If TempHTML = "" Then Exit Function
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_UserName}", EL_Common.ServerHTMLEncode(UserName))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_UserTypeName}", EL_Common.ServerHTMLEncode(UserTypeName))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_TrueName}", EL_Common.ServerHTMLEncode(TrueName))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Userface}", "<img src='"& Userface &"' width='"& FaceSizeX &"' height='"& FaceSizeY &"' border='0' />")
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Sex}", EL_Common.Lang("User.Sex"& Sex, "男"))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Birthday}", EL_Common.ServerHTMLEncode(Birthday))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Mobile}", EL_Common.ServerHTMLEncode(Mobile))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Phone}", EL_Common.ServerHTMLEncode(Phone))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Fax}", EL_Common.ServerHTMLEncode(Fax))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_QQ}", EL_Common.ServerHTMLEncode(QQ))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_ICQ}", EL_Common.ServerHTMLEncode(ICQ))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_MSN}", EL_Common.ServerHTMLEncode(MSN))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Email}", EL_Common.ServerHTMLEncode(Email))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Address}", EL_Common.ServerHTMLEncode(Address))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_ZipCode}", EL_Common.ServerHTMLEncode(ZipCode))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Marriage}", EL_Common.ServerHTMLEncode(Marriage))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Job}", EL_Common.ServerHTMLEncode(Job))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_JobTitle}", EL_Common.ServerHTMLEncode(JobTitle))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Income}", EL_Common.ServerHTMLEncode(Income))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_CompanyName}", EL_Common.ServerHTMLEncode(CompanyName))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Sign}", EL_Common.UBB(EL_Common.HTMLEncode(Sign)))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_RegDateTime}", RegDateTime)
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_LoginTimes}", LoginTimes)
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_LastLoginTime}", LastLoginTime)
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_LastLoginIp}", LastLoginIp)
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_GroupName}", EL_Common.ServerHTMLEncode(GroupName))
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Points}", Points)
	  TempHTML = EL_Common.RegExpStaticLabel(TempHTML, "{$User_Exps}", Exps)	  
	  Label_UserInfo = TempHTML	  
   End Function
   
End Class


%>