📄 classsendtofriend.asp

📁 依蓝旅游网站管理系统Elan2008.SP2
💻 ASP
字号:
<%
Class ClassSendToFriend
  
   Private InfoID, CommonRegExp, HTML, EL_Channel, InfoTitle
   
   Private Sub Class_Initialize()
      InfoID = EL_Common.ELRequest("InfoID", 2)
	  If InfoID < 1 Then
	      EL_Common.ShowErrorMsg(EL_Common.RegExpStaticLabel(EL_Common.Lang("BaseConfig.InfoError", "指定{$ItemName}不存在"), "{$ItemName}", EL_Channel.ItemName))
		  Call ApplicationTerminate()
	  End If
	  
      Set CommonRegExp = New RegExp
	  CommonRegExp.IgnoreCase = True 
      CommonRegExp.Global = True
	  Set EL_Channel = New ClassChannel	 
	  EL_Channel.GetChannelConfig()	  
	  If EL_Channel.ErrorCode = 1 Or EL_Channel.ChannelType = 1 Then
	     EL_Common.ShowErrorMsg(EL_Common.Lang("BaseConfig.ChannelError", "频道参数错误"))
		 Call ApplicationTerminate()
	  End If
	  
	  If EL_Channel.Disabled Then
	     EL_Common.ShowErrorMsg(EL_Common.Lang("BaseConfig.Disabled", "该频道已被禁用"))
		 Call ApplicationTerminate()
	  End If
   End Sub
   
   Private Sub Class_Terminate()
	  Set CommonRegExp = Nothing
	  Set EL_Channel = Nothing
   End Sub
   
   Public Sub Execute()
      InfoTitle = GetInfoTitle()
      If Action = "SendMail" Then
	     Call SendMail()
		 EL_Common.ShowSuccessMsg(EL_Common.Lang("SendToFriend.SendOk", "您已经成功将邮件发送给好友"))
		 Call ApplicationTerminate()
	  End If
	  
      Dim StrPath
	  HTML = EL_Common.Template(ChannelID, 21, 0)
	  HTML = EL_Common.ReplaceCommonLabels(HTML)
	  
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ChannelID}", ChannelID)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ChannelName}", EL_Channel.ChannelName)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ChannelPictrue}", EL_Channel.ChannelPictrue)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ChannelDir}", EL_Channel.ChannelDir)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ItemName}", EL_Channel.ItemName)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ItemUnit}", EL_Channel.ItemUnit)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ClassItemName}", EL_Channel.ClassItemName)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$UploadDir}", EL_Channel.UploadDir)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$MetaKeywords}", "<meta name=""keywords"" content="""& EL_Channel.MetaKeywords &""" />")
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$MetaDescription}", "<meta name=""description"" content="""& EL_Channel.MetaDescription &""" />")
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ShowClassMenu}", "<script language='JavaScript1.2' type='text/JavaScript' src='"& InstallDir & EL_Channel.ChannelDir &"/Js/ShowClassMenu.js'></script>")
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ShowSearchForm}", "<script language='JavaScript' type='text/JavaScript' src='"& InstallDir & EL_Channel.ChannelDir &"/Js/ShowSearchForm.js'></script>")
	  
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$PageTitle}", EL_Common.Join2String(EL_Common.Join2String(SiteTitle, EL_Channel.ChannelName, EL_Common.TitleDivide), EL_Common.Lang("SendToFriend.PageTitle", "告诉好友"), EL_Common.TitleDivide))
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$DefaultSkin}", EL_Common.Skin(ChannelID, 0, 0))
	  
	  StrPath = EL_Common.Lang("BaseConfig.Path", "&nbsp;&gt;&gt;&nbsp;")	  
	  EL_Common.ShowPath = EL_Common.ShowPath & StrPath &"<a href='"& InstallDir & EL_Channel.ChannelDir &"/Index.asp'>"& EL_Channel.ChannelName &"</a>"& StrPath & EL_Common.Lang("SendToFriend.PageTitle", "告诉好友")
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$ShowPath}", EL_Common.ShowPath)
	  
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$InfoID}", InfoID)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$InfoTitle}", InfoTitle)
	  HTML = EL_Common.RegExpStaticLabel(HTML, "{$InfoURL}", ComeURL)
	  
	  Response.Write HTML 
   End Sub 
   
   Private Sub SendMail()
      Dim EL_SendMail, ToUserName, ToEmail, EmailBody
	  
	  ToUserName = EL_Common.ELRequest("FriendName", 1)
	  ToEmail = EL_Common.ELRequest("FriendEmail", 1)
	  EmailBody = "<HTML><BODY bgcolor=""#FFFFFF"">" 
	  EmailBody = EmailBody & ToUserName &"：<br>"
	  EmailBody = EmailBody & "&nbsp;&nbsp;&nbsp;&nbsp;您好！"
	  EmailBody = EmailBody & "&nbsp;&nbsp;&nbsp;&nbsp;您的朋友 "& EL_User.UserName &"（"& EL_User.TrueName &"） 给您推荐的"& EL_Channel.ItemName &"：<a href='"& ComeURL &"' target='_blank'>"& InfoTitle
	  EmailBody = EmailBody & "</a><br>链接地址："& ComeURL 
	  EmailBody = EmailBody & "<br><br>信息来源：<a href='"& SiteURL &"'>"& SiteName &"</a>"
	  EmailBody = EmailBody & "</BODY></HTML>"
	  
	  If EL_Common.CheckEmail(ToEmail) = False Then
	     EL_Common.ShowErrorMsg(EL_Common.Lang("BaseConfig.EmailError", "电子邮件格式错误"))
		 Call ApplicationTerminate()
	  End If
	  
	  Set EL_SendMail = New ClassSendMail
	  
	  EL_SendMail.SubjectName = InfoTitle
	  If Trim(EL_User.UserName) = "" Then
	     EL_SendMail.FromUserName = SiteName
	  Else
	     EL_SendMail.FromUserName = EL_User.UserName
	  End If
	  If Trim(EL_User.Email) = "" Then
	     EL_SendMail.FromEmail = WebmasterEmail
	  Else
	     EL_SendMail.FromEmail = EL_User.Email
	  End If
	  EL_SendMail.ToEmail = ToEmail
	  EL_SendMail.EmailBody = EmailBody
	  EL_SendMail.SendMail()
	  Set EL_SendMail = Nothing
   End Sub
   
   Private Function GetInfoTitle()
      Dim TitleCmd, rsTitle
	  Select Case EL_Channel.ChannelModule
	     Case 1: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Article", "Title", "ChannelID="& ChannelID &" And ArticleID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case 2: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Hotel", "HotelName", "ChannelID="& ChannelID &" And HotelID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case 3: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Product", "ProductName", "ChannelID="& ChannelID &" And ProductID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case 5: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Sight", "SightName", "ChannelID="& ChannelID &" And SightID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case 6: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Photo", "PhotoName", "ChannelID="& ChannelID &" And PhotoID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case 7: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Shop", "ProductName", "ChannelID="& ChannelID &" And ProductID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case 8: Call EL_Common.InitCommonCmd(TitleCmd, rsTitle, "EL_Car", "CarName", "ChannelID="& ChannelID &" And CarID="& InfoID &" And Passed="& EL_True &" And Deleted="& EL_False)
		 Case Else: 
		      EL_Common.ShowErrorMsg("频道模块错误")
			  Call ApplicationTerminate()
	  End Select
	  rsTitle.Close()
	  If TitleCmd(0) <> 1 Then
	     EL_Common.ShowErrorMsg(EL_Common.RegExpStaticLabel(EL_Common.Lang("BaseConfig.InfoError", "指定{$ItemName}不存在"), "{$ItemName}", EL_Channel.ItemName))
		 Set rsTitle = Nothing
		 Set TitleCmd = Nothing
		 Call ApplicationTerminate()
	  End If
	  rsTitle.Open()
	  GetInfoTitle = rsTitle(0)
	  rsTitle.Close()
	  Set rsTitle = Nothing
	  Set TitleCmd = Nothing
   End Function

End Class
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -