showuser.asp

依蓝旅游网站管理系统Elan2008.SP2

<%
Option Explicit
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
%>
<!--#Include File="../Conn.asp"-->
<!--#Include File="../Inc/Const.asp"-->
<%
On Error Resume Next

If EL_User.UserIsLogin = False Then
   Response.Redirect InstallDir &"User/User_Login.asp?url="& EL_Common.ServerURLEncode(Request.ServerVariables("SCRIPT_NAME") &"?"& Request.ServerVariables("QUERY_STRING"))
End If

Call ShowUser()
Call EL_Common.ShowScriptError()
Call ApplicationTerminate()


Sub ShowUser()
   Dim HTML, UserID, UserName
   Dim UserCmd, rsUser, FaceSize
   UserID = EL_Common.ELRequest("UserID", 2)
   UserName = EL_Common.ELRequest("UserName", 1)
   '优先查询UserID, 当UserID=0时，查询UserName
   Call EL_Common.InitCommand(UserCmd, "EL_SP_ShowUser")
   With UserCmd
      .Parameters.Append .CreateParameter("RETURN", 2, 4)
	  .Parameters.Append .CreateParameter("@UserID", 3, 1, 4, UserID)
	  .Parameters.Append .CreateParameter("@UserName", 200, 1, 50, UserName)
	  Set rsUser = .Execute()
   End With
   rsUser.Close()
   If UserCmd(0)<>1 Then
      EL_Common.ShowErrorMsg(EL_Common.Lang("User.Error16", "会员ID错误"))
	  Set rsUser = Nothing
	  Set UserCmd = Nothing
	  Exit Sub
   End If
   rsUser.Open()
   FaceSize = Split(rsUser("FaceSize"), "*")
   
   HTML = EL_Common.Template(-2, 14, 0)
   HTML = EL_Common.ReplaceCommonLabels(HTML)   
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$PageTitle}", EL_Common.Lang("User.ShowUser", "查看会员信息"))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$MetaKeywords}", "<meta name=""keywords"" content="""& MetaKeywords &""" />")
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$MetaDescription}", "<meta name=""description"" content="""& MetaDescription &""" />")
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$DefaultSkin}", EL_Common.Skin(0, 0, 0))

   HTML = EL_Common.RegExpStaticLabel(HTML, "{$UserName}", EL_Common.ServerHTMLEncode(rsUser("UserName")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$TrueName}", EL_Common.ServerHTMLEncode(rsUser("TrueName")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Userface}", "<img src='"& rsUser("Userface") &"' width='"& FaceSize(0) &"' height='"& FaceSize(1) &"'>")
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Sex}", EL_Common.Lang("User.Sex"& rsUser("Sex"), ""))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Birthday}", rsUser("Birthday"))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Mobile}", EL_Common.ServerHTMLEncode(rsUser("Mobile")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Phone}", EL_Common.ServerHTMLEncode(rsUser("Phone")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Fax}", EL_Common.ServerHTMLEncode(rsUser("Fax")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$QQ}", EL_Common.ServerHTMLEncode(rsUser("QQ")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$ICQ}", EL_Common.ServerHTMLEncode(rsUser("ICQ")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$MSN}", EL_Common.ServerHTMLEncode(rsUser("MSN")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Email}", EL_Common.ServerHTMLEncode(rsUser("Email")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Address}", EL_Common.ServerHTMLEncode(rsUser("Address")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$ZipCode}", EL_Common.ServerHTMLEncode(rsUser("ZipCode")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Marriage}", EL_Common.ServerHTMLEncode(rsUser("Marriage")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Job}", EL_Common.ServerHTMLEncode(rsUser("Job")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$JobTitle}", EL_Common.ServerHTMLEncode(rsUser("JobTitle")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$CompanyName}", EL_Common.ServerHTMLEncode(rsUser("CompanyName")))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$Sign}", EL_Common.UBB(EL_Common.HTMLEncode(rsUser("Sign"))))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$LoginTimes}", rsUser("LoginTimes"))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$LastLoginTime}", rsUser("LastLoginTime"))
   HTML = EL_Common.RegExpStaticLabel(HTML, "{$LastLoginIp}", rsUser("LastLoginIp"))
   If rsUser("Online") = True Then
      HTML = EL_Common.RegExpStaticLabel(HTML, "{$Status}", EL_Common.Lang("User.Online", "在线"))
   Else
      HTML = EL_Common.RegExpStaticLabel(HTML, "{$Status}", EL_Common.Lang("User.Offline", "离线"))
   End If
   
   rsUser.Close()
   Set rsUser = Nothing
   Set UserCmd = Nothing
   Response.Write HTML      
End Sub
%>