checknewuser.asp

依蓝旅游网站管理系统Elan2008.SP2

<%
Option Explicit
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
%>
<!--#Include File="../Conn.asp"-->
<!--#Include File="../Inc/Const.asp"-->
<%
On Error Resume Next

If ComeURL = "" Then
   EL_Common.ShowErrorMsg(EL_Common.Lang("BaseConfig.ComeURLError1", "禁止直接输入地址访问该页面"))
   Call ApplicationTerminate()
End If

Dim CheckUserCmd
Dim UserID, UserName, CheckCode

UserID = EL_Common.ELRequest("UserID", 2)
UserName = EL_Common.ELRequest("UserName", 1)
CheckCode = EL_Common.ELRequest("CheckCode", 1)

Call EL_Common.InitCommand(CheckUserCmd, "EL_SP_CheckNewUser")
With CheckUserCmd
  .Parameters.Append .CreateParameter("RETURN", 2, 4)
  .Parameters.Append .CreateParameter("@CheckType", 3, 1, 4, 1)
  .Parameters.Append .CreateParameter("@UserID", 3, 1, 4, UserID)
  .Parameters.Append .CreateParameter("@UserName", 200, 1, 50, UserName)
  .Parameters.Append .CreateParameter("@CheckCode", 200, 1, 128, CheckCode)
  .Execute()
End With
If CheckUserCmd(0) = 40 Then
   Set CheckUserCmd = Nothing
   EL_Common.ShowErrorMsg(EL_Common.Lang("User.Error10", "验证失败！会员名不存在或验证码错误"))
   Call ApplicationTerminate()
End If

EL_Common.ShowSuccessMsg(EL_Common.Lang("User.CheckSuccess", "恭喜！您的帐号已经成功验证！"))
EL_Common.ShowScriptError()
Call ApplicationTerminate()
%>