user_regsuccess.asp

依蓝旅游网站管理系统Elan2008.SP2

<%
Option Explicit
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
%>
<!--#Include File="../Conn.asp"-->
<!--#Include File="../Inc/Const.asp"-->
<%
On Error Resume Next

'检查页面来源
If CheckComeURL = False Then
   EL_Common.ShowErrorMsg(EL_Common.Lang("BaseConfig.ComeURLError", "禁止从本站外部提交数据"))
   Call ApplicationTerminate()
End If


Dim HTML, UserCmd, rsUser, CheckUserType, UserID, UserType, EmailPassed, AdminPassed, RetMessage

UserID = EL_Common.ELClng(Session("TempUserID"))

HTML = EL_Common.Template(-2, 13, 0)
HTML = EL_Common.ReplaceCommonLabels(HTML)   
HTML = EL_Common.RegExpStaticLabel(HTML, "{$PageTitle}", EL_Common.Join2String(SiteTitle, EL_Common.Lang("User.UserReg", "会员注册"), EL_Common.TitleDivide))
HTML = EL_Common.RegExpStaticLabel(HTML, "{$MetaKeywords}", "<meta name=""keywords"" content="""& MetaKeywords &""" />")
HTML = EL_Common.RegExpStaticLabel(HTML, "{$MetaDescription}", "<meta name=""description"" content="""& MetaDescription &""" />")
HTML = EL_Common.RegExpStaticLabel(HTML, "{$ShowPath}", EL_Common.Lang("BaseConfig.SiteIndex", "") & EL_Common.Lang("BaseConfig.Path", "&nbsp;&gt;&gt;&nbsp;") &"会员注册")
HTML = EL_Common.RegExpStaticLabel(HTML, "{$DefaultSkin}", EL_Common.Skin(0, 0, 0))  

Call EL_Common.InitCommonCmd(UserCmd, rsUser, "EL_User", "EmailPassed,AdminPassed", "UserID="& UserID)
EmailPassed = rsUser(0)
AdminPassed = rsUser(1)
rsUser.Close()
Set rsUser = Nothing


If EmailPassed = True And AdminPassed = True Then   
   RetMessage = EL_Common.Lang("User.SuccessMessage.t0", "您已经正式成为本站会员")
Else
   If EmailPassed = False Then
	  RetMessage = EL_Common.Lang("User.SuccessMessage.t1", "您注册的是普通会员，必须通过邮件验证，才能正式成为本站会员！系统已经发送注册确认邮件到您的注册邮箱，请及时接收邮件以通过验证")
   ElseIf AdminPassed = False Then
	  RetMessage = EL_Common.Lang("User.SuccessMessage.t2", "您注册的是普通会员，必须通过管理的认证，才能正式成为本站会员")
   End If
End If


HTML = EL_Common.RegExpStaticLabel(HTML, "{$RetMessage}", RetMessage)  
 
Response.Write HTML
Session("TempUserID") = ""
Call ApplicationTerminate()



Function CheckComeURL()
   CheckComeURL = False
   If ComeURL = "" Then Exit Function
   Dim Current_URL
   Current_URL = "http://" & Trim(Request.ServerVariables("HTTP_HOST"))
   Current_URL = Current_URL & Trim(Request.ServerVariables("SCRIPT_NAME"))
   CheckComeURL = EL_Common.CheckComefrom(ComeURL, Current_URL)
End Function
%>