hierarchy.sv

Open Verification Methodology

// $Id: hierarchy.sv,v 1.2 2008/01/02 09:22:50 jlrose Exp $
//----------------------------------------------------------------------
//   Copyright 2007-2008 Mentor Graphics Corporation
//   Copyright 2007-2008 Cadence Design Systems, Inc.
//   All Rights Reserved Worldwide
//
//   Licensed under the Apache License, Version 2.0 (the
//   "License"); you may not use this file except in
//   compliance with the License.  You may obtain a copy of
//   the License at
//
//       http://www.apache.org/licenses/LICENSE-2.0
//
//   Unless required by applicable law or agreed to in
//   writing, software distributed under the License is
//   distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
//   CONDITIONS OF ANY KIND, either express or implied.  See
//   the License for the specific language governing
//   permissions and limitations under the License.
//----------------------------------------------------------------------
package user_pkg;

import ovm_pkg::*;
`include "ovm_templates.svh"

//----------------------------------------------------------------------
// CLASS transaction
//----------------------------------------------------------------------
class transaction extends ovm_transaction;

  rand int data;
  rand int addr;

  function void copy( input transaction t );
    data = t.data;
    addr = t.addr;
  endfunction

  function bit comp( input transaction a , input transaction b );
    return ((a.data == b.data) && (a.addr == b.addr));
  endfunction

  function ovm_object clone();
    transaction t; t = new();
    t.copy(this);
    return t;
  endfunction

  function string convert2string();
    string s;
    $sformat(s, "[ addr = %x, data = %x ]", addr, data);
    return s;
  endfunction

endclass

//----------------------------------------------------------------------
// COMPONENT gen
//----------------------------------------------------------------------
class gen extends ovm_threaded_component;

  ovm_blocking_put_port #(transaction) put_port;

  function new(string name, ovm_component parent);
    super.new(name, parent);
    put_port = new("put_port", this);
  endfunction

  task run;
    transaction t;
    string msg;

    for(int i=0; i < 20; i++) begin
      t = new();
      assert(t.randomize());
      $sformat(msg, "sending  : %s", t.convert2string());
      ovm_report_info("gen", msg);
      put_port.put(t);
    end
  endtask

endclass


//----------------------------------------------------------------------
// COMPONENT conv
//----------------------------------------------------------------------
class conv extends ovm_threaded_component;

  ovm_blocking_put_port #(transaction) put_port;
  ovm_blocking_get_port #(transaction) get_port;

  function new(string name, ovm_component parent);
    super.new(name, parent);
    put_port = new("put_port", this);
    get_port = new("get_port", this);
  endfunction

  task run;
    transaction t;

    forever begin
      get_port.get(t);
      put_port.put(t);
    end
  endtask

endclass

//----------------------------------------------------------------------
// COMPONENT bfm
//----------------------------------------------------------------------
class bfm extends ovm_threaded_component;

  ovm_blocking_get_port #(transaction) get_port;

  function new(string name, ovm_component parent);
    super.new(name, parent);
    get_port = new("get_port", this);
  endfunction

  task run;
    transaction t;
    string msg;

    forever begin
      get_port.get(t);
      $sformat(msg, "receiving: %s", t.convert2string());
      ovm_report_info("bfm", msg);
    end
  endtask

endclass

//----------------------------------------------------------------------
// COMPONENT producer
//----------------------------------------------------------------------
// begin codeblock producer
class producer extends ovm_component;

  ovm_blocking_put_port #(transaction) put_port;

  gen g;
  conv c;
  tlm_fifo #(transaction) f;

  function new(string name, ovm_component parent);
    super.new(name, parent);
    put_port = new("put_port", this);
    g = new("gen", this);
    c = new("conv", this);
    f = new("fifo", this);
    g.put_port.connect(f.blocking_put_export);  // A
    c.get_port.connect(f.blocking_get_export);  // B
    c.put_port.connect(put_port); // C
  endfunction

endclass
// end codeblock producer

//----------------------------------------------------------------------
// COMPONENT consumer
//----------------------------------------------------------------------
// begin codeblock consumer
class consumer extends ovm_component;

  ovm_blocking_put_export #(transaction) put_export;

  bfm b;
  tlm_fifo #(transaction) f;

  function new(string name, ovm_component parent);
    super.new(name, parent);
    put_export = new("put_export", this);
    f = new("fifo", this);
    b = new("bfm", this);
    put_export.connect(f.blocking_put_export); // E
    b.get_port.connect(f.blocking_get_export); // F
  endfunction

endclass
// end codeblock consumer

//----------------------------------------------------------------------
// COMPONENT top
//----------------------------------------------------------------------
// begin codeblock top
class top extends ovm_component;

  producer p;
  consumer c;

  function new(string name, ovm_component parent);
    super.new(name, parent);
    p = new("producer", this);
    c = new("consumer", this);
    p.put_port.connect(c.put_export);  // D
  endfunction

endclass
// end codeblock top


//----------------------------------------------------------------------
// ENVIRONMENT env
//----------------------------------------------------------------------
// begin codeblock env
class env extends ovm_env;
  top t;

  function new(string name = "env");
    super.new(name);
    t = new("top", this);
  endfunction

  task run;
    #1000;
  endtask

endclass
// end codeblock env

endpackage

//----------------------------------------------------------------------
// MODULE top
//----------------------------------------------------------------------
// begin codeblock topmod
module top;

  import user_pkg::*;
  env e;

  initial begin
    e = new("e");
    e.do_test();
  end

endmodule
// end codeblock topmod