admin_newsmodifysave.asp

简单明晰的asp后台代码 新闻 产品

<!--#include file = "../inc/dbclass.inc.asp" -->
<!--#include file = "../inc/syslogincheck.inc.asp" -->

<%
' =============================================================
' made by xiasp & 智多网络 http://www.cq18.com/ qq群：12403617
' =============================================================
%>

<%
call header("增加新闻保存")
call content()
call footer()

' 本页内容区
sub content()

	dim i

	' 传入参数：新闻id
	dim snewsid
	snewsid = getsafeint(trim(request("id")),0)

	' 新闻id有效性验证，防止有些人恶意的破坏此演示程序
	if snewsid < 1 then
		goerror "请通过页面上的链接进行操作，不要试图进行任何非法操作。"
	end if

	' 取提交过来的数据
	' 注意取新闻内容的方法，因为对大表单的自动处理，一定要使用循环，否则大于100k的内容将取不到，单个表单项的限制为102399字节（100k左右）
	dim scataid, stitle, scontent, spicture, sfrom, sspecial
	scataid = request.form("d_cataid")
	stitle = request.form("d_title")
	spicture = request.form("d_picture")
	sfrom = request.form("d_from")
	sspecial = request.form("d_special")

	' 开始：ewebeditor编辑区取值-----------------
	scontent = ""
	for i = 1 to request.form("d_content").count
		scontent = scontent & request.form("d_content")(i)
	next
	' 结束：ewebeditor编辑区取值-----------------

	' 以下为所有通过编辑器上传的所有文件相关信息，包括编辑区手动上传的和自动远程上传的
	' getsafestr函数为过滤一些特殊字符，防止有些人恶意的破坏此演示程序

	' 上传后保存到本地服务器的文件名（不带路径），多个以"|"分隔
	dim ssavefilename
	' 上传后保存到本地服务器的路径文件名，多个以"|"分隔
	dim ssavepathfilename
	ssavefilename = getsafestr(request.form("d_savefilename"))
	ssavepathfilename = getsafestr(request.form("d_savepathfilename"))

	' 保存新闻内容，同时取出自增的新闻id
	ssql = "select * from newsdata where d_id=" & snewsid
	ors.open ssql, oconn, 1, 3
	if not ors.eof then
		ors("d_cataid") = scataid
		ors("d_title") = stitle
		ors("d_content") = scontent
		ors("d_picture") = spicture
		ors("d_savefilename") = ssavefilename
		ors("d_savepathfilename") = ssavepathfilename
		ors("d_from") = sfrom
		if sspecial = 1 then ors("d_special") = sspecial
		ors.update
		ors.close
		set ors = nothing
		call oktowhere("新闻信息修改成功，确认返回！","-2")
	else
		goerror "无效的新闻id，请点页面上的链接进行操作！"
	end if
	

end sub
%>