gobor_config.asp

e路小说小偷 免维护

<%
'系统变量
Dim LastHTML,LastMain,LastList,LastPage,LastTit
Dim i,li,Tmp,BiaoTi,ZuoZhe,ZhangJie,ZiShu,ZhuangTai,GengXin,NeiRong,MiaoShu
Dim PageDown,NextPage,BackPage,BackID,NextID,TxtID

Response.Charset = "GB2312" '不设置中文会乱码
Server.ScriptTimeOut = 999999999

Dim Web
	Web = LCase(Request.ServerVariables("SERVER_NAME"))
Dim Url
	Url = LCase(Request.ServerVariables("URL"))
Dim Query
	Query = LCase(Request.ServerVariables("QUERY_STRING"))
Dim myGoBor
	Set myGoBor = New GoBor_ClsSteal
Dim myCache
	Set myCache = New Cache
Dim cID,bID,rID
    cID = Trim(Request("cID")) '类别ID
    If Len(cID) = 0 Or Not IsNumeric(cID) Then cID = 0
    cID = Clng(cID)
    bID = Trim(Request("bID")) '书页ID
    If Len(bID) = 0 Or Not IsNumeric(bID) Then bID = 0
    bID = Clng(bID)
    rID = Trim(Request("rID")) '章节ID
    If Len(rID) = 0 Or Not IsNumeric(rID) Then rID = 0
    rID = Clng(rID)
Dim Act
    Act = LCase(Request("GoBor"))
Dim SearchType,SearchKey
		SearchType = Trim(Replace(Request("searchtype"),"'","''")) : SearchKey = Trim(Replace(Request("searchkey"),"'","''"))
Dim initial
    initial = LCase(Request("initial"))	'字母排列
Dim Page
    Page = LCase(Request("page"))
    If Len(Page) = 0 Or Not IsNumeric(Page) Then Page = 1
    Page = Clng(Page)

Class GoBor_ClsSteal
	Private oXmlHttp, oAdos, oTempReg
	Private GoBor_sMethod
	
	Private Sub Class_Initialize
		Set oXmlHttp = Server.CreateObject("Msxml2.ServerXMLHTTP")
		Set oAdos = Server.CreateObject("ADODB.Stream")
		Set oTempReg = New RegExp
		GoBor_sMethod = "GET"
	End Sub
	
	Private Sub Class_Terminate
		Set oXmlHttp = Nothing
		Set oAdos = Nothing
		Set oTempReg = Nothing
	End Sub
	
	Public Function GB(Str)
		Response.Write Str
	End Function

	Public Property get Version
		Version = "e路小说(www.elu3.com)小说小偷v1.2.0815"
	End Property
	
	Public Function Cut(ByVal sCUrl,ByVal sCset)
		If IsNull(sCUrl) = True Or sCUrl = "$False$" Then Cut = sCUrl : Exit Function
		With oXmlHttp
			.Open GoBor_sMethod,sCUrl,False
			.Send()
			If .ReadyState<>4 Or .Status<>200 Then 
			Cut = "$False$" : Exit Function
			Else
			Cut = ByTesToBStr(.ResponseBody,sCset)
			End If
		If Err.Number<>0 Then Err.Clear
		End With
	End Function
	
	Public Function BytesToBstr(ByVal sBody,ByVal sCset)
		With oAdos
			.Type = 1
			.Mode = 3
			.Open
			.Write sBody
			.Position = 0
			.Type = 2
			.Charset = sCset
			BytesToBstr = .ReadText
			.Close
		End With
	End Function
	
	Function Key(ByVal ConStr,ByVal StartStr,ByVal OverStr,ByVal IncluL,ByVal IncluR)
		If ConStr="$False$" or ConStr="" or IsNull(ConStr)=True Or StartStr="" or IsNull(StartStr)=True Or OverStr="" or IsNull(OverStr)=True Then Key="$False$" : Exit Function
		Dim ConStrTemp,Start,Over
		ConStrTemp = LCase(ConStr) : StartStr = LCase(StartStr) : OverStr = LCase(OverStr)
		Start = InStrB(1, ConStrTemp, StartStr, vbBinaryCompare)
		If Start <= 0 then 
			Key = "$False$" : Exit Function
   		Else
		If IncluL = False Then : Start = Start + LenB(StartStr)
   		End If
   		Over = InStrB(Start,ConStrTemp,OverStr,vbBinaryCompare)
   		If Over <= 0 Or Over <= Start then
      		Key = "$False$" : Exit Function
		Else
      		If IncluR = True Then Over = Over + LenB(OverStr)
   		End If
		Key = MidB(ConStr,Start,Over-Start)
	End Function
	
	Public Function Rep(ByVal sValue,ByVal sPatrn,ByVal sNewStr)
		If sValue = "" Then Exit Function
		With oTempReg
			.IgnoreCase = True
			.Global = True
			.Pattern = sPatrn
			Rep = .Replace(sValue, sNewStr)
		End With
	End Function
	
	Public Function Cache(ByVal GUrl,ByVal GSex,ByVal GName)
		myCache.name = UCase(GName)
		If myCache.valid and InStr(myCache.value,"$False$") = 0 then
			Cache = myCache.value
		Else
			Cache = Cut(GUrl,GSex)
			myCache.add Cache,dateadd("h",3,Now)
		End If
	If myCache.value = "$False$" Then Response.Write("<script>alert('您查看的小说因故已被删除！');location='" & GoBor_sFileName & "';</script>") : Response.End
	End Function
	
	Public Function Un(ByVal word,ByVal snum) 
	Word = Replace(Word,"&nbsp;","")
	If IsNull(Word) Then Exit Function 
		With oTempReg
		    .Global = True :  .IgnoreCase = True : .Pattern = "<.*?>" : Word = .Replace(Word,"") 
			If Snum <> 0 Then
	        	If Len(Word) > Snum Then Word = Left(Word,Snum)+".." 
			End If
	        .Pattern="\r\n\s*" : Word = .Replace(Word,"") 
		End With
	  Un = Replace(Replace(Word,Chr(10),""),Chr(32),"")
	End Function
End Class	
%>