frmlogin.frm

一个用VB写的财务软件源码

VERSION 5.00
Begin VB.Form frmLogin 
   BorderStyle     =   1  'Fixed Single
   Caption         =   "注册"
   ClientHeight    =   1410
   ClientLeft      =   2625
   ClientTop       =   2460
   ClientWidth     =   3885
   ControlBox      =   0   'False
   Icon            =   "frmLogin.frx":0000
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   1410
   ScaleWidth      =   3885
   StartUpPosition =   2  '屏幕中心
   Begin VB.CommandButton cmdModifyPassword 
      Caption         =   "修改口令(&M)"
      Height          =   300
      Left            =   2570
      TabIndex        =   6
      Top             =   480
      Width           =   1215
   End
   Begin VB.TextBox txtPassword 
      Height          =   300
      IMEMode         =   3  'DISABLE
      Left            =   950
      PasswordChar    =   "*"
      TabIndex        =   3
      Top             =   480
      Width           =   1545
   End
   Begin VB.ComboBox cboUser 
      Height          =   300
      ItemData        =   "frmLogin.frx":27A2
      Left            =   950
      List            =   "frmLogin.frx":27A4
      Style           =   2  'Dropdown List
      TabIndex        =   1
      Top             =   150
      Width           =   2835
   End
   Begin VB.CommandButton cmdCancel 
      Cancel          =   -1  'True
      Caption         =   "取消(&C)"
      Height          =   345
      Left            =   2340
      TabIndex        =   5
      Top             =   960
      Width           =   1065
   End
   Begin VB.CommandButton cmdOk 
      Caption         =   "确认(&O)"
      Default         =   -1  'True
      Height          =   345
      Left            =   600
      TabIndex        =   4
      Top             =   960
      Width           =   1065
   End
   Begin VB.Label lblKl 
      AutoSize        =   -1  'True
      Caption         =   "口令(&P)："
      Height          =   180
      Left            =   120
      TabIndex        =   2
      Top             =   540
      Width           =   810
   End
   Begin VB.Label lblXm 
      AutoSize        =   -1  'True
      Caption         =   "操作员(&N)："
      Height          =   180
      Left            =   75
      TabIndex        =   0
      Top             =   210
      Width           =   990
   End
End
Attribute VB_Name = "frmLogin"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Option Base 1

Public OK As Boolean
Private Type UserUDT
    UserID As String        '用户代号
    Password As String      '密码
    Type As Integer         '人员性质
End Type
Dim aryUser() As UserUDT
Public m_sUserID As String
Private m_sUserName As String
Private m_iUserType As Integer


Public Property Get usUserID() As String
    usUserID = m_sUserID
End Property
Public Property Get usUserName() As String
    usUserName = m_sUserName
End Property
Public Property Get uiUserType() As Integer
    uiUserType = m_iUserType
End Property



Private Sub cboUser_Click()
txtPassword.text = ""
End Sub

Private Sub cmdCancel_Click()
    OK = False
    Unload Me
End Sub


Private Sub Form_Initialize()
    OK = False
End Sub

Private Sub Form_Load()
    
    Dim sSql As String, i As Long
    Dim rstUser As ADODB.Recordset

    '装入所有操作员
    cboUser.Clear
    sSql = "select * from tSYS_User order by titype,userid"
    Set rstUser = New ADODB.Recordset
    With rstUser
        .CursorLocation = adUseClient
        .Open sSql, gloSys.cnnSys, adOpenStatic, adLockReadOnly
        If .RecordCount > 0 Then
            .MoveFirst
            ReDim aryUser(.RecordCount)
            For i = 1 To .RecordCount
                cboUser.AddItem "[" & .Fields("userID").Value & "]" & _
                        .Fields("userName").Value
                cboUser.ItemData(cboUser.NewIndex) = i          '用于指针数组
                aryUser(i).UserID = .Fields("userID").Value
                aryUser(i).Password = s.decrypt(Trim("" & .Fields("password").Value))
                aryUser(i).Type = .Fields("tiType").Value
                .MoveNext
            Next i
            cboUser.ListIndex = 0
        End If
    End With

End Sub


Private Sub cmdOk_Click()
        
    If txtPassword.text <> aryUser(cboUser.ItemData(cboUser.ListIndex)).Password Then
        MsgBox "密码错误！", vbInformation
        txtPassword.SelStart = 0
        txtPassword.SelLength = Len(txtPassword.text)
        txtPassword.SetFocus
    Else
'        If DogCheck Then
            OK = True
            m_sUserID = aryUser(cboUser.ItemData(cboUser.ListIndex)).UserID
            m_sUserName = Mid$(cboUser.text, InStr(1, cboUser.text, "]") + 1)
            m_iUserType = aryUser(cboUser.ItemData(cboUser.ListIndex)).Type
            Unload Me
'        End If
    End If
    

End Sub


Private Sub cmdModifyPassword_Click()
    
    Dim adoCmd As ADODB.Command
    
    '修改密码先检查原密码是否正确
    If txtPassword.text <> aryUser(cboUser.ItemData(cboUser.ListIndex)).Password Then
        MsgBox "原密码错误！", vbInformation
        txtPassword.SelStart = 0
        txtPassword.SelLength = Len(txtPassword.text)
        txtPassword.SetFocus
    Else
        frmModifyPassword.Show 1, Me
        If frmModifyPassword.OK Then
            '修改动态数组中该用户的密码
            aryUser(cboUser.ItemData(cboUser.ListIndex)).Password = _
                    frmModifyPassword.usNewPassword
            '修改数据库中该用户的密码
            Set adoCmd = New ADODB.Command
            adoCmd.ActiveConnection = gloSys.cnnSys
            adoCmd.CommandText = "Update tSYS_user set Password='" & _
                s.encrypt(frmModifyPassword.usNewPassword) & "' where userID='" & _
                aryUser(cboUser.ItemData(cboUser.ListIndex)).UserID & "'"
            adoCmd.Execute
        End If
    End If
    
End Sub