clsnormal.cls

一个用VB写的财务软件源码

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsNormal"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit
'“通用”类

Private m_adoRst As ADODB.Recordset


'方法：向数据集保存一条记录。
'   字段名：
'   值。
Public Sub SaveOneField(FieldName As String, Value As Variant)

    On Error GoTo ErrorHandler
        m_adoRst.Fields(FieldName).Value = Value
    Exit Sub

ErrorHandler:
    m_adoRst.Fields(FieldName).Value = Null
    
End Sub


'方法：从数据集取一个值填充一个控件。
'   字段名；
'   控件名称。
Public Sub FillOneBox(FieldName As String, TB As Control, ValueType As Byte)

    On Error GoTo Err
    With m_adoRst
        Select Case ValueType
            Case 2
                TB.Text = IIf(IsNull(.Fields(FieldName).Value), "____-__-__", _
                            Format(.Fields(FieldName).Value, "yyyy-mm-dd"))
            Case 1
                TB.Text = IIf(IsNull(.Fields(FieldName).Value), "", _
                            Trim$("" & .Fields(FieldName).Value))
            Case 0
                TB.Text = IIf(IsNull(.Fields(FieldName).Value), 0, _
                            Format(.Fields(FieldName).Value, "##0.00"))
        End Select
    End With
    
    Exit Sub

Err:
    MsgBox "数据库中没有此数据项！", vbCritical
End Sub


'方法：清空一个文本框。
'   控件名称；
'   清空值类型：0、清为“0”；1、清为“”；2、清为日期“____-__-__”。
Public Sub ClearOneBox(TB As Control, ClearType As Byte)
    Select Case ClearType
        Case 0
            TB.Text = 0
        Case 1
            TB.Text = ""
        Case 2
            TB.Text = "____-__-__"
    End Select
End Sub


'方法：锁定一个控件。
Public Sub LockOneBox(TB As Control)
    TB.BackColor = &H80000016
    TB.Enabled = False
End Sub


'方法：解除一个控件的锁定。
Public Sub UnlockOneBox(TB As Control)
    TB.BackColor = vbWhite
    TB.Enabled = True
End Sub