runstat.bat

StatSVN能够从Subversion版本库中取得信息

@ECHO ON

rem 调用格式 runstat 仓库路径 本地名称 发布目录
set repos=%1
set localname=%2
set target=%3

SET LOWER=0
SET UPPER=0

rem 检查一下仓库的最新版本，如果最新版本为0，说明没有内容不需要统计，直接跳出
@FOR /f %%D IN ('%SVN_LOOK% youngest %repos%') DO set UPPER=%%D
if %UPPER%==0 GOTO :N_EXIT

rem 如果子目录已经存在，认为工作拷贝已经存在，则直接更新，不进行检出工作
if exist .\%localname%\nul GOTO :UPDATE

rem 检出指定的仓库路径到本地名称为目录名的目录下
:CHECKOUT
mkdir .\%localname%

%SVN_SVN% co file:///%repos% .\%localname%

rem 取出上次Update的版本号和当前版本号进行比较，如果版本号较旧则进行更新，否则说明不需要更新，直接跳出
:UPDATE
if not exist .\%localname%\%localname%_last_revision.txt GOTO :BEGIN_UPDATE

rem 取出上次备份后的版本号，并做＋1处理(注意此算法未在98系统验证)
@FOR /f %%C IN (.\%localname%\%localname%_last_revision.txt) DO @set LOWER=%%C
@set /a LOWER=%LOWER%+1

rem 不需要更新，则跳转结束
IF %LOWER% gtr %UPPER% GOTO :N_EXIT

rem 更新版本库并记录最新的版本号
:BEGIN_UPDATE
%SVN_SVN% update .\%localname%
@echo %UPPER% > .\%localname%\%localname%_last_revision.txt

rem 生成XMLLog文件logfile.log
cd %localname%
%SVN_SVN% log -v --xml > logfile.log

rem 调用Statsvn进行统计，本例中指定了需要统计的文件类型，并把结果输出到指定的目录，同时开50个线程进行查询。
java -jar %STATSVN_JAR% -output-dir %target%\%localname% %target%\%localname%\logfile.log %target%\%localname% -include **/*.java;**/*.js;**/*jsp;**/*.xml -title SVNSpace -threads 50

cd ..

rem 到这里统计文件已经生成，可以到指定的发布目录进行查看了。
:N_EXIT
@echo 项目库%localname%处理结束...
@exit /B