manage_create_config.asp

JTBC网站内容管理系统是一套可扩充的网站内容管理系统

<%
Response.Expires = 0
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"

Dim slng: slng = get_safecode(request.querystring("slng"))

Sub jtb_cms_manage_create_detail()
  Dim tsortid, tsortids, tstartid, tendid, tcreatenew, ttitle
  tsortid = get_num(request.querystring("sortid"), 0)
  tstartid = get_num(request.querystring("startid"), 0)
  tendid = get_num(request.querystring("endid"), 0)
  tcreatenew = get_num(request.querystring("createnew"), 0)
  If not tsortid = -1 Then
    tsortids = tsortid
  Else
    Dim ti, tsortidary
    tsortidary = get_sortary(ngenre, slng)
    For ti = 0 to UBound(tsortidary)
      tsortids = tsortids & tsortidary(ti, 0) & ","
    Next
    tsortids = Left(tsortids, Len(tsortids) - 1)
  End If
  Dim trs, tsqlstr
  tsqlstr = "select * from " & ndatabase & " where " & cfname("hidden") & "=0 and " & cfname("class") & " in (" & tsortids & ")"
  If not tstartid = 0 Then tsqlstr = tsqlstr & " and " & nidfield & ">=" & tstartid
  If not tendid = 0 Then tsqlstr = tsqlstr & " and " & nidfield & "<=" & tendid
  If tcreatenew = 1 Then tsqlstr = tsqlstr & " and " & cfname("update") & "=0"
  Set trs = server.CreateObject("adodb.recordset")
  trs.open tsqlstr, conn, 1, 3
  Dim theadxml: theadxml = "<?xml version=""1.0"" encoding=""utf-8""?>" & vbcrlf
  theadxml = theadxml & "<?xml-stylesheet type=""text/xsl"" href=""" & get_lrstr(nuri, "/", "leftr") & "/detail_" & slng & ".xslt""?>" & vbcrlf
  theadxml = theadxml & "<xml>" & vbcrlf
  Dim tfootxml: tfootxml = "</xml>"
  Dim tmpstr, tmpurl, tscount, tecount
  tscount = 0: tecount = 0
  Do While not trs.EOF
    ttitle = ntitle & spstr & get_str(trs(cfname("topic")))
    tmpurl = ncreatefolder & "/detail/" & format_date(trs(cfname("time")), 2) & "/" & trs(nidfield) & ncreatefiletype
    tmpstr = theadxml
    tmpstr = tmpstr & "  <title><![CDATA[" & encode_forxml(web_title(ttitle)) & "]]></title>" & vbcrlf
    tmpstr = tmpstr & "  <sort><![CDATA[" & get_num(trs(cfname("class")), 0) & "]]></sort>" & vbcrlf
    tmpstr = tmpstr & "  <language><![CDATA[" & slng & "]]></language>" & vbcrlf
    tmpstr = tmpstr & "  <detail>" & vbcrlf
    tmpstr = tmpstr & "    <id><![CDATA[" & get_str(trs(nidfield)) & "]]></id>" & vbcrlf
    tmpstr = tmpstr & "    <topic><![CDATA[" & encode_forxml(get_str(trs(cfname("topic")))) & "]]></topic>" & vbcrlf
    tmpstr = tmpstr & "    <count><![CDATA[" & get_num(trs(cfname("count")), 0) & "]]></count>" & vbcrlf
    tmpstr = tmpstr & "    <time><![CDATA[" & get_date(trs(cfname("time"))) & "]]></time>" & vbcrlf
    tmpstr = tmpstr & "    <content><![CDATA[" & encode_forxml(encode_forscript(encode_content(trs(cfname("content")), trs(cfname("cttype"))))) & "]]></content>" & vbcrlf
    tmpstr = tmpstr & "  </detail>" & vbcrlf
    tmpstr = tmpstr & tfootxml
    If create_file_text(tmpurl, tmpstr) Then
      tscount = tscount + 1
      If trs(cfname("update")) = 0 Then
        trs(cfname("update")) = 1
        trs.update
      End If
    Else
      tecount = tecount + 1
    End If
  trs.movenext
  Loop
  Set trs = Nothing
  response.write "ok:" & tscount & ":" & tecount
End Sub

Sub jtb_cms_manage_create_list()
  Dim ti, tsortid, ttitle
  Dim tirs, tclass, tlsturl, tmpstr, tmpurl, tscount, tecount
  tirs = 0: tmpstr = "": tscount = 0: tecount = 0
  tsortid = get_num(request.querystring("sortid"), 0)
  If tsortid = -1 Then
    tsortid = get_sortary(ngenre, slng)
  Else
    ReDim tsortid(0, 0)
    tsortid(0, 0) = get_num(request.querystring("sortid"), 0)
  End If
  Dim trs, tsqlstr
  Dim theadxml: theadxml = "<?xml version=""1.0"" encoding=""utf-8""?>" & vbcrlf
  theadxml = theadxml & "<?xml-stylesheet type=""text/xsl"" href=""" & get_lrstr(nuri, "/", "leftr") & "/list_" & slng & ".xslt""?>" & vbcrlf
  theadxml = theadxml & "<xml>" & vbcrlf
  Dim tfootxml: tfootxml = "</xml>"
  Dim tannexxml
  Dim tpages
  If IsArray(tsortid) Then
    For ti = 0 to UBound(tsortid)
      ttitle = ntitle & spstr & get_sorttext(ngenre, slng, tsortid(ti, 0))
      tsqlstr = "select * from " & ndatabase & " where " & cfname("hidden") & "=0 and " & cfname("class") & "=" & tsortid(ti, 0) & " order by " & cfname("time") & " desc"
      Set trs = server.CreateObject("adodb.recordset")
      trs.open tsqlstr, conn, 1, 1
      tirs = 0: tpages = CLng(trs.recordcount/npagesize)
      Do While not trs.EOF
        tmpstr = tmpstr & "  <list>" & vbcrlf
        tmpstr = tmpstr & "    <topic><![CDATA[" & encode_forxml(get_str(trs(cfname("topic")))) & "]]></topic>" & vbcrlf
        tmpstr = tmpstr & "    <time><![CDATA[" & format_date(get_date(trs(cfname("time"))), 1) & "]]></time>" & vbcrlf
        tmpstr = tmpstr & "    <count><![CDATA[" & get_num(trs(cfname("count")), 0) & "]]></count>" & vbcrlf
        tmpstr = tmpstr & "    <linkurl><![CDATA[" & ncreatefolder & "/detail/" & format_date(trs(cfname("time")), 2) & "/" & trs(nidfield) & ncreatefiletype & "]]></linkurl>" & vbcrlf
        tmpstr = tmpstr & "  </list>" & vbcrlf
        trs.movenext
        If ((not tirs = 0) and (tirs mod npagesize = 0)) or trs.EOF Then
          tlsturl = CLng(tirs/npagesize)
          If tlsturl = 0 Then tlsturl = 1
          If tpages = 0 Then tpages = 1
          tmpurl = ncreatefolder & "/list/" & tsortid(ti, 0) & "/" & tlsturl & ncreatefiletype
          tannexxml = "  <title><![CDATA[" & encode_forxml(web_title(ttitle)) & "]]></title>" & vbcrlf
          tannexxml = tannexxml & "  <sort><![CDATA[" & tsortid(ti, 0) & "]]></sort>" & vbcrlf
          tannexxml = tannexxml & "  <language><![CDATA[" & slng & "]]></language>" & vbcrlf
          tannexxml = tannexxml & "  <npage><![CDATA[" & tlsturl & "]]></npage>" & vbcrlf
          tannexxml = tannexxml & "  <npages><![CDATA[" & tpages & "]]></npages>" & vbcrlf
          tmpstr = theadxml & tannexxml & tmpstr
          tmpstr = tmpstr & tfootxml
          If create_file_text(tmpurl, tmpstr) Then
            tscount = tscount + 1
          Else
            tecount = tecount + 1
          End If
          tmpstr = ""
        End If
        tirs = tirs + 1
      loop
    Next
  End If
  response.write "ok:" & tscount & ":" & tecount
End Sub

Sub jtb_cms_manage_create_template()
  Dim thtml_index, thtml_list, thtml_detail
  thtml_index = get_num(request.querystring("html_index"), 0)
  thtml_list = get_num(request.querystring("html_list"), 0)
  thtml_detail = get_num(request.querystring("html_detail"), 0)
  Dim tmpstr, tmpurl, tscount, tecount
  tscount = 0: tecount = 0
  If thtml_index = 1 Then
    tmpstr = ireplace("module.index", "tpl")
    tmpurl = "index_" & slng & ".html"
    If create_file_text(tmpurl, encode_newline(tmpstr)) Then
      tscount = tscount + 1
    Else
      tecount = tecount + 1
    End If
  End If
  If thtml_list = 1 Then
    tmpstr = ireplace("module.list", "tpl")
    tmpurl = "list_" & slng & ".xslt"
    If create_file_text(tmpurl, encode_newline(tmpstr)) Then
      tscount = tscount + 1
    Else
      tecount = tecount + 1
    End If
  End If
  If thtml_detail = 1 Then
    tmpstr = ireplace("module.detail", "tpl")
    tmpurl = "detail_" & slng & ".xslt"
    If create_file_text(tmpurl, encode_newline(tmpstr)) Then
      tscount = tscount + 1
    Else
      tecount = tecount + 1
    End If
  End If
  response.write "ok:" & tscount & ":" & tecount
End Sub

Sub jtb_cms_manage_create_sort()
  Dim theadxml: theadxml = "<?xml version=""1.0"" encoding=""utf-8""?>" & vbcrlf
  theadxml = theadxml & "<xml>" & vbcrlf
  Dim tfootxml: tfootxml = "</xml>"
  Dim ti, tsortary
  Dim tmpstr, tmpurl, tscount, tecount
  tscount = 0: tecount = 0
  tsortary = get_sortary(ngenre, slng)
  If IsArray(tsortary) Then
    For ti = 0 to UBound(tsortary)
      tmpstr = tmpstr & "  <sort id=""" & tsortary(ti, 0) & """ fid=""" & tsortary(ti, 2) & """><![CDATA[" & tsortary(ti, 1) & "]]></sort>" & vbcrlf
      tscount = tscount + 1
    Next
  End If
  tmpstr = theadxml & tmpstr
  tmpstr = tmpstr & tfootxml
  tmpurl = "sort_" & slng & ncreatefiletype
  If create_file_text(tmpurl, encode_newline(tmpstr)) Then
    response.write "ok:" & tscount & ":" & tecount
  End If
End Sub

Sub jtb_cms_manage_create()
  Select Case request.querystring("type")
    Case "detail"
      Call jtb_cms_manage_create_detail
    Case "list"
      Call jtb_cms_manage_create_list
    Case "template"
      Call jtb_cms_manage_create_template
    Case "sort"
      Call jtb_cms_manage_create_sort
  End select
End Sub
%>