module_config.asp

JTBC网站内容管理系统是一套可扩充的网站内容管理系统

<%
'****************************************************
' Jetiben CMS Power by Jetiben.com
' Email: [e-mail]
' Web: http://www.jetiben.com/
'****************************************************
Function module_data_side()
  Dim tmpstr, tpgenre
  tpgenre = get_str(request.querystring("pgenre"))
  tmpstr = ireplace("module.data_side", "tpl")
  tmpstr = replace(tmpstr, "{$pgenre}", tpgenre)
  module_data_side = tmpstr
End Function

Function module_data_pay()
  Dim torderid, tpgenre, tmpstr
  torderid = get_safecode(request.querystring("orderid"))
  tpgenre = get_str(request.querystring("pgenre"))
  Dim tdatabase, tidfield, tfpre
  tdatabase = cndatabase(tpgenre, "0")
  tidfield = cnidfield(tpgenre, "0")
  tfpre = cnfpre(tpgenre, "0")
  If check_null(tdatabase) Then Exit Function
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & tdatabase & " where " & cfnames(tfpre, "state") & "<>-1 and " & cfnames(tfpre, "orderid") & "='" & torderid & "'"
  rs.open sqlstr, conn, 1, 3
  If not rs.EOF Then
    If rs(cfnames(tfpre, "prepaid")) = 1 Then
      Call imessage(itake("module.prepaid", "lng"), -1)
    Else
      tmpstr = itake("module.data_detail", "tpl")
      tmpstr = replace(tmpstr, "{$orderid}", torderid)
      tmpstr = replace(tmpstr, "{$name}", get_str(rs(cfnames(tfpre, "name"))))
      tmpstr = replace(tmpstr, "{$address}", get_str(rs(cfnames(tfpre, "address"))))
      tmpstr = replace(tmpstr, "{$money}", get_num(rs(cfnames(tfpre, "allprice")), 0))
      tmpstr = creplace(tmpstr)
    End If
    module_data_pay = tmpstr
  Else
    Call imessage(itake("module.inexistence", "lng"), -1)
  End If
  Set rs = Nothing
End Function

Function module_data_receive()
  Dim torderid, tpgenre, tmpstr
  torderid = get_safecode(request.querystring("orderid"))
  tpgenre = get_str(request.querystring("pgenre"))
  Dim tdatabase, tidfield, tfpre
  tdatabase = cndatabase(tpgenre, "0")
  tidfield = cnidfield(tpgenre, "0")
  tfpre = cnfpre(tpgenre, "0")
  If check_null(tdatabase) Then Exit Function
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & tdatabase & " where " & cfnames(tfpre, "orderid") & "='" & torderid & "'"
  rs.open sqlstr, conn, 1, 3
  If not rs.EOF Then
    If rs(cfnames(tfpre, "prepaid")) = 1 Then
      Call imessage(itake("module.prepaid", "lng"), 0)
    Else
      Dim tpaymoney: tpaymoney = ipay_receive
      Dim tpaystr
      If tpaymoney = -1 Then
        tpaystr = itake("module.payinfo1", "lng")
      ElseIf tpaymoney <> get_num(rs(cfnames(tfpre, "allprice")), 0) Then
        tpaystr = itake("module.payinfo2", "lng")
      Else
        tpaystr = itake("module.payinfo3", "lng")
        rs(cfnames(tfpre, "prepaid")) = 1
        rs(cfnames(tfpre, "payid")) = payid
        rs.update
        Call update_support_payment_information(torderid, payid, tpgenre, rs(tidfield), tpaymoney)
      End If
      tmpstr = itake("module.data_receive", "tpl")
      tmpstr = replace(tmpstr, "{$orderid}", torderid)
      tmpstr = replace(tmpstr, "{$paystr}", tpaystr)
      tmpstr = creplace(tmpstr)
    End If
    module_data_receive = tmpstr
  Else
    Call imessage(itake("module.inexistence", "lng"), 0)
  End If
  Set rs = Nothing
End Function

Function jtb_cms_module_pay()
  Dim tmpstr: tmpstr = ireplace("module.pay", "tpl")
  jtb_cms_module_pay = tmpstr
End Function

Function jtb_cms_module_receive()
  Dim tmpstr: tmpstr = ireplace("module.receive", "tpl")
  jtb_cms_module_receive = tmpstr
End Function

Function jtb_cms_module
  Select Case request.querystring("type")
    Case "pay"
      jtb_cms_module = jtb_cms_module_pay
    Case "receive"
      jtb_cms_module = jtb_cms_module_receive
    Case Else
      jtb_cms_module = jtb_cms_module_pay
  End Select
End Function
'****************************************************
' Jetiben CMS Power by Jetiben.com
' Email: [e-mail]
' Web: http://www.jetiben.com/
'****************************************************
%>