module_config.asp

JTBC网站内容管理系统是一套可扩充的网站内容管理系统

      jtb_cms_module = jtb_cms_module_commence
    Case "manage"
      Call isuserlogin("0")
      jtb_cms_module = jtb_cms_module_manage
    Case "user_detail"
      jtb_cms_module = jtb_cms_module_user_detail
    Case "lostpassword"
      Call check_passport_islostpassword_close
      jtb_cms_module = jtb_cms_module_lostpassword
    Case Else
      jtb_cms_module = jtb_cms_module_premise
  End Select
End Function

Sub jtb_cms_module_logindisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  If check_null(tbackurl) Then tbackurl = get_actual_route("./")
  Call check_valcode(tbackurl)
  Dim tuname, tpword
  tuname = get_safecode(request.Form("username"))
  tpword = get_safecode(request.Form("password"))
  tpword = md5(tpword, "2")
  If check_uname(tuname, tpword) Then
    response.cookies("user")("uname") = tuname
    response.cookies("user")("pword") = tpword
    session("uname") = tuname
    response.redirect tbackurl
  Else
    Call imessage(itake("global.lng_error.login", "lng"), tbackurl)
  End If
End Sub

Sub jtb_cms_module_logoutdisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  If check_null(tbackurl) Then tbackurl = get_actual_route("./")
  response.cookies("user")("uname") = ""
  response.cookies("user")("pword") = ""
  session("uname") = ""
  response.redirect tbackurl
End Sub

Sub jtb_cms_module_insertdisp()
  Dim tmpchkstr, tmpcitem
  tmpchkstr = "username:" & itake("config.username", "lng") & ",password:" & itake("config.password", "lng") & ",email:" & itake("config.email", "lng") & ",city:" & itake("config.city", "lng") & ",sex:" & itake("config.sex", "lng") & ",old:" & itake("config.old", "lng")
  For Each tmpcitem In Split(tmpchkstr, ",")
    If check_null(request.Form(Split(tmpcitem, ":")(0))) Then
      Call client_alert(replace_template(itake("module.insert_empty", "lng"), "[]", "[" & Split(tmpcitem, ":")(1) & "]"), -1)
    End If
  Next
  Dim reg_limit, ritem
  reg_limit = "&,',<,>,#,+,-,/,*,@,$,%,^," & Chr(32) & "," & Chr(9) & ",;"
  reg_limit = Split(reg_limit, ",")
  For Each ritem In reg_limit
    If InStr(get_str(request.Form("username")), ritem) > 0 Then
      Call client_alert(itake("module.insert_limit", "lng"), -1)
    End If
  Next
  Dim reguname: reguname = get_safecode(get_str(request.Form("username")))
  If strlength(reguname) < 2 Or strlength(reguname) > 16 Then Call client_alert(itake("module.insert_length", "lng"), -1)
  If get_str(request.Form("password")) <> get_str(request.Form("cpassword")) Then Call client_alert(itake("module.insert_checkout", "lng"), -1)
  If Not isvalidemail(get_str(request.Form("email"))) Then Call client_alert(itake("module.insert_email", "lng"), -1)
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase & " where " & cfname("username") & "='" & reguname & "'"
  rs.open sqlstr, conn, 1, 3
  If Not rs.EOF Then
    Call client_alert(itake("module.insert_exist", "lng"), -1)
  Else
    rs.addnew
    rs(cfname("username")) = reguname
    rs(cfname("password")) = md5(request.Form("password"), "2")
    rs(cfname("email")) = left_intercept(get_str(request.Form("email")), 50)
    rs(cfname("city")) = Left_intercept(get_str(request.Form("city")), 50)
    rs(cfname("sex")) = get_num(request.Form("sex"), 0)
    rs(cfname("old")) = get_num(request.Form("old"), 0)
    rs(cfname("name")) = left_intercept(get_str(request.Form("name")), 50)
    rs(cfname("qq")) = get_num(request.Form("qq"), 0)
    rs(cfname("msn")) = left_intercept(get_str(request.Form("msn")), 50)
    rs(cfname("phone")) = left_intercept(get_str(request.Form("phone")), 50)
    rs(cfname("homepage")) = left_intercept(get_str(request.Form("homepage")), 50)
    rs(cfname("code")) = get_num(request.Form("code"), 0)
    rs(cfname("address")) = left_intercept(get_str(request.Form("address")), 50)
    rs(cfname("time")) = Now()
    rs(cfname("lasttime")) = Now()
    rs(cfname("pretime")) = Now()
    rs.Update
    response.cookies("user")("uname") = reguname
    response.cookies("user")("pword") = md5(request.Form("password"), "2")
    session("uname") = reguname
    response.redirect get_actual_route("./")
  End If
End Sub

Sub jtb_cms_module_member_informationdisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase & " where " & cfname("username") & "='" & nusername & "'"
  rs.open sqlstr, conn, 1, 3
  If Not rs.EOF Then
    rs(cfname("email")) = left_intercept(get_str(request.Form("email")), 50)
    rs(cfname("city")) = left_intercept(get_str(request.Form("city")), 50)
    rs(cfname("sex")) = get_num(request.Form("sex"), 0)
    rs(cfname("old")) = get_num(request.Form("old"), 0)
    rs(cfname("name")) = left_intercept(get_str(request.Form("name")), 50)
    rs(cfname("qq")) = get_num(request.Form("qq"), 0)
    rs(cfname("msn")) = left_intercept(get_str(request.Form("msn")), 50)
    rs(cfname("phone")) = left_intercept(get_str(request.Form("phone")), 50)
    rs(cfname("homepage")) = left_intercept(get_str(request.Form("homepage")), 50)
    rs(cfname("code")) = get_num(request.Form("code"), 0)
    rs(cfname("address")) = left_intercept(get_str(request.Form("address")), 50)
    rs.Update
    Call imessage(itake("global.lng_public.edit_succeed", "lng"), tbackurl)
  Else
    Call imessage(itake("global.lng_public.sudd", "lng"), tbackurl)
  End If
  rs.Close
  Set rs = Nothing
End Sub

Sub jtb_cms_module_member_passworddisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  Dim tpassword, tnpassword, tncpassword
  tpassword = md5(request.form("password"), "2")
  tnpassword = md5(request.form("npassword"), "2")
  tncpassword = md5(request.form("ncpassword"), "2")
  If not tnpassword = tncpassword Then Call imessage(itake("module.insert_checkout", "lng"), tbackurl)
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase & " where " & cfname("username") & "='" & nusername & "'"
  rs.open sqlstr, conn, 1, 3
  If Not rs.EOF Then
    If Not rs(cfname("password")) = tpassword Then Call imessage(itake("module.insert_password", "lng"), tbackurl)
    rs(cfname("password")) = tnpassword
    rs.Update
    response.cookies("user")("pword") = tnpassword
    Call imessage(itake("global.lng_public.edit_succeed", "lng"), tbackurl)
  Else
    Call imessage(itake("global.lng_public.sudd", "lng"), tbackurl)
  End If
  rs.Close
  Set rs = Nothing
End Sub

Sub jtb_cms_module_member_usersetdisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase & " where " & cfname("username") & "='" & nusername & "'"
  rs.open sqlstr, conn, 1, 3
  If Not rs.EOF Then
    Dim tface_width, tface_height
    tface_width = get_num(request.Form("face_width"), 0)
    tface_height = get_num(request.Form("face_height"), 0)
    If tface_width > face_width_max Then tface_width = face_width_max
    If tface_height > face_height_max Then tface_height = face_height_max
    rs(cfname("face")) = get_num(request.Form("face"), 0)
    rs(cfname("face_u")) = get_num(request.Form("face_u"), 0)
    rs(cfname("face_url")) = left_intercept(get_str(request.Form("face_url")), 255)
    rs(cfname("face_width")) = tface_width
    rs(cfname("face_height")) = tface_height
    rs(cfname("sign")) = left_intercept(get_str(request.Form("sign")), 100)
    rs.Update
    Call imessage(itake("global.lng_public.edit_succeed", "lng"), tbackurl)
  Else
    Call imessage(itake("global.lng_public.sudd", "lng"), tbackurl)
  End If
  rs.Close
  Set rs = Nothing
End Sub

Sub jtb_cms_module_member_message_senddisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  Dim trecipients: trecipients = get_safecode(request.form("recipients"))
  Dim tuserstate: tuserstate = check_isuser(trecipients)
  If tuserstate = 0 Then Call imessage(itake("message.recipients_error", "lng"), tbackurl)
  If tuserstate = 2 Then Call imessage(itake("message.recipients_error2", "lng"), tbackurl)
  If count_user_message(trecipients) > message_max Then Call imessage(ireplace("message.recipients_error_max", "lng"), tbackurl)
  Dim tmpchkstr, tmpcitem
  tmpchkstr = "topic:" & itake("global.lng_config.topic", "lng") & ",content:" & itake("global.lng_config.content", "lng")
  For Each tmpcitem In Split(tmpchkstr, ",")
    If check_null(request.Form(Split(tmpcitem, ":")(0))) Then
      Call client_alert(replace_template(itake("module.insert_empty", "lng"), "[]", "[" & Split(tmpcitem, ":")(1) & "]"), -1)
    End If
  Next
  ndatabase = cndatabase(ngenre, "message")
  nidfield = cnidfield(ngenre, "message")
  nfpre = cnfpre(ngenre, "message")
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase
  rs.open sqlstr, conn, 1, 3
  rs.addnew
  rs(cfname("topic")) = left_intercept(get_str(request.Form("topic")), 50)
  rs(cfname("content")) = left_intercept(get_str(request.Form("content")), 1000)
  rs(cfname("time")) = Now()
  rs(cfname("len")) = len(left_intercept(get_str(request.Form("content")), 1000))
  rs(cfname("addresser")) = nusername
  rs(cfname("recipients")) = trecipients
  rs.update
  Set rs = Nothing
  Call imessage(itake("message.send_succeed", "lng"), tbackurl)
End Sub

Sub jtb_cms_module_member_message_controldisp()
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  ndatabase = cndatabase(ngenre, "message")
  nidfield = cnidfield(ngenre, "message")
  nfpre = cnfpre(ngenre, "message")
  Dim tcid: tcid = get_safecode(request.Form("sel_id"))
  Dim totsql: totsql = " and " & cfname("recipients") & "='" & nusername & "'"
  Call dbase_delete(ndatabase, nidfield, tcid, totsql)
  response.redirect tbackurl
End Sub

Sub jtb_cms_module_member_message_deletedisp()
  ndatabase = cndatabase(ngenre, "message")
  nidfield = cnidfield(ngenre, "message")
  nfpre = cnfpre(ngenre, "message")
  Dim tid: tid = get_num(request.querystring("id"), 0)
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase & " where " & cfname("recipients") & "='" & nusername & "' and " & nidfield & "=" & tid
  rs.open sqlstr, conn, 1, 3
  If not rs.EOF Then
    rs.delete
    response.redirect "?type=manage&mtype=message"
  Else
    Call imessage(itake("message.delete_error", "lng"), tbackurl)
  End If
End Sub

Sub jtb_cms_module_member_friend_adddisp()
  Dim tname: tname = get_safecode(request.form("name"))
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  If check_isuser(tname) = 0 Then Call imessage(itake("friend.add_error1", "lng"), tbackurl)
  ndatabase = cndatabase(ngenre, "friend")
  nidfield = cnidfield(ngenre, "friend")
  nfpre = cnfpre(ngenre, "friend")
  Set rs = server.CreateObject("adodb.recordset")
  sqlstr = "select * from " & ndatabase & " where " & cfname("username") & "='" & nusername & "'"
  rs.open sqlstr, conn, 1, 3
  If rs.recordcount > friend_max Then Call imessage(itake("friend.add_error2", "lng"), tbackurl)
  rs.addnew
  rs(cfname("name")) = tname
  rs(cfname("username")) = nusername
  rs(cfname("time")) = Now()
  rs.update
  Set rs = Nothing
  response.redirect tbackurl
End Sub

Sub jtb_cms_module_member_friend_controldisp
  Dim tbackurl: tbackurl = get_safecode(request.querystring("backurl"))
  ndatabase = cndatabase(ngenre, "friend")
  nidfield = cnidfield(ngenre, "friend")
  nfpre = cnfpre(ngenre, "friend")
  Dim tcid: tcid = get_safecode(request.Form("sel_id"))
  Dim totsql: totsql = " and " & cfname("username") & "='" & nusername & "'"
  Call dbase_delete(ndatabase, nidfield, tcid, totsql)
  response.redirect tbackurl
End Sub

Sub jtb_cms_module_member_messagedisp()
  Select Case request.querystring("mtypes")
    Case "send"
      Call jtb_cms_module_member_message_senddisp
    Case "control"
      Call jtb_cms_module_member_message_controldisp
    Case "delete"
      Call jtb_cms_module_member_message_deletedisp
  End Select
End Sub

Sub jtb_cms_module_member_frienddisp()
  Select Case request.querystring("mtypes")
    Case "add"
      Call jtb_cms_module_member_friend_adddisp
    Case "control"
      Call jtb_cms_module_member_friend_controldisp
  End Select
End Sub

Sub jtb_cms_module_managedisp()
  Select Case request.querystring("mtype")
    Case "information"
      Call jtb_cms_module_member_informationdisp
    Case "password"
      Call jtb_cms_module_member_passworddisp
    Case "userset"
      Call jtb_cms_module_member_usersetdisp
    Case "message"
      Call jtb_cms_module_member_messagedisp
    Case "friend"
      Call jtb_cms_module_member_frienddisp
  End Select
End Sub

Sub jtb_cms_module_lostpassworddisp()
  Dim tusername, temail, tname
  tusername = get_safecode(request.form("username"))
  temail = get_safecode(request.form("email"))
  tname = get_safecode(request.form("name"))
  sqlstr = "select top 1 * from " & ndatabase & " where " & cfname("username") & "='" & tusername & "' and " & cfname("email") & "='" & temail & "' and " & cfname("name") & "='" & tname & "'"
  Set rs = server.CreateObject("adodb.recordset")
  rs.open sqlstr, conn, 1, 3
  If not rs.EOF Then
    Dim tsubject, tbody, tpassword, tmd5password
    tpassword = get_rndcode(8)
    tmd5password = md5(tpassword, "2")
    tsubject = itake("module.lostpassword_subject", "lng")
    tsubject = replace(tsubject, "[]", "[" & web_title("") & "]")
    tbody = itake("module.lostpassword_body", "lng")
    tbody = replace(tbody, "[name]", htmlencode(tname))
    tbody = replace(tbody, "[username]", htmlencode(tusername))
    tbody = replace(tbody, "[password]", tpassword)
    If email_send(temail, tsubject, tbody, "") Then
      rs(cfname("password")) = tmd5password
      rs.update
      Call imessage(itake("module.lostpassword_emailok", "lng"), "0")
    Else
      Call imessage(itake("module.lostpassword_emailerror", "lng"), "0")
    End If
  Else
    Call imessage(itake("module.lostpassword_infoerror", "lng"), -1)
  End If
  Set rs = Nothing
End Sub

Sub jtb_cms_module_action()
  Select Case request.querystring("action")
    Case "login"
      Call jtb_cms_module_logindisp
    Case "logout"
      Call jtb_cms_module_logoutdisp
    Case "insert"
      Call check_passport_isregister_close
      Call jtb_cms_module_insertdisp
    Case "manage"
      Call jtb_cms_module_managedisp
    Case "lostpassword"
      Call check_passport_islostpassword_close
      Call jtb_cms_module_lostpassworddisp
  End Select
End Sub

Call jtb_cms_module_action
'****************************************************
' Jetiben CMS Power by Jetiben.com
' Email: [e-mail]
' Web: http://www.jetiben.com/
'****************************************************
%>