configure.in

c unit test framework

dnl Process this file with autoconf to produce a configure script.

AC_INIT(src/check.c)

CHECK_MAJOR_VERSION=0
CHECK_MINOR_VERSION=9
CHECK_MICRO_VERSION=3
CHECK_VERSION=$CHECK_MAJOR_VERSION.$CHECK_MINOR_VERSION.$CHECK_MICRO_VERSION

AM_INIT_AUTOMAKE(check,$CHECK_VERSION)

AC_SUBST(CHECK_MAJOR_VERSION)
AC_SUBST(CHECK_MINOR_VERSION)
AC_SUBST(CHECK_MICRO_VERSION)

AC_ARG_ENABLE(plain_docdir,
[  --enable-plain-docdir        don't append version information to docdir],
[case "${enableval}" in
  yes) plain_docdir=true ;;
  no)  plain_docdir=false ;;
  *)   AC_MSG_ERROR(bad value ${enableval} for --enable-plain-docdir) ;;
esac], [plain_docdir=false ])

AM_CONDITIONAL(PLAIN_DOCDIR, test x"$plain_docdir" = "xtrue")

dnl Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_RANLIB
if test -n "$GCC"; then
   CFLAGS="$CFLAGS -Wall -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
fi
AC_CHECK_PROG(have_docbook2html,docbook2html,yes)
if test x"$have_docbook2html" != "xyes" ; then
   AC_MSG_WARN([required tools not found, not building docs])
fi
AM_CONDITIONAL(MAKE_DOC, test x"$have_docbook2html" = "xyes")
dnl Checks for libraries.

dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(unistd.h)
AC_CHECK_HEADERS(stdint.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T

AC_CHECK_SIZEOF(int, 4)
AC_CHECK_SIZEOF(short, 2)
AC_CHECK_SIZEOF(long, 4)

dnl Checks for library functions.
dnl AC_FUNC_FORK
dnl AC_FUNC_MALLOC
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([strerror])

AM_CONFIG_HEADER(config.h)

AC_OUTPUT(Makefile
	  src/Makefile
	  src/check.h
	  tests/Makefile
	  doc/Makefile
	  doc/money/Makefile
	  rpm/Makefile
	  rpm/check.spec
	  debian/Makefile)