leafdew.f90

CLM集合卡曼滤波数据同化算法

  SUBROUTINE leafdew ( dtime,rainrate,snowrate,tm,sigf,lai,sai,&
                        ldew,etrrun,tti )

!=======================================================================
!      Source file: leafdew.f90
! Original version: Yongjiu Dai, September 15, 1999
!
! calculation of (1) water storage of intercepted precipitation
!                (2) direct throughfall and canopy draniage of precipitation
! 
! note: the evaporation loss is taken off after the calculation of leaf temperature
!       in the subroutine clm_leaftem.f90
!       not in this subroutine
!
!=======================================================================

  USE PHYCON_MODULE ! physical constant
  IMPLICIT NONE

! ------------------------ Dummy Argument ------------------------------

  real, INTENT(in) :: &
        dtime     ! time step [second]

  real, INTENT(in) :: &
        rainrate, &! rainfall rate [mm/s]
        snowrate, &! snowfall rate [mm/s]
        tm,       &! air temperature at reference height [K]
        sigf,     &! fraction of veg cover, excluding snow-covered veg [-]
        lai,      &! leaf area index [-]
        sai        ! stem area index [-]

  real, INTENT(inout) :: &
        ldew       ! depth of water on foliage [mm]

  real, INTENT(out) :: &
        etrrun,   &! rate of canopy runoff and snow falling off canopy [mm/s]
        tti        ! direct throughfall [mm/s]

! ------------------------ Local variables ---------------------------

  real  prcp,     &! precipitation rate [mm/s]
        ldewmx,   &! maximum allowed water on canopy [mm]
        fpi,      &! coefficient of interception
        pinf,     &! interception of precipitation [mm/s]
        vegt,     &! sigf*lsai
        xrun,     &! excess water that exceeds the leaf capacity [mm/s]
        lsai       ! sum of leaf area index and stem area index [-]

! --------------------------------------------------------------------

     etrrun = 0.                       ! rate of canopy runoff
     tti = 0.                          ! precip. direct through canopy

     prcp = rainrate + snowrate  ! total precipitation
     lsai = lai + sai

     if(sigf > 0.001 .AND. prcp > 0.)then
        vegt = sigf*lsai

!  The leaf water capacities for solid and liquid are different, 
!  general double for snow, but these are of somewhat less significance
!  for water budget because of lower evap. rate at low temperature. Hence,
!  it is reseanable to assume that vegetation storage of solid water 
!  is the same as liquid water

        ldewmx = dewmx*vegt

! Direct throughfall
        fpi = 1. - exp(-0.5*lsai)
        tti  = prcp*(1.-fpi)*sigf
 
! Water storage of intercepted precipitation and dew
        pinf = prcp*fpi*sigf
        ldew = max(0., ldew + dtime*pinf)

! Initialize rate of canopy runoff and snow falling off canopy
        etrrun = 0.0
 
! Excess water that exceeds the leaf capacity
        xrun = (ldew - ldewmx)/dtime
 
! Test on maximum dew on leaf
        if(xrun > 0.) then
           etrrun = xrun
           ldew = ldewmx
        end if
     endif

     END SUBROUTINE leafdew