fractsnow.f90

CLM集合卡曼滤波数据同化算法

  SUBROUTINE fractsnow (kpt,fveg,z0m,snowdp,wt,sigf,fsno)

!=======================================================================
!      Source file: fractsnow.f90
! Original version: Yongjiu Dai, September 15, 1999
!
! Provide snow cover fraction
!
!=======================================================================
  IMPLICIT NONE

! dummy arguments
  integer, INTENT(in) :: &
         kpt      !number of clm land points, including subgrid points

  real, dimension(1:kpt), INTENT(in) :: &
        snowdp,  &! snow depth [m]
        z0m,     &! aerodynamic roughness length [m]
        fveg      ! fractional vegetation cover [-]

  real, dimension(1:kpt), INTENT(out) :: &
        wt,      &! fraction of vegetation covered with snow [-]
        sigf,    &! fraction of veg cover, excluding snow-covered veg [-]
        fsno      ! fraction of soil covered by snow [-]

  integer k       !looping index

!-----------------------------------------------------------------------
      do k = 1, kpt
         if(fveg(k) > 0.001) then

! Fraction of vegetation buried (covered) by snow
            wt(k) = 0.1*snowdp(k)/z0m(k)
            wt(k) = wt(k)/(1.+wt(k))

! Fraction of vegetation cover free of snow
            sigf(k) = (1.-wt(k))*fveg(k)

! Fraction of soil covered by snow
            fsno(k) = snowdp(k)/(0.1+snowdp(k))
         else
            wt(k) = 0.
            sigf(k) = 0.
            fsno(k) = snowdp(k)/(0.1+snowdp(k))
         endif
         if(sigf(k) < 0.001) sigf(k) = 0.
         if(sigf(k) > 0.999) sigf(k) = 1.
      enddo

  END SUBROUTINE fractsnow