link_ram.ld

在SPI 平台优化好的G.711代码,保证好用

/*--------------------------------------------------------------
 File: link_ram.ld

This linker script is used to build DSP MIPS applications.  

--------------------------------------------------------------*/


OUTPUT_FORMAT("elf32-tradlittlemips")
OUTPUT_ARCH(mips)

MEMORY
{
	  /* The ram ORIGIN address can be changed, but it should always be set to 0x400 bytes above */
	  /* where System MIPS will load the DSP MIPS image.  The DSP MIPS startup code modifies the */
	  /* first 0x400 bytes of the image to create its exception vector tables -- by adding the   */
	  /* offset, sde-ld will not put any code or data in this region.                            */

	  /* The setting below reflects a DSP MIPS image that logically starts at 0x81000000.  The   */
	  /* offset of 0x400 is added to create room for the startup code to create its exception    */
	  /* vector table.                                                                           */
    ram : ORIGIN = 0x84000000 + 0x400, LENGTH = 0x0FFFF000
}


SECTIONS
{	
   /* put initconfig section first in RAM -- the Spi_Configure structure will start here */
	.initconfig :
	{
		*(.initconfig)
	} > ram

    .text : 
    {
         *(.text) *(.text.*)     
         *(.reset)   				
        *(.boot) 
        *(.sdeosabi)
        *(.gnu.linkonce.t*)
        . = ALIGN(8) ;
        _ctor_list = .;
		__CTOR_LIST__ = .;
        *(.ctors);*(.ctor);LONG (0); 
        _dtor_list = .;
		__DTOR_LIST__ = .;
        *(.dtors);*(.dtor);LONG (0); 
    } > ram
    
    
	.rodata : 
    { 
        *(.rodata)
        *(.rodata.*)  
        *(.gnu.linkonce.r*)
    } > ram
    
    .data :
    {
		. = ALIGN(8);
		_ld_data_RAM_start = .;
        *(.data)
        *(.gnu.linkonce.d*)
        _gp = . + 0x8000;
        *(.lit8)
        *(.lit4)
        *(.sdata)
		. = ALIGN(8);
		_ld_data_RAM_end = .; 
    } > ram
    
    .bss (NOLOAD) :
    {
        . = ALIGN(8);
        _ld_bss_start = .;
        *(.sbss)
        *(.scommon)
        *(.bss)
        *(COMMON)
		. = ALIGN(8);
        _ld_bss_end = .;
        _end = .;
    } > ram

    .heap (NOLOAD) :
    {
        _HEAP = .;
        _HEAP_START = .;
        *(.heap)
        _HEAP_END = .;
    } > ram

    sdeinit :
    {
        *(.sdeinit)
    } > ram

    sdefini :
    {
        *(.sdefini)
    } > ram

	system_stack :
	{
      	. = ALIGN(8);
      	_system_stack_start = .;
			*(.system_stack)
			. = ALIGN(8);
        	_system_stack_end = .;
			
	} > ram

	hisr_memory :
	{
		*(.hisr_memory)
	} > ram

	avail_memory :
	{
		*(avail_memory)
	} > ram

	 /* DWARF debug sections */

   .debug          0 : { *(.debug) }
   .debug_srcinfo  0 : { *(.debug_srcinfo) }
   .debug_aranges  0 : { *(.debug_aranges) }
   .debug_pubnames 0 : { *(.debug_pubnames) }
   .debug_sfnames  0 : { *(.debug_sfnames) }
   .line           0 : { *(.line) }
   .misc           0 : { *(.rel.dyn) }

}