configure.in

fortran并行计算包

        else
            AC_MSG_RESULT([no, assume Java 1 SDK!])
        fi
    fi
dnl
    if test "$jac_javac_working" = "yes" ; then
        is_javac_working=yes
    else
        is_javac_working=no
    fi
dnl
fi               dnl endof { if test "x$JDK_TOPDIR" = "x" }

if test "$is_javac_working" = "no" ; then
#   Locate Java from user's PATH and known locations
    JAC_PATH_PROG(JC, javac, [
        JAC_TRY_COMPILE( [$JC], , , [
            public static void main( String args[] )
            {
                System.out.println( "Hello world" );
            }
        ], [ jac_javac_working=yes ], [ jac_javac_working=no ] )
        if test "$jac_javac_working" = "yes" ; then
            AC_MSG_RESULT(yes)
            AC_MSG_CHECKING([if $JC accepts -classpath, -d & -sourcepath])
            JAC_TRY_COMPILE( [$JC], [-classpath . -d . -sourcepath .], , [
                public static void main( String args[] )
                {
                    System.out.println( "Hello world" );
                }
            ], [ jac_javac_working=yes ], [ jac_javac_working=no ] )
        fi
        if test "$jac_javac_working" = "yes" ; then
            AC_MSG_RESULT(yes)
            AC_MSG_CHECKING([if $JC understands List & Map])
            JAC_TRY_COMPILE( [$JC], [-classpath . -d . -sourcepath .], [
                import java.util.List;
                import java.util.Map;
            ], [
                public static void main( String args[] )
                {
                    List list;
                    Map  map;
                }
            ], [ jac_javac_working=yes ], [ jac_javac_working=no ] )
        fi
        if test "$jac_javac_working" = "yes" ; then
            AC_MSG_RESULT(yes)
            AC_MSG_CHECKING([if $JC handles static-inner-class reference])
            JAC_TRY_COMPILE( [$JC], [-classpath . -d . -sourcepath .], , [
                public class RecType
                {
                    static final int STATEDEF = 6;
                }
                public static void main( String args[] )
                {
                    int itmp = conftest.RecType.STATEDEF;
                    System.out.println( itmp );
                }
            ], [ jac_javac_working=yes ], [ jac_javac_working=no ] )
        fi
        if test "$jac_javac_working" = "yes" ; then
            AC_MSG_RESULT(yes)
            AC_MSG_CHECKING([if $JC compiles Swing-1.1.1 code])
            JAC_TRY_COMPILE( [$JC], ,[
                import javax.swing.*;
            ], [
                public static void main( String args[] )
                {
                    JFrame frame = new JFrame();
                    System.out.println( "Checking Swing" );
                }
            ], [ jac_javac_working=yes ], [ jac_javac_working=no ] )
        fi
        if test "$jac_javac_working" = "yes" ; then
            jac_prog_working=yes
        else
            jac_prog_working=no
        fi
    ])
#   if JC still hasn't been found, we have exhausted all options! Abort.
    if test "x$JC" = "x" ; then
        AC_MSG_WARN([Cannot find a working javac in \$PATH or known locations!])
        PAC_MSG_ERROR($enable_softerror,
        [Put a working javac in your path or set the --with-java option])
    fi
#   Set JDK_TOPDIR from JC found by JAC_PATH_PROG
    changequote(,)dnl
    JDK_TOPDIR="`echo $JC | sed -e 's%\(.*\)/[^/]*/[^/]*$%\1%'`"
    changequote([,])dnl
    is_javac_working=yes
dnl
fi               dnl end of { if test "x$JDK_TOPDIR" = "x" }

# Print the version of Java used 
# Warn the version of JDK that causes problem
if test "$enable_checkversion" = "yes" ; then
    AC_MSG_CHECKING(for Java version)
    VERSION=`$JDK_TOPDIR/bin/java -fullversion 2>&1`
    case "$VERSION" in
	*1.0.*)
            AC_MSG_RESULT([$VERSION, i.e. the oldest Java])
            AC_MSG_WARN([Java $VERSION is too old to be used with SLOG-2/Jumpshot-2 !])
            ;;
	*1.1.*)
            AC_MSG_RESULT([$VERSION, i.e. Java 1 SDK])
            AC_MSG_WARN([Java $VERSION is too old to be used with SLOG-2/Jumpshot-2 !])
            ;;
	*)
            AC_MSG_RESULT([$VERSION, i.e. Java 2 SDK])
            ;;
    esac
fi

if test "$is_javac_working" = "no" ; then
    PAC_MSG_ERROR($enable_softerror,
        [SLOG-2/Jumpshot-4 can be compiled with Java 2 SDK,
	i.e. j2sdk 1.2.2 or newer.])
fi

# Set the JAVA related tools, like javah and jar.
JH="$JDK_TOPDIR/bin/javah"
RMIC="$JDK_TOPDIR/bin/rmic"
JAR="$JDK_TOPDIR/bin/jar"
for exe in "$JH" "$RMIC" "$JAR" ; do
    AC_MSG_CHECKING([if $exe exists])
    if test -x "$exe" ; then
        AC_MSG_RESULT(yes)
    else
        AC_MSG_RESULT(no)
        PAC_MSG_ERROR($enable_softerror,
                      [$exe does NOT exist, check JDK_TOPDIR = $JDK_TOPDIR])
    fi
done

CPRP=cp
RM="rm -f"
MKDIR=mkdir
AC_SUBST(RM)

AC_SUBST(JFLAGS)
AC_SUBST(JC)
AC_SUBST(JH)
AC_SUBST(RMIC)
AC_SUBST(JAR)

JAC_CHECK_CYGPATH(JPATH_START, JPATH_FINAL)
AC_SUBST(JPATH_START)
AC_SUBST(JPATH_FINAL)

#
# Naming the various build directories, don't inherit them from environment
# Only srcbuild_dir( i.e. this directory ) and libbuild_dir are needed
#
srcbuild_dir=`pwd`
changequote(, )dnl
rootbuild_dir="`echo $srcbuild_dir | sed -e 's%\(.*\)/[^/]*$%\1%'`"
changequote([, ])dnl
# echo "rootbuild_dir = $rootbuild_dir"
libbuild_dir=$rootbuild_dir/lib

# VPATH: Set the srcbuild_dir
if test ! -d $srcbuild_dir/base ; then
    echo "creating directory $srcbuild_dir/base"
    $MKDIR $srcbuild_dir/base
fi
if test ! -d $srcbuild_dir/logformat ; then
    echo "creating directory $srcbuild_dir/logformat"
    $MKDIR $srcbuild_dir/logformat
fi
if test ! -d $srcbuild_dir/viewer ; then
    echo "creating directory $srcbuild_dir/viewer"
    $MKDIR $srcbuild_dir/viewer
fi
if test ! -d $srcbuild_dir/images ; then
    $CPRP -pr $srcdir/images $srcbuild_dir
    $CPRP $srcdir/jumpshot.colors $srcbuild_dir
    $CPRP $srcdir/applet.html $srcbuild_dir
fi
if test ! -d $srcbuild_dir/html ; then
    $CPRP -pr $srcdir/../doc/jumpshot-4/html $srcbuild_dir
fi
AC_SUBST(srcbuild_dir)

# VPATH build: Set the libbuild_dir
if test ! -d $libbuild_dir ; then
    echo "creating $libbuild_dir from source"
    $MKDIR $libbuild_dir
fi
AC_SUBST(libbuild_dir)

# Define the "dirs" components
base_dirs="base/io base/drawable base/statistics base/topology"
logformat_clog_dirs="logformat/clog logformat/clogTOdrawable logformat/clog2 logformat/clog2TOdrawable"
logformat_basic_dirs="logformat/trace logformat/slog2"
logformat_slog2_dirs="logformat/slog2/output logformat/slog2/input logformat/slog2/pipe logformat/slog2/update"
viewer_dirs="viewer/common viewer/convertor viewer/legends viewer/zoomable viewer/histogram viewer/timelines viewer/first viewer/launcher"

# Initial the "dirs" components: slog2_make_dirs, slog2_makefile_dirs.
slog2_make_dirs="$base_dirs"
slog2_makefile_dirs="$base_dirs"
if test "$enable_clog" = "yes" ; then
    slog2_make_dirs="$slog2_make_dirs $logformat_clog_dirs"
    slog2_makefile_dirs="$slog2_makefile_dirs $logformat_clog_dirs"
fi
slog2_make_dirs="$slog2_make_dirs $logformat_basic_dirs"
slog2_makefile_dirs="$slog2_makefile_dirs $logformat_basic_dirs"
# Only slog2_makefile_dirs needs logformat/slog2's subdirectory list
slog2_makefile_dirs="$slog2_makefile_dirs $logformat_slog2_dirs"
slog2_make_dirs="$slog2_make_dirs $viewer_dirs"
slog2_makefile_dirs="$slog2_makefile_dirs $viewer_dirs"

# Output all the directories that needs to do "make"
AC_SUBST(slog2_make_dirs)

# Append each directory slog2_makefile_dirs with "/Makefile"
slog2_makefiles="Makefile"
for dir in $slog2_makefile_dirs ; do
    slog2_makefiles="$slog2_makefiles $dir/Makefile"
done

AC_OUTPUT($slog2_makefiles)